Comment enregistrer automatiquement la date et l'heure lorsqu'une cellule change ?

Il est facile pour nous d'insérer manuellement une date et une heure statiques ou d'insérer une date dynamique qui change avec l'heure du système à l'aide d'une formule. Si vous souhaitez enregistrer automatiquement la date et l'heure lorsque vous modifiez ou saisissez des valeurs, ce problème peut être un peu différent à résoudre. Cependant, dans cet article, vous pouvez accomplir cette tâche en suivant les étapes ci-dessous.

Enregistrer automatiquement la date et l'heure lorsqu'une cellule change avec le code VBA

Enregistrer automatiquement la date et l'heure lorsqu'une cellule change avec le code VBA

Par exemple, j'ai une plage de valeurs, et maintenant, lorsque je modifie ou saisis de nouvelles valeurs dans la Colonne B, je veux qu'il y ait un enregistrement automatique de la date et de l'heure actuelles dans la Colonne C, comme le montre la capture d'écran suivante :

Vous pouvez accomplir cette tâche avec le code VBA suivant. Veuillez procéder comme suit :

1. Maintenez les touches ALT + F11 enfoncées pour ouvrir la fenêtre Microsoft Visual Basic for Applications.

2. Ensuite, choisissez votre feuille de calcul utilisée dans l'Explorateur de projets à gauche, double-cliquez dessus pour ouvrir le Module, puis copiez et collez le code VBA suivant dans le Module vide :

Code VBA : Enregistrer automatiquement la date et l'heure lorsqu'une cellule change

Private Sub Worksheet_Change(ByVal Target As Range)
'Update 20140722
Dim WorkRng As Range
Dim Rng As Range
Dim xOffsetColumn As Integer
Set WorkRng = Intersect(Application.ActiveSheet.Range("B:B"), Target)
xOffsetColumn = 1
If Not WorkRng Is Nothing Then
    Application.EnableEvents = False
    For Each Rng In WorkRng
        If Not VBA.IsEmpty(Rng.Value) Then
            Rng.Offset(0, xOffsetColumn).Value = Now
            Rng.Offset(0, xOffsetColumn).NumberFormat = "dd-mm-yyyy, hh:mm:ss"
        Else
            Rng.Offset(0, xOffsetColumn).ClearContents
        End If
    Next
    Application.EnableEvents = True
End If
End Sub

3. Ensuite, enregistrez et fermez ce code pour retourner à la feuille de calcul. Maintenant, lorsque vous modifiez la valeur d'une cellule ou saisissez de nouvelles données dans la Colonne B, la date et l'heure seront automatiquement enregistrées dans la Colonne C.

Remarques :

1. Dans le code ci-dessus, vous pouvez modifier « B:B » par toute autre colonne dans laquelle vous souhaitez changer les valeurs des cellules dans ce script : Set WorkRng = Intersect(Application.ActiveSheet.Range("B:B"), Target).

2. Avec ce script xOffsetColumn = 1 , vous pouvez insérer et mettre à jour la date et l'heure dans la première colonne à côté de votre colonne de valeurs modifiées. Vous pouvez changer le chiffre 1 par d'autres nombres, tels que 2, 3, 4, 5…, ce qui signifie que la date sera insérée dans la deuxième, troisième, quatrième ou cinquième colonne à côté de votre colonne de valeurs modifiées.

3. Lorsque vous supprimez une valeur dans la colonne modifiée, la date et l'heure seront également supprimées.