Comment garder la fenêtre Excel toujours au top?

Avez-vous déjà souhaité que vos fenêtres Excel restent toujours au top et ne soient pas couvertes par d'autres fenêtres? Malheureusement, Excel ne fournit pas de fonctionnalité pour résoudre cette tâche. Mais, ici, je peux vous donner un code VBA pour gérer ce travail.

Gardez la fenêtre Excel toujours au top avec le code VBA

Gardez la fenêtre Excel toujours au top avec le code VBA

Le code VBA suivant peut vous aider à garder la fenêtre Excel toujours au top, le code est appliqué à la fois au bureau 32 bits et au bureau 64 bits.

1. Maintenez le ALT + F11 clés pour ouvrir le Fenêtre Microsoft Visual Basic pour Applications.

2Cliquez sur insérer > Moduleet collez le code suivant dans le Fenêtre du module.

Code VBA: gardez la fenêtre Excel toujours au top

'Update 20140909
#If Win64 Then
    Public Declare PtrSafe Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As LongPtr, _
            ByVal hwndInsertAfter As LongPtr, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#Else
    Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#End If
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
    #If Win64 Then
        Dim xHwnd As LongPtr
    #Else
        Dim xHwnd As Long
    #End If
    If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub
Sub SetXLOnTop()
    ShowXLOnTop True
End Sub
Sub SetXLNormal()
    ShowXLOnTop False
End Sub

3. Puis appuyez F5 clé pour exécuter ce code, et un Macros boîte de dialogue apparaîtra, sélectionnez DéfinirXLSurHaut option, et cliquez Courir .

4. Et puis votre fenêtre Excel sera toujours au-dessus des autres applications.

Notes: Si vous souhaitez ramener la fenêtre Excel à la normale, appuyez simplement sur F5 clé pour ouvrir le Macros dialogue, choisissez DéfinirXNormal et cliquez sur Courir.