Comment trouver et remplacer du texte puis conserver la mise en forme dans Excel?

La fonction Rechercher et remplacer est puissante et utile lorsque nous devons trouver une valeur spécifique et la remplacer par une autre. Mais s'il existe une plage de cellules et que certaines des cellules incluent des valeurs de mise en forme différentes. Dans ce cas, rechercher et remplacer une valeur par la fonction Rechercher et remplacer interrompra la mise en forme des valeurs dans les cellules, comme illustré ci-dessous, comment pouvons-nous préserver la mise en forme des valeurs dans chaque cellule lors de la recherche et du remplacement dans Excel?

Rechercher et remplacer conserver la mise en forme avec le code de macro

Rechercher et remplacer conserver la mise en forme avec le code de macro

Il n'y a pas d'autres méthodes, mais le code de macro peut vous aider à rechercher et à remplacer du texte et à préserver la mise en forme.

1. presse Alt + F11 clés pour ouvrir le Microsoft Visual Basic pour Application fenêtre.

2. Cliquez insérer > Moduleet collez le code ci-dessous dans le script.

VBA: rechercher et remplacer préserver la mise en forme

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

3. presse F5 clé, une boîte de dialogue apparaît pour vous permettre de sélectionner une plage à rechercher et à remplacer, voir capture d'écran:

4. Cliquez sur OK et la chaîne spécifique dans la cellule sélectionnée est remplacée par autre et conserve la mise en forme.

Conseil : Dans le code,  KK est la chaîne que vous voulez trouver, et Kutools est la chaîne par laquelle vous souhaitez remplacer, vous pouvez les modifier selon vos besoins.