Comment compter les valeurs uniques basées sur plusieurs critères dans Excel ?

Dans cet article, je vais vous donner quelques exemples pour compter les valeurs uniques basées sur un ou plusieurs critères dans une feuille de calcul. Les étapes détaillées suivantes peuvent vous aider.

Compter les valeurs uniques basées sur un critère

Compter les valeurs uniques basées sur deux dates données

Compter les valeurs uniques basées sur deux critères

Compter les valeurs uniques basées sur trois critères

Compter les valeurs uniques basées sur un critère

Par exemple, j'ai la plage de données suivante, et maintenant je veux compter les produits uniques vendus par Tom.

Veuillez entrer cette formule dans une cellule vide où vous souhaitez obtenir le résultat, G2 par exemple :

=SOMME(SI("Tom"=$C$2:$C$20; 1/(NB.SI.ENS($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20)); 0)), puis appuyez simultanément sur les touches Maj + Ctrl + Entrée pour obtenir le bon résultat, voir capture d'écran :

Remarque : Dans la formule ci-dessus, « Tom » est le critère de nom sur lequel vous souhaitez effectuer le décompte, C2:C20 sont les cellules contenant le critère de nom, A2:A20 sont les cellules dont vous souhaitez compter les valeurs uniques.

Compter les valeurs uniques basées sur deux dates données

Pour calculer les valeurs uniques entre deux dates données, par exemple, je veux compter les produits uniques entre la plage de dates du 01/09/2016 au 30/09/2016, veuillez appliquer cette formule :

=SOMME(SI($D$2:$D$20<=DATE(2016; 9; 30)*($D$2:$D$20>=DATE(2016; 9; 1)); 1/NB.SI.ENS( $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATE(2016; 9; 30);$D$2:$D$20; ">="&DATE(2016; 9; 1))); 0), puis appuyez simultanément sur les touches Maj + Ctrl + Entrée pour obtenir le résultat unique, voir capture d'écran :

Remarque : Dans la formule ci-dessus, les dates 01/09/2016 et 30/09/2016 sont les dates de début et de fin sur lesquelles vous souhaitez effectuer le décompte, D2:D20 sont les cellules contenant le critère de date, A2:A20 sont les cellules à partir desquelles vous souhaitez compter les valeurs uniques.

Compter les valeurs uniques basées sur deux critères

Si vous souhaitez compter les produits uniques vendus par Tom en septembre, la formule suivante peut vous aider.

Veuillez entrer cette formule dans une cellule vide pour afficher le résultat, H2 par exemple.

=SOMME(SI(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATE(2016; 9; 30)*($D$2:$D$20>=DATE(2016; 9; 1))); 1/NB.SI.ENS($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATE(2016; 9; 30);$D$2:$D$20; ">="&DATE(2016; 9; 1))); 0) puis appuyez simultanément sur les touches Maj + Ctrl + Entrée pour obtenir le résultat unique, voir capture d'écran :

Remarques :

1. Dans la formule ci-dessus, « Tom » est le critère de nom, 01/09/2016 et 30/09/2016 sont les deux dates sur lesquelles vous souhaitez effectuer le décompte, C2:C20 sont les cellules contenant le critère de nom, et D2:D20 sont les cellules contenant la date, A2:A20 est la plage de cellules à partir de laquelle vous souhaitez compter les valeurs uniques.

2. Si vous avez besoin d'utiliser un critère « ou » pour compter les valeurs uniques, par exemple, calculez les produits vendus par Tom ou dans la région Sud, veuillez appliquer cette formule :

=SOMME(--(FREQUENCE(SI(("Tom"=$C$2:$C$20)+("Sud"=$B$2:$B$20); NB.SI($A$2:$A$20; "<"&$A$2:$A$20); ""); NB.SI($A$2:$A$20; "<"&$A$2:$A$20))>0)), et n'oubliez pas d'appuyer simultanément sur les touches Maj + Ctrl + Entrée pour obtenir le résultat unique, voir capture d'écran :

Compter les valeurs uniques basées sur trois critères

Pour compter les produits uniques avec trois critères, la formule peut être plus complexe. Disons que nous voulons calculer les produits uniques vendus par Tom en septembre dans la région Nord. Veuillez procéder comme suit :

Entrez cette formule dans une cellule vide pour afficher le résultat, I2 par exemple :

=SOMME(SI(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATE(2016; 9; 30))*($D$2:$D$20>=DATE(2016; 9; 1))*("Nord"=$B$2:$B$20); 1/NB.SI.ENS($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATE(2016; 9; 30); $D$2:$D$20; ">="&DATE(2016; 9; 1); $B$2:$B$20; "Nord")); 0), puis appuyez simultanément sur les touches Maj + Ctrl + Entrée pour obtenir le résultat unique, voir capture d'écran :