Comment remplir automatiquement une zone de texte lors de la saisie dans Excel?

Par défaut, Excel peut se souvenir de ce que vous avez entré dans les cellules de la feuille de calcul actuelle et compléter automatiquement ce contenu la prochaine fois lors de la saisie d'une lettre initiale associée dans une nouvelle cellule. Cependant, si vous souhaitez que tout le contenu que vous avez entré dans la feuille de calcul soit complété automatiquement dans une zone de texte (contrôle ActiveX), comment pouvez-vous faire? Cet article fournira une méthode VBA pour vous aider à remplir automatiquement une zone de texte lors de la saisie d'une lettre initiale à l'intérieur.

Remplir automatiquement une zone de texte lors de la saisie avec le code VBA

Remplir automatiquement une zone de texte lors de la saisie avec le code VBA

Veuillez procéder comme suit pour créer une zone de texte automatiquement lors de la saisie d'une lettre initiale dans la zone de texte.

1. Veuillez insérer une zone de texte en cliquant sur Développeur > insérer > Zone de texte (contrôle ActiveX). Voir la capture d'écran:

2. Et puis cliquez sur Développeur > insérer > Zone de liste (contrôle ActiveX) pour insérer une zone de liste dans la feuille de calcul actuelle. Voir la capture d'écran:

3. Cliquez avec le bouton droit sur l'onglet de la feuille, puis cliquez sur Voir le code dans le menu contextuel comme illustré ci-dessous.

4. dans le Microsoft Visual Basic pour applications , veuillez copier et coller ci-dessous le code VBA dans la fenêtre Code. Et puis cliquez Outils > Références , puis vérifiez le Exécution de scripts Microsoft boîte dans la Références - VBAProject boite de dialogue. Voir la capture d'écran:

Code VBA: remplir automatiquement une zone de texte lors de la saisie

Dim xRg As Range
Dim xDic As New Dictionary
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Me.TextBox1.Value = Me.ListBox1.Value
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim xVal As String
    On Error Resume Next
    If IsNumeric(Target.Value) Then
        xVal = Str(Target.Value)
    Else
        xVal = Target.Value
    End If
    If xVal <> "" Then
        If Not xDic.Exists(xVal) Then
            xDic.Add xVal, xVal
        End If
    End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Me.ListBox1.Visible = False
End Sub
Private Sub Worksheet_Activate()
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    If xRg Is Nothing Then
        Set xRg = ActiveSheet.UsedRange
    End If
    Me.ListBox1.Visible = False
    xDic.RemoveAll
    With Me.ListBox1
        For I = 1 To xRg.Count
            xStr = xRg(I).Value
            If xStr <> "" Then
                .AddItem xStr
                If Not xDic.Exists(xStr) Then
                    xDic.Add xStr, xStr
                End If
            End If
        Next
    End With
End Sub
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With Me.ListBox1
        .Top = Me.TextBox1.Top
        .Left = Me.TextBox1.Left + Me.TextBox1.Width
        .Width = Me.TextBox1.Width
    End With
    TextBoxVal Me.TextBox1.Object
End Sub
Sub TextBoxVal(xTextBox As Variant)
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    If xRg Is Nothing Then Exit Sub
    Me.ListBox1.Clear
    xStr = xTextBox.Value
    If xStr = "" Then
        Me.ListBox1.Visible = False
        Application.EnableEvents = True
        Exit Sub
    End If
    For I = 0 To UBound(xDic.Items)
        If Left(xDic.Items(I), Len(xStr)) = xStr Then
            Me.ListBox1.AddItem xDic.Items(I)
        End If
    Next
    Me.ListBox1.Visible = True
    If Me.ListBox1.ListCount > 0 Then
        With xTextBox
            .Value = Me.ListBox1.List(0)
            .SelStart = Len(xStr)
            .SelLength = Len(Me.ListBox1.List(0))
        End With
    End If
    Me.ListBox1.Activate
    Me.ListBox1.Selected(0) = True
    Application.ScreenUpdating = True
End Sub
Private Sub ListBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Me.TextBox1.Value = Me.ListBox1.Value
    End If
End Sub

Notes: Dans le code, ListBox1 et Zone de texte1 sont le nom de la zone de liste et de la zone de texte que vous avez insérées dans votre feuille de calcul.

5. appuie sur le autre + Q touches pour quitter Microsoft Visual Basic pour applications fenêtre.

6. Désactivez le mode de conception en cliquant sur Développeur > Mode de conception dans la feuille de calcul.

7. Passez maintenant à une autre feuille de calcul, puis revenez à la feuille de calcul précédente pour activer le code VBA.

À partir de maintenant. Lors de la saisie d'une lettre initiale dans la zone de texte, tous les textes commençant par cette lettre que vous avez entrée dans la feuille de calcul seront répertoriés dans la zone de liste située sur le côté droit de la zone de texte. Veuillez double-cliquer sur celui dont vous avez besoin pour le saisir dans la zone de texte. Voir la capture d'écran:

Notes: Vous pouvez utiliser le Up or Vers le bas flèche pour vous déplacer parmi tous les textes à saisie semi-automatique de la zone de liste, puis appuyez sur la touche Entrer touche pour saisir celle requise dans la zone de texte.

Articles Liés:

• Comment sélectionner automatiquement le texte d'une zone de texte lorsqu'elle est sélectionnée dans Excel?
• Comment effacer le contenu de la zone de texte lorsque vous cliquez sur Excel?
• Comment concaténer des textes de plusieurs cellules dans une zone de texte dans Excel?
• Comment désactiver l'édition dans la zone de texte pour empêcher la saisie de l'utilisateur dans Excel?
• Comment formater une zone de texte en pourcentage dans Excel?