Fonction COUNTIFS d'Excel - Compter les cellules avec plusieurs critères - Logique ET et logique OU

Syntaxe de la fonction COUNTIFS dans Excel

• Syntaxe de la fonction COUNTIFS
• Points à retenir

Compter les cellules qui répondent à plusieurs critères spécifiés avec COUNTIFS en logique ET

• COUNTIFS pour compter les cellules qui répondent à plusieurs critères spécifiés dans une plage
• COUNTIFS pour compter les cellules qui répondent à plusieurs critères spécifiés dans différentes plages

Compter les cellules qui répondent à plusieurs critères spécifiés en logique OU

• Additionner les résultats de COUNTIF ou COUNTIFS pour compter les cellules qui répondent à l'un des critères spécifiés
• COUNTIFS avec une constante de tableau pour compter les cellules qui répondent à l'un des critères spécifiés

Syntaxe de la fonction COUNTIFS dans Excel

En tant que l'une des fonctions statistiques dans Excel, COUNTIFS compte les cellules qui répondent à un ou plusieurs critères spécifiés dans une ou plusieurs plages.

Syntaxe de la fonction COUNTIFS

La syntaxe de la fonction COUNTIFS contient les arguments suivants :

• "plage_critères1" (obligatoire) fait référence à la première plage de cellules où appliquer "critères1".
• "critères1" (obligatoire) fait référence à la condition définissant quelles cellules doivent être comptées dans "plage_critères1".
• "plage_critères2", "critères2" (facultatif) font référence à des plages supplémentaires et leurs critères associés. Jusqu'à 127 paires de plage et critères sont autorisées.

La fonction COUNTIF renvoie une valeur numérique – le nombre de cellules qui répondent à un ou plusieurs critères spécifiés dans les plages associées.

Points à retenir

• Le nombre de lignes et de colonnes de chaque plage supplémentaire doit être égal à celui de "plage_critères1". Les plages peuvent être identiques, adjacentes ou non adjacentes.
•  
• Dans la formule COUNTIFS dans Excel, un astérisque (*) peut correspondre à n'importe quel nombre de caractères, tandis que le point d'interrogation (?) correspond à n'importe quel caractère unique. Si vous devez compter des cellules avec le caractère générique réel - astérisque (*) ou point d'interrogation (?), placez une tilde (~) avant le caractère générique. Par exemple, ~*, ~?.
• Les guillemets (“”) sont requis pour encadrer les critères non numériques, tandis que les critères numériques peuvent ne pas avoir de guillemets (“”). Par exemple, 80, “>=80”, “a”, “inde”.
• La fonction COUNTIFS n'est pas sensible à la casse. Ainsi, la chaîne “Inde” ou “INDE” ne fait aucune différence pour le résultat de la formule.
• Pour utiliser une référence de cellule dans la fonction COUNTIFS avec des "opérateurs de comparaison", vous devrez mettre les opérateurs entre guillemets (“”), et ajouter une esperluette (&) entre eux. Par exemple, “>”&B2.
• L'ordre des opérateurs de comparaison est important : = ne peut fonctionner seul ou après > ou <.

Compter les cellules qui répondent à plusieurs critères spécifiés avec COUNTIFS en logique ET

Par défaut, la fonction COUNTIFS évalue plusieurs critères avec une "logique" "ET". Le résultat de la formule COUNTIFS montre le nombre de cellules qui répondent à tous les critères spécifiés. Voici quelques exemples utilisant la fonction COUNTIFS pour compter des cellules en logique ET.

COUNTIFS pour compter les cellules qui répondent à plusieurs critères spécifiés dans une plage

√ Remarque : Les cellules vides signifient que les scores n'ont pas été enregistrés correctement. Un score de 0 signifie que l'étudiant n'a pas passé le test.

Pour compter le nombre d'étudiants dont le score en anglais est compris entre 60 et 90 (inclus), nous avons listé ici deux méthodes.

• Vous pouvez utiliser une formule COUNTIFS :

  =COUNTIFS(C2:C8,">=60",C2:C8,"<=90")

  Le résultat est "5"
•  
• Ou, si vous avezKutools for Excelinstallé, vous pouvez aller dans l'onglet "Kutools", trouver "Sélectionner", et cliquer sur "Sélectionner des cellules spécifiques" dans la liste déroulante. Réglez comme indiqué dans la capture d'écran ci-dessous :
  

Kutools pour Excel - Boostez Excel avec plus de 300 outils essentiels. Profitez de fonctionnalités IA gratuites en permanence ! Obtenez-le maintenant

☞ Plus d'approches pour accomplir la tâche : Comment compter le nombre de cellules entre deux valeurs ou dates dans Excel ?

Pour compter le nombre de scores valides (les cellules ne sont pas 0 ou vides), nous avons également listé ici deux méthodes.

• Vous pouvez utiliser la formule ci-dessous :

  =COUNTIFS(C2:D8,"<>0",C2:D8,"<>")

  Le résultat est "12"
  √ Remarque : "<>" dans Excel signifie différent de. "<>0" signifie différent de 0 ; Et "<>" signifie différent de vide, ou nous pouvons dire, ne sont pas vides.
•  
• Avec "Kutools for Excel" installé, vous pouvez également aller dans l'onglet "Kutools", trouver "Sélectionner", et cliquer sur "Sélectionner des cellules spécifiques" dans la liste déroulante. Réglez comme indiqué dans la capture d'écran ci-dessous :
  
  √ Remarque : Kutools ne compte pas les cellules vides par défaut, donc sous "Type spécifique", vous pouvez simplement définir les critères comme “Différent de 0”.”

  Kutools pour Excel - Boostez Excel avec plus de 300 outils essentiels. Profitez de fonctionnalités IA gratuites en permanence ! Obtenez-le maintenant

COUNTIFS pour compter les cellules qui répondent à plusieurs critères spécifiés dans différentes plages

• Pour compter le nombre d'étudiants qui sont "des pays se terminant par la lettre 'a'" et "leurs noms commencent par 'J'", utilisez la formule :

  =COUNTIFS(A2:A8,"j*", B2:B8,"*a")

  Le résultat est "2"
  √ Remarque : Le caractère générique "astérisque (*)" correspond à n'importe quel nombre de caractères.
•  
• Pour compter le nombre d'étudiants dont "le score en anglais et le score en mathématiques sont tous deux supérieurs (non égaux à) aux scores d'Eddie (valeurs en C4 et D4)", utilisez l'une des formules suivantes :

  =COUNTIFS(C2:C8,">60",D2:D8,">80")

  =COUNTIFS(C2:C8,">"&C4,D2:D8,">"&D4

  Le résultat est "3"
•  
• Pour compter le nombre d'étudiants qui sont "d'Inde (la valeur en B2)", et "avec une note de A (la valeur en E2)", utilisez l'une des formules suivantes :

  =COUNTIFS(B2:B8,"india",E2:E8,"a")

  =COUNTIFS(B2:B8,B2,E2:E8,E2)

  Le résultat est "2"

Compter les cellules qui répondent à plusieurs critères spécifiés en logique OU

Compter les cellules qui répondent à plusieurs critères spécifiés en "logique OU" signifie compter le nombre total de cellules qui répondent au critère1, les cellules qui répondent au critère2, et les cellules qui répondent…, en d'autres termes, compter les cellules qui répondent à l'un des (au moins un) critères. Pour ce faire, nous avons listé 2 méthodes ci-dessous :

Additionner les résultats de COUNTIF ou COUNTIFS pour compter les cellules qui répondent à l'un des critères spécifiés

En additionnant les nombres de cellules qui répondent à au moins un des critères que vous avez spécifiés, il serait facile de générer le nombre total de cellules. Donc, ce que vous devez faire est d'écrire plusieurs formules COUNTIF(S) selon vos besoins, puis d'effectuer des opérations arithmétiques.

• Pour compter le nombre d'étudiants qui sont "d'Inde (valeur en B2)" ou "Angleterre (valeur en B3)", utilisez l'une des formules suivantes :

  =COUNTIF(B2:B8,"india")+COUNTIF(B2:B8,"england")

  =COUNTIF(B2:B8,B2)+COUNTIF(B2:B8,B3)

  Le résultat est "4"
  √ Remarque : Vous pouvez utiliser "Kutools for Excel" si vous avez installé le module complémentaire professionnel : "Kutools" > "Sélectionner" > "Sélectionner des cellules spécifiques", sélectionnez "OU" sous le "Type spécifique".
•  
• Pour compter le nombre d'étudiants ayant "un score en anglais ou en mathématiques supérieur à 80 (y compris 80)", utilisez l'une des formules suivantes :

  =COUNTIF(C2:C8,">=80")+COUNTIF(D2:D8,">=80")-COUNTIFS(C2:C8,">=80", D2:D8,">=80")

  Le résultat est "5"
  √ Remarque : Soustraire COUNTIFS(C2:C8,">=80", D2:D8,">=80") ici permet de supprimer les doublons, c'est-à-dire les étudiants ayant un score en anglais et en mathématiques tous deux supérieurs à 80.

COUNTIFS avec une constante de tableau pour compter les cellules qui répondent à l'un des critères spécifiés

Bien qu'additionner les résultats de COUNTIF ou COUNTIFS puisse être trop volumineux en formatage, nous pouvons combiner l'utilisation de SOMME et des fonctions COUNTIFS avec une constante de tableau pour compter le nombre de cellules différentes répondant aux critères associés. Consultez les exemples ci-dessous :

• Pour compter le nombre d'étudiants qui sont "d'Inde ou d'Angleterre", utilisez la formule (une plage) :

  =SUM(COUNTIF(B2:B8,{"india","england"}))

  Le résultat est "4"
•  
• Pour compter le nombre d'étudiants qui sont "d'Inde ou d'Amérique avec la note A, B ou C", utilisez la formule :

  =SUM(COUNTIFS(B2:B8,{"india","america"},E2:E8,{"a";"b";"c"}))

  Le résultat est "4"
  √ Remarque : Vous devez utiliser des "points-virgules (;)" dans la deuxième constante de tableau. Pour les cas avec plus de critères, envisagez d'utiliser une formule "SOMMEPROD".