Passer au contenu principal

Excel INDEX MATCH : recherches de base et avancées

Auteur : Amanda Li Dernière modification: 2023-12-29

Dans Excel, récupérer avec précision des données spécifiques est souvent une nécessité fréquente. Bien que les fonctions INDEX et MATCH aient chacune leurs propres atouts, leur combinaison débloque un ensemble d'outils puissants pour la recherche de données. Ensemble, ils facilitent une gamme de capacités de recherche, depuis les recherches horizontales et verticales de base jusqu'à des fonctionnalités plus avancées telles que les recherches bidirectionnelles, sensibles à la casse et multicritères. Offrant des capacités améliorées par rapport à VLOOKUP, l'association d'INDEX et de MATCH permet une plus large gamme d'options de recherche de données. Dans ce didacticiel, explorons l'étendue des possibilités qu'ils peuvent réaliser ensemble.


Comment utiliser INDEX et MATCH dans Excel

Avant d'utiliser les fonctions INDEX et MATCH, assurons-nous de savoir comment INDEX et MATCH peuvent nous aider à rechercher des valeurs en premier.


Comment utiliser la fonction INDEX dans Excel

Le plus INDEX La fonction dans Excel renvoie la valeur à un emplacement donné dans une plage spécifique. La syntaxe de la fonction INDEX est la suivante :

=INDEX(array, row_num, [column_num])
  • tableau (obligatoire) fait référence à la plage à partir de laquelle vous souhaitez renvoyer la valeur.
  • row_num (obligatoire, sauf si num_colonne est présent) fait référence au numéro de ligne du tableau.
  • num_colonne (facultatif, mais obligatoire si row_num est omis) fait référence au numéro de colonne du tableau.

Par exemple, pour savoir la partition de Jeff, 6ème élève de la liste, vous pouvez utiliser la fonction INDEX comme ceci :

=INDEX(C2:C11,6)

indice excel correspondance 01

Remarque : la gamme C2: C11 est l'endroit où les scores sont répertoriés, tandis que le nombre 6 trouve la note d'examen du 6e étudiant.

Ici, faisons un petit test. Pour la formule =INDEX(A1:C1,2), quelle valeur renverra-t-il ? --- Oui, ça reviendra Date de naissance, 2ème valeur dans la ligne donnée.

Il faut maintenant savoir que la fonction INDEX peut parfaitement fonctionner avec des plages horizontales ou verticales. Mais que se passe-t-il si nous en avons besoin pour renvoyer une valeur dans une plage plus large avec plusieurs lignes et colonnes ? Eh bien, dans ce cas, nous devrions appliquer à la fois un numéro de ligne et un numéro de colonne. Par exemple, pour savoir La note de Jeff dans la plage du tableau au lieu d'une seule colonne, nous pouvons localiser son score avec un numéro de ligne de 6 et numéro de colonne de 3 dans le cellules passant par A2 à C11 comme ça:

=INDEX(A2:C11,6,3)

indice excel correspondance 02

Ce que nous devons savoir sur la fonction INDEX dans Excel :
  • La fonction INDEX peut fonctionner avec des plages verticales et horizontales.
  • Si les deux row_num et num_colonne des arguments sont utilisés, row_num va en avance sur le num_colonne, et INDEX récupère la valeur à l'intersection du spécifié row_num et num_colonne.

Cependant, pour une très grande base de données avec plusieurs lignes et colonnes, il n'est certainement pas pratique pour nous d'appliquer la formule avec un numéro de ligne et un numéro de colonne exacts. Et c'est là que nous devons combiner l'utilisation de la fonction MATCH.


Comment utiliser la fonction MATCH dans Excel

La fonction MATCH dans Excel renvoie une valeur numérique, l'emplacement d'un élément spécifique dans la plage donnée. La syntaxe de la fonction MATCH est la suivante :

=MATCH(lookup_value, lookup_array, [match_type])
  • valeur de recherche (obligatoire) fait référence à la valeur à correspondre dans le tableau_recherche.
  • tableau_recherche (obligatoire) fait référence à la plage de cellules dans laquelle vous souhaitez rechercher MATCH.
  • Type de match (optionnel): 1, 0 or -1.
    • 1 (par défaut), MATCH trouvera la plus grande valeur inférieure ou égale à la valeur de recherche. Les valeurs dans le tableau_recherche doivent être placés dans l'ordre croissant.
    • 0, MATCH trouvera la première valeur exactement égale à la valeur de recherche. Les valeurs dans le tableau_recherche peut être dans n'importe quel ordre. (Pour les cas où le type de correspondance est défini sur 0, vous pouvez utiliser des caractères génériques.)
    • -1, MATCH trouvera la plus petite valeur supérieure ou égale à la valeur de recherche. Les valeurs dans le tableau_recherche doivent être placés par ordre décroissant.

Par exemple, pour savoir la position de Vera dans la liste des noms, vous pouvez utiliser la formule MATCH comme ceci :

=MATCH("Vera",A2:A11,0)

indice excel correspondance 3

√ Remarque : Le résultat « 4 » indique que le nom « Vera » est en 4ème position de la liste.

Ce que nous devons savoir sur la fonction MATCH dans Excel :
  • La fonction MATCH renvoie la position de la valeur de recherche dans le tableau de recherche, pas la valeur elle-même.
  • La fonction MATCH renvoie la première correspondance en cas de doublons.
  • Tout comme la fonction INDEX, la fonction MATCH peut également fonctionner avec des plages verticales et horizontales.
  • MATCH n'est pas sensible à la casse.
  • Si la valeur de recherche de la formule MATCH se présente sous forme de texte, placez-le entre guillemets.
  • Si la valeur de recherche ne se trouve pas dans le tableau_recherche, #N / A l'erreur est renvoyée.

Maintenant que nous connaissons les utilisations de base des fonctions INDEX et MATCH dans Excel, retroussons nos manches et préparons-nous à combiner les deux fonctions.


Comment combiner INDEX et MATCH dans Excel

Veuillez consulter l'exemple ci-dessous pour comprendre comment combiner les fonctions INDEX et MATCH :

Trouver La partition d'Evelyn, sachant que les résultats des examens sont dans la 3ème colonne, on peut utilisez la fonction MATCH pour déterminer automatiquement la position de la ligne sans avoir besoin de le compter manuellement. Par la suite, nous pouvons utiliser la fonction INDEX pour récupérer le valeur à l'intersection de la ligne identifiée et de la 3ème colonne:

=INDEX(A2:C11,MATCH("Evelyn",A2:A11,0),3)

indice excel correspondance 4

Eh bien, puisque la formule peut paraître un peu compliquée, passons en revue chaque partie.

indice excel correspondance 5

Le plus INDEX la formule contient trois arguments :

  • row_num: CORRESPONDRE("Évelyn",A2:A11,0) fournit à INDEX la position de ligne de la valeur "Evelyn" dans le périmètre A2: A11, lequel est 5.
  • num_colonne: 3 précise le 3ème colonne pour INDEX pour localiser le score dans le tableau.
  • tableau: A2: C11 demande à INDEX de renvoyer la valeur correspondante à l'intersection de la ligne et de la colonne spécifiées, dans la plage allant de A2 à C11. Finalement, nous obtenons le résultat 90.

Dans la formule ci-dessus, nous avons utilisé une valeur codée en dur, "Evelyne". Cependant, en pratique, les valeurs codées en dur ne sont pas pratiques, car elles nécessiteraient une modification à chaque fois que l'on cherche à rechercher des données différentes, comme le score d'un autre élève. Dans de tels scénarios, nous pouvons utiliser des références de cellules pour créer des formules dynamiques. Par exemple, dans ce cas, je vais changez "Evelyn" en F2:

=INDEX(A2:C11,MATCH(F2,A2:A11,0),3)

(AD) Simplifiez les recherches avec Kutools : aucune saisie de formule requise !

Kutools for Excel's Super recherche fournit une variété d'outils de recherche sur mesure pour répondre à tous vos besoins. Que vous effectuiez des recherches multicritères, une recherche sur plusieurs feuilles ou une recherche un vers plusieurs, Super recherche simplifie le processus en quelques clics. Explorez ces fonctionnalités pour voir comment Super recherche change la façon dont vous interagissez avec les données Excel. Dites adieu aux tracas liés à la mémorisation de formules complexes.

Outils de recherche Kutools

Kutools for Excel - Vous offrant plus de 300 fonctions pratiques pour une productivité sans effort. Ne manquez pas votre chance de l'essayer avec un essai gratuit complet de 30 jours ! Commence dès maintenant!


Exemples de formules INDEX et MATCH

Dans cette partie, nous parlerons de différentes circonstances pour utiliser les fonctions INDEX et MATCH pour répondre à différents besoins.


INDEX et MATCH pour appliquer une recherche bidirectionnelle

Dans l'exemple précédent, nous connaissions le numéro de colonne et avons utilisé une formule MATCH pour trouver le numéro de ligne. Mais que se passe-t-il si nous ne sommes pas sûrs du numéro de colonne également ?

Dans de tels cas, nous pouvons effectuer une recherche bidirectionnelle, également appelée recherche matricielle, en utilisant deux fonctions MATCH : une pour trouver le numéro de ligne et l’autre pour déterminer le numéro de colonne. Par exemple, pour savoir La partition d'Evelyn, il faut utiliser la formule :

=INDEX(A2:C11,MATCH("Evelyn",A2:A11,0),MATCH("Score",A1:C1,0))

indice excel correspondance 6

Comment fonctionne cette formule :
  • La première formule MATCH trouve l'emplacement d'Evelyn dans la liste A2:A11, fournissant 5 comme numéro de ligne à INDEX.
  • La deuxième formule MATCH détermine la colonne pour les scores et les retours 3 comme numéro de colonne à INDEX.
  • La formule se simplifie en =INDEX(A2:C11,5,3), et INDEX renvoie 90.

INDEX et MATCH pour appliquer une recherche à gauche

Considérons maintenant un scénario dans lequel vous devez déterminer la classe d'Evelyn. Vous avez peut-être remarqué que la colonne de classe est positionnée à gauche de la colonne de nom, une situation qui dépasse les capacités d'une autre puissante fonction de recherche d'Excel, RECHERCHEV.

En fait, la possibilité d'effectuer des recherches sur le côté gauche est l'un des aspects dans lesquels la combinaison d'INDEX et de MATCH surpasse VLOOKUP.

Trouver La classe d'Evelyne, utilisez la formule suivante pour rechercher Evelyn dans B2:B11 et récupérer la valeur correspondante de A2:A11.

=INDEX(A2:A11,MATCH("Evelyn",B2:B11,0))

indice excel correspondance 7

Remarque: Vous pouvez facilement effectuer une recherche à gauche pour des valeurs spécifiques en utilisant le RECHERCHE de droite à gauche caractéristique de Kutools for Excel en quelques clics seulement. Pour implémenter la fonctionnalité, accédez au Kutools dans votre Excel, puis cliquez sur Super recherche > RECHERCHE de droite à gauche dans le Laits en poudre groupe.

RECHERCHE de droite à gauche

Si vous n'avez pas installé Kutools, cliquez ici pour téléchargez et bénéficiez d'un essai gratuit complet de 30 jours !


INDEX et MATCH pour appliquer une recherche sensible à la casse

Les fonctions MATCH sont intrinsèquement insensibles à la casse. Cependant, lorsque vous avez besoin que votre formule fasse la différence entre les caractères majuscules et minuscules, vous pouvez l'améliorer en incorporant le EXACT fonction. En combinant la fonction MATCH avec EXACT dans une formule INDEX, vous pouvez alors effectuer efficacement une recherche sensible à la casse, comme indiqué ci-dessous :

=INDEX(array, MATCH(TRUE, EXACT(lookup_value, lookup_array), 0))
  • tableau fait référence à la plage à partir de laquelle vous souhaitez renvoyer la valeur.
  • valeur de recherche fait référence à la valeur à laquelle correspondre, compte tenu de la casse des caractères, dans le tableau_recherche.
  • tableau_recherche fait référence à la plage de cellules avec laquelle vous souhaitez que MATCH soit comparé valeur de recherche.

Par exemple, pour savoir La note d'examen de JIMMY, utilisez la formule suivante :

=INDEX(C2:C11,MATCH(TRUE,EXACT("JIMMY",A2:A11),0))

√ Remarque : Il s'agit d'une formule matricielle qui vous oblige à entrer avec Ctrl + Shift + Entrer, sauf dans Excel 365 et Excel 2021.

indice excel correspondance 8

Comment fonctionne cette formule :
  • La fonction EXACT compare "JIMMY" avec les valeurs de la liste A2: A11, en considérant la casse des caractères : si les deux chaînes correspondent précisément, en tenant compte des caractères majuscules et minuscules, EXACT renvoie VRAI; sinon ça revient FAUX. En conséquence, nous obtenons un tableau contenant des valeurs VRAI et FAUX.
  • La fonction MATCH récupère ensuite le position de la première valeur VRAIE dans le tableau, qui devrait être 10.
  • Enfin, INDEX récupère la valeur au 10ème position fournie par MATCH dans le tableau.

Notes:

  • N'oubliez pas de saisir correctement la formule en appuyant sur Ctrl + Maj + Entrée, sauf si vous utilisez Excel 365 or Excel 2021, auquel cas il suffit d'appuyer sur Entrer.
  • La formule ci-dessus recherche dans une seule liste C2: C11. Si vous souhaitez effectuer une recherche dans une plage comportant plusieurs colonnes et lignes, disons A2: C11, vous devez proposer à la fois les numéros de colonne et de ligne à INDEX :
  • =INDEX(A2:C11,MATCH(TRUE,EXACT("JIMMY",A2:A11),0),3)
  • Dans cette formule révisée, nous utilisons la fonction MATCH pour rechercher « JIMMY », en considérant le cas des caractères, dans la plage A2: A11, et une fois que nous trouvons une correspondance, nous récupérons la valeur correspondante du 3ème colonne de la gamme A2: C11.

INDEX et MATCH pour trouver la correspondance la plus proche

Dans Excel, vous pouvez rencontrer des situations dans lesquelles vous devez trouver la correspondance la plus proche ou la plus proche d'une valeur spécifique dans un ensemble de données. Dans de tels scénarios, l’utilisation d’une combinaison des fonctions INDEX et MATCH, ainsi que des fonctions ABS et MIN, peut s’avérer extrêmement utile.

=INDEX(array, MATCH(MIN(ABS(lookup_array - lookup_value)), ABS(lookup_array - lookup_value),0))
  • tableau fait référence à la plage à partir de laquelle vous souhaitez renvoyer la valeur.
  • tableau_recherche fait référence à la plage de valeurs à laquelle vous souhaitez trouver la correspondance la plus proche valeur de recherche.
  • valeur de recherche fait référence à la valeur pour trouver sa correspondance la plus proche.

Par exemple, pour savoir dont le score est le plus proche de 85, utilisez la formule suivante pour rechercher le score le plus proche de 85 en C2:C11 et récupérer la valeur correspondante de A2:A11.

=INDEX(A2:A11,MATCH(MIN(ABS(C2:C11-85)),ABS(C2:C11-85),0))

√ Remarque : Il s'agit d'une formule matricielle qui vous oblige à entrer avec Ctrl + Shift + Entrer, sauf dans Excel 365 et Excel 2021.

Comment fonctionne cette formule :
  • ABS(C2:C11-85) calcule la différence absolue entre chaque valeur de la plage C2: C11 et 85, ce qui donne lieu à un tableau de différences absolues.
  • MIN(ABS(C2:C11-85)) trouve la valeur minimale dans le tableau des différences absolues, qui représente la différence la plus proche de 85.
  • La fonction MATCH MATCH(MIN(ABS(C2:C11-85)),ABS(C2:C11-85),0) trouve ensuite la position de la différence absolue minimale dans le tableau des différences absolues, qui devrait être 10.
  • Enfin, INDEX récupère la valeur à la position dans la liste A2: A11 qui correspond au score le plus proche de 85 dans le périmètre C2: C11.

Notes:

  • N'oubliez pas de saisir correctement la formule en appuyant sur Ctrl + Maj + Entrée, sauf si vous utilisez Excel 365 or Excel 2021, auquel cas il suffit d'appuyer sur Entrer.
  • En cas d'égalité, cette formule renverra le premier match.
  • Trouver la correspondance la plus proche du score moyen, remplace 85 dans la formule avec MOYENNE(C2:C11).

INDEX et MATCH pour appliquer une recherche avec plusieurs critères

Pour trouver une valeur qui répond à plusieurs conditions, vous obligeant à effectuer une recherche dans deux colonnes ou plus, utilisez la formule suivante. La formule vous permet d'effectuer une recherche multicritère en spécifiant diverses conditions dans différentes colonnes, vous aidant ainsi à trouver la valeur souhaitée qui répond à tous les critères spécifiés.

=INDEX(array, MATCH(1, (lookup_value1=lookup_array1) * (lookup_value2=lookup_array2) * (…), 0))

√ Remarque : Il s'agit d'une formule matricielle qui vous oblige à entrer avec Ctrl + Shift + Entrer. Une paire d'accolades apparaîtra alors dans la barre de formule.

  • tableau fait référence à la plage à partir de laquelle vous souhaitez renvoyer la valeur.
  • (lookup_value=lookup_array) représente une seule condition. Cette condition vérifie si un valeur de recherche correspond aux valeurs dans le tableau_recherche.

Par exemple, pour trouver le score de Coco de classe A, dont la date de naissance est le 7/2/2008, vous pouvez utiliser la formule suivante :

=INDEX(D2:D11,MATCH(1,(G2=A2:A11)*(G3=B2:B11)*(G4=C2:C11),0))

indice excel correspondance 9

Notes:

  • Dans cette formule, nous évitons de coder en dur les valeurs, ce qui simplifie l'obtention d'un score avec différentes informations en modifiant les valeurs dans les cellules. G2, G3, G4.
  • Vous devez saisir la formule en appuyant sur Ctrl + Maj + Entrée sauf dans Excel 365 or Excel 2021, où vous pouvez simplement appuyer sur Entrer.
    Si vous oubliez constamment d'utiliser Ctrl + Maj + Entrée pour compléter la formule et obtenir des résultats incorrects, utilisez la formule suivante, légèrement plus complexe, avec laquelle vous pouvez compléter par un simple Entrer clé:
    =INDEX(D2:D11,MATCH(1,INDEX((G2=A2:A11)*(G3=B2:B11)*(G4=C2:C11),0,1),0))
  • Les formules peuvent être complexes et difficiles à retenir. Pour simplifier les recherches multicritères sans avoir besoin de saisir manuellement une formule, pensez à utiliser Kutools for Excel's Recherche multi-conditions fonctionnalité. Une fois que vous avez installé Kutools, accédez au Kutools dans votre Excel, puis cliquez sur Super recherche > Recherche multi-conditions dans le Laits en poudre groupe.

    Recherche multi-conditions

    Si vous n'avez pas installé Kutools, cliquez ici pour téléchargez et bénéficiez d'un essai gratuit complet de 30 jours !


INDEX et MATCH pour appliquer une recherche sur plusieurs colonnes

Imaginez un scénario dans lequel vous avez affaire à plusieurs colonnes de données. La première colonne fait office de clé pour classer les données dans les autres colonnes. Pour déterminer la catégorie ou la classification d'une entrée spécifique, vous devrez effectuer une recherche dans les colonnes de données et l'associer à la clé appropriée dans la colonne de référence.

Par exemple, dans le tableau ci-dessous, comment pouvons-nous faire correspondre l'élève Shawn avec sa classe correspondante en utilisant INDEX et MATCH ? Eh bien, vous pouvez y parvenir avec une formule, mais la formule est assez complète et peut être difficile à comprendre, sans parler de la mémorisation et de la saisie.

=IFERROR(INDEX($A$2:$A$4,MATCH(IF(SUM(MMULT(--($B$2:$E$4=G2),TRANSPOSE(COLUMN($B$2:$E$4)^0)))>0,1,-1),MMULT(--($B$2:$E$4=G2),TRANSPOSE(COLUMN($B$2:$E$4)^0))^0,0)), "")

C'est là que Kutools for Excel's Indexer et faire correspondre sur plusieurs colonnes la fonctionnalité est pratique. Cela simplifie le processus, permettant de faire correspondre rapidement et facilement des entrées spécifiques avec leurs catégories correspondantes. Pour débloquer ce puissant outil et faire correspondre sans effort Shawn avec sa classe, il suffit téléchargez et installez le complément Kutools pour Excel, puis procédez comme suit :

  1. Sélectionnez la cellule de destination dans laquelle vous souhaitez afficher la classe correspondante.
  2. Sur le Kutools onglet, cliquez sur Aide à la formule > Recherche et référence > Indexer et faire correspondre sur plusieurs colonnes.
  3. indice excel correspondance 11
  4. Dans la boîte de dialogue contextuelle, procédez comme suit :
    1. Cliquez sur le 1er icône de correspondance d'index excel bouton à côté de Recherche_col pour sélectionner la colonne contenant les informations clés que vous souhaitez renvoyer, c'est-à-dire les noms de classe. (Vous ne pouvez sélectionner qu'une seule colonne ici.)
    2. Cliquez sur le 2ème icône de correspondance d'index excel bouton à côté de Table_rng pour sélectionner les cellules pour correspondre aux valeurs dans le sélectionné Recherche_col, c'est-à-dire les noms des étudiants.
    3. Cliquez sur le 3ème icône de correspondance d'index excel bouton à côté de Valeur_de recherche pour sélectionner la cellule contenant le nom de l'élève que vous souhaitez associer à sa classe, dans ce cas, Shawn.
    4. Cliquez OK.
    5. indice excel correspondance 12

Résultat

Kutools a généré automatiquement la formule et vous verrez immédiatement le nom de la classe de Shawn affiché dans la cellule de destination.

Remarque: Pour essayer le Indexer et faire correspondre sur plusieurs colonnes fonctionnalité, vous aurez besoin de Kutools for Excel installé sur votre ordinateur. Si vous ne l'avez pas encore installé, n'attendez pas --- Téléchargez-le et installez-le maintenant pour un essai gratuit de 30 jours sans aucune limitation. Faites qu'Excel fonctionne plus intelligemment dès aujourd'hui !


INDEX et MATCH pour rechercher la première valeur non vide

Pour récupérer la première valeur non vide, en ignorant les erreurs, d'une colonne ou d'une ligne, vous pouvez utiliser une formule basée sur les fonctions INDEX et MATCH. Cependant, si vous ne souhaitez pas ignorer les erreurs de votre plage, ajoutez la fonction ISBLANK.

  • Obtenez la première valeur non vide d'une colonne ou d'une ligne en ignorant les erreurs :
  • =INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))
  • Obtenez la première valeur non vide d'une colonne ou d'une ligne incluant les erreurs :
  • =INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

Notes:


INDEX et MATCH pour rechercher la première valeur numérique

Pour récupérer la première valeur numérique d'une colonne ou d'une ligne, utilisez la formule basée sur les fonctions INDEX, MATCH et ISNUMBER.

=INDEX(B4:B15,MATCH(TRUE,ISNUMBER(B4:B15),0))

Notes:


INDEX et MATCH pour rechercher des associations MAX ou MIN

Si vous devez récupérer une valeur associée à la valeur maximale ou minimale dans une plage, vous pouvez utiliser la fonction MAX ou MIN avec les fonctions INDEX et MATCH.

  • INDEX et MATCH pour récupérer une valeur associée à la valeur maximale :
  • =INDEX(array, MATCH(MAX(lookup_array), lookup_array, 0))
  • INDEX et MATCH pour récupérer une valeur associée à la valeur minimale :
  • =INDEX(array, MATCH(MIN(lookup_array), lookup_array, 0))
  • Il y a deux arguments dans les formules ci-dessus :
    • tableau fait référence à la plage à partir de laquelle vous souhaitez renvoyer les informations associées.
    • tableau_recherche représente l'ensemble des valeurs à examiner ou à rechercher selon des critères spécifiques, c'est-à-dire des valeurs maximales ou minimales.

Par exemple, si vous souhaitez déterminer qui a le score le plus élevé, employez la formule suivante :

=INDEX(A2:A11,MATCH(MAX(C2:C11),C2:C11,0))

Comment fonctionne cette formule :
  • MAX (C2:C11) recherche la valeur la plus élevée de la plage C2: C11, lequel est 96.
  • La fonction MATCH trouve alors la position de la valeur la plus élevée dans le tableau C2: C11, qui devrait être 1.
  • Enfin, INDEX récupère le 1ère valeur dans la liste A2: A11.

Notes:

  • En cas de plusieurs valeurs maximales ou minimales, comme le montre l'exemple ci-dessus où deux étudiants ont obtenu le même score le plus élevé, cette formule renverra la première correspondance.
  • Pour déterminer qui a le score le plus bas, utilisez la formule suivante :
    =INDEX(A2:A11,MATCH(MIN(C2:C11),C2:C11,0))

Astuce : Personnalisez vos propres messages d'erreur #N/A

Lorsque vous travaillez avec les fonctions INDEX et MATCH d'Excel, vous pouvez rencontrer l'erreur #N/A lorsqu'il n'y a aucun résultat correspondant. Par exemple, dans le tableau ci-dessous, lorsque vous tentez de trouver le score d'une élève nommée Samantha, une erreur #N/A apparaît car elle n'est pas présente dans l'ensemble de données.

indice excel correspondance 15

Pour rendre vos feuilles de calcul plus conviviales, vous pouvez personnaliser ce message d'erreur en encapsulant votre formule INDEX MATCH dans la fonction IFNA :

=IFNA(INDEX(C2:C11,MATCH(F2,A2:A11,0)),"Not found")

indice excel correspondance 16

Notes:

  • Vous pouvez personnaliser vos messages d'erreur en remplaçant "Pas trouvé" avec le texte de votre choix.
  • Si vous souhaitez gérer toutes les erreurs, pas seulement #N/A, pensez à utiliser le IFERREUR fonction au lieu de IFNA:
    =IFERROR(INDEX(C2:C11,MATCH(F2,A2:A11,0)),"Not found")

    Notez qu'il n'est peut-être pas conseillé de supprimer toutes les erreurs, car elles servent d'alerte pour des problèmes potentiels dans vos formules.

Ci-dessus se trouve tout le contenu pertinent lié aux fonctions INDEX et MATCH dans Excel. J'espère que vous trouverez le tutoriel utile. Si vous souhaitez découvrir davantage de trucs et astuces Excel, cliquez ici s'il vous plait pour accéder à notre vaste collection de plus de milliers de tutoriels.

Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Leave your comments
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations