KutoolsforOffice — Une solution unique, cinq outils puissants.Faire plus avec moins d'efforts.Soldes de mars : 20 % de réduction

Comptez facilement les valeurs uniques et distinctes – 7 exemples

AuteurXiaoyang Date de modification

Généralement, dans Excel, les valeurs uniques sont celles qui apparaissent une seule fois dans une liste, sans aucune duplication, tandis que les valeurs distinctes regroupent toutes les valeurs différentes — c’est-à-dire les valeurs uniques ainsi que la première occurrence de chaque valeur dupliquée. Lorsque vous travaillez avec un grand jeu de données, il peut être utile de compter le nombre de valeurs uniques et distinctes au sein d’une plage de cellules contenant des doublons, comme le montre la capture d’écran ci-dessous. Ce tutoriel vous présente quelques astuces rapides pour compter efficacement les valeurs uniques et distinctes dans Excel.

Compter les valeurs uniques ou distinctes dans une liste

Compter le nombre de valeurs uniques dans une plage dans Excel

Compter les valeurs uniques valeurs (uniques et premières occurrences dupliquées) dans Excel

Télécharger le fichier exemple

Compter les valeurs uniques distinctes

Compter le nombre de valeurs uniques dans une plage dans Excel

Cette section présente quelques exemples de formules permettant de compter le nombre de valeurs uniques, notamment en divisant du texte et des nombres au sein d’une liste.

Compter le nombre de valeurs uniques dans une plage avec des formules

Supposons que j’aie une liste de noms contenant certains doublons. Je dois maintenant obtenir uniquement le nombre de noms uniques (mis en surbrillance en jaune), comme illustré dans la capture d’écran ci-dessous :

données exemples

Pour résoudre ce problème, la formule matricielle suivante peut vous être utile :

Étape 1 : Saisie de la formule

Saisissez ou copiez la formule ci-dessous dans une cellule vide où vous souhaitez afficher le résultat :

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
Remarque : dans la formule ci-dessus, « A2:A12 » est la liste de données dont vous souhaitez compter les valeurs uniques.

Étape 2 : Appuyez sur les touches Ctrl + Maj + Entrée pour obtenir le résultat correct :

Compter les valeurs uniques avec une formule

Remarques:

  1. Si votre liste de cellules contient d’autres types de données, tels que des nombres, des booléens ou des valeurs d’erreur, la formule ci-dessus comptera le nombre de valeurs uniques, quel que soit leur type.
  2. Lorsque la liste de données contient des cellules vides, cette formule les exclut automatiquement.
  3. Pour compter uniquement les valeurs texte uniques lorsqu’il existe d’autres types de données, veuillez appliquer la formule matricielle ci-dessous, puis appuyez sur les touches « Ctrl » + « Maj » + « Entrée » pour obtenir le résultat :
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Pour compter uniquement les nombres uniques à partir d’une liste de cellules contenant tout type de données, veuillez utiliser la formule matricielle suivante, puis appuyez sur les touches « Ctrl » + « Maj » + « Entrée » pour obtenir le résultat :
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Compter le nombre de valeurs uniques dans une plage en quelques clics grâce à Kutools pour Excel

Retenir des formules pour les réutiliser plus tard peut vite devenir fastidieux. Heureusement, avec « Kutools pour Excel », son option « Compter le nombre de valeurs uniques dans une plage » dans  « Assistant de formule » vous permet d’obtenir le résultat en quelques clics seulement. Découvrez la démonstration ci-dessous :

  1. Cliquez sur une cellule pour afficher le résultat ;
  2. Activez cette fonctionnalité en cliquant sur « Kutools » > « Assistant de formule » > « Assistant de formule » > « Statistiques » > « Compter le nombre de valeurs uniques dans une plage » ;
  3. Sélectionnez la liste de données, puis cliquez sur « OK ».
    Compter les valeurs uniques avec Kutools
Conseils :
  1. Pour utiliser cette fonctionnalité, vous devez télécharger et installer Kutools pour Excel.
  2. La fonctionnalité « Assistant de formule » regroupe plus de 40 formules courantes, telles que « Extraire les valeurs uniques », « Extraire les cellules contenant des valeurs uniques d’une plage (en incluant les premières occurrences des doublons) », « Compter le nombre de valeurs séparées par des virgules dans une cellule », « Effectuer une somme basée sur un texte identique », et bien d’autres encore…

Compter le nombre de valeurs uniques dans une plage dans Excel 365/2021 avec des formules

Si vous utilisez Excel 365 ou Excel 2021, la nouvelle fonction UNIQUE vous permet de créer des formules plus simples pour compter le nombre de valeurs uniques dans une plage d’un ensemble de données.

Par exemple, pour compter le nombre de noms uniques dans la plage A2:A12, saisissez la formule suivante :

Étape 1 : Copiez ou saisissez la formule ci-dessous

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Remarque : dans cette formule, « A2:A12 » est la liste de données dont vous souhaitez Compter le nombre de valeurs uniques dans une plage.

Étape 2 : Appuyez sur la touche Entrée pour obtenir le résultat :

Compter les valeurs uniques dans Excel 365/2021 avec une formule

Conseils:

  1. Si la liste de données inclut d’autres types de données, tels que du texte, des nombres, des booléens ou des valeurs d’erreur, cette formule renvoie le nombre de valeurs uniques, quel que soit leur type.
  2. La formule ci-dessus permet de compter le nombre de valeurs uniques dans une plage, y compris les cellules vides. Si vous souhaitez exclure les cellules vides, appliquez simplement la formule ci-dessous, puis appuyez sur la touche « Entrée » :
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Compter les valeurs uniques valeurs (uniques et premières occurrences dupliquées) dans Excel

Pour compter les valeurs différentes (valeurs uniques ainsi que les premières occurrences des doublons) dans une plage de cellules, je vous présente ici d’autres formules permettant d’accomplir cette tâche.

Compter les valeurs uniques valeurs avec des formules

Dans Excel, appliquez l’une des formules ci-dessous pour obtenir le nombre de valeurs distinctes.

Étape 1 : Saisissez l’une des formules ci-dessous

Formule 1 : Après avoir saisi la formule, appuyez sur la touche « Entrée ».

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formule 2 : Après avoir saisi la formule, appuyez sur Ctrl + Maj + Entrée.

=SUM(1/COUNTIF(A2:A12,A2:A12))
Remarque : dans ces formules, « A2:A12 » est la liste de données dont vous souhaitez compter Valeur différente.

Résultat :

Compter les valeurs distinctes avec une formule

Conseils :

  1. Si la liste de données contient d’autres types de données, tels que des nombres, des booléens ou des valeurs d’erreur, cette formule renvoie toutes les valeurs distinctes, quel que soit leur type.
  2. Lorsque vous utilisez la formule ci-dessus, vous obtenez la valeur d’erreur #DIV/0 si la liste de données contient des cellules vides. Pour corriger cela et ignorer les cellules vides, veuillez appliquer l’une des formules suivantes :
    Formule 1 : Après avoir saisi la formule, appuyez sur la touche « Entrée ».
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formule 2 : Après avoir saisi la formule, appuyez sur les touches « Ctrl » + « Maj » + « Entrée ».
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Compter les valeurs distinctes en excluant les cellules vides avec une formule

  3. Pour obtenir uniquement le nombre de valeurs texte distinctes dans une liste de données, veuillez appliquer la formule matricielle ci-dessous et appuyer sur les touches « Ctrl » + « Maj » + « Entrée » pour obtenir le résultat :
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Pour compter uniquement les valeurs numériques distinctes, veuillez utiliser la formule matricielle suivante et appuyer sur les touches « Ctrl » + « Maj » + « Entrée » pour obtenir le résultat :
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Compter les valeurs uniques valeurs en quelques clics grâce à Kutools pour Excel

Si vous devez appliquer fréquemment ces formules dans votre classeur, il peut être fastidieux de les mémoriser pour les réutiliser par la suite. Heureusement, avec **Kutools pour Excel**, son option **« Compter les cellules avec des valeurs uniques (inclure la première occurrence dupliquée) »** dans l’**Assistant de formule** vous permet d’obtenir le résultat en quelques clics seulement. Découvrez la démonstration ci-dessous :

  1. Cliquez sur une cellule pour afficher le résultat ;
  2. Activez cette fonctionnalité en cliquant sur « Kutools » > « Assistant de formule » > « Statistiques » > « Compter les cellules avec des valeurs uniques (inclure la première occurrence dupliquée) » ;
  3. Sélectionnez la liste de données, puis cliquez sur « OK ».
    Compter les valeurs distinctes avec Kutools
Conseils:
  1. Pour utiliser cette fonctionnalité, vous devez télécharger et installer Kutools pour Excel.
  2. La fonctionnalité « Assistant de formule » regroupe plus de 40 formules courantes, telles que « Extraire les valeurs uniques », « Extraire les cellules contenant des valeurs uniques d’une plage (en incluant les premières occurrences des doublons) », « Compter le nombre de valeurs séparées par des virgules dans une cellule », « Faire une somme selon un texte identique », et bien d’autres encore…

Compter les valeurs uniques valeurs avec un tableau croisé dynamique

Dans Excel, le tableau croisé dynamique peut également vous aider à obtenir le nombre de valeurs distinctes à partir d’une liste de données. Voici la marche à suivre :

Étape 1 : Créez un Tableau croisé dynamique

  1. Sélectionnez la liste de données, puis cliquez sur « Insertion » > « Tableau croisé dynamique » depuis le Ruban, voir la capture d’écran :
    créer un tableau croisé dynamique pour les données sélectionnées
  2. Dans la boîte de dialogue « Tableau croisé dynamique à partir d’un tableau ou d’une plage » qui s’ouvre :
    (1). Choisissez une nouvelle feuille de calcul ou une feuille de calcul existante où vous souhaitez insérer le tableau croisé dynamique ;
    (2). Cochez ensuite la case « Ajouter ces données au modèle de données ».
    (3). Cliquez ensuite sur le bouton « OK ».
    définir les options dans la boîte de dialogue Tableau croisé dynamique à partir d’un tableau ou d’une plage

Étape 2 : Organisez le champ et sélectionnez l’option Nombre distinct

  1. Le volet « Champs de tableau croisé dynamique » s’affiche. Faites glisser le champ « Noms » vers la zone « Valeurs », comme illustré ci-dessous :
    Organiser les champs pour le tableau croisé dynamique
  2. Ensuite, cliquez sur la flèche déroulante « Nombre de noms » et choisissez « Paramètres des champs de valeur », voir la capture d’écran :
    cliquer sur l’option Paramètres des champs de valeurs
  3. La boîte de dialogue « Paramètres des champs de valeur » s’ouvre alors. Sélectionnez « Nombre distinct » dans la liste située sous l’onglet « Résumer les valeurs par », puis cliquez sur « OK » (voir la capture d’écran).
    sélectionner l’option Compte distinct

Résultat :

Le Tableau croisé dynamique créé affiche désormais le nombre distinct de la liste de données, comme illustré dans la capture d’écran ci-dessous :

Résultat du tableau croisé dynamique pour compter les valeurs distinctes

Conseils:

  1. Si vous mettez à jour vos données sources, il vous suffit de cliquer avec le bouton droit sur le tableau croisé dynamique et de sélectionner l’option « Actualiser » pour obtenir le dernier décompte.
  2. L’option « Comptage distinct » n’est disponible qu’à partir d’Excel 2013.

Compter les valeurs uniques valeurs dans Excel 365/2021 avec des formules

Dans Excel 365 ou Excel 2021, combinez la nouvelle fonction UNIQUE avec la fonction standard NBVAL pour créer une formule simple et efficace.

Veuillez copier ou saisir la formule ci-dessous dans une cellule vide, puis appuyer sur la touche « Entrée » pour obtenir le résultat :

=COUNTA(UNIQUE(A2:A12))
Remarque : dans cette formule, « A2:A12 » est la liste de données dont vous souhaitez Compter les valeurs uniques les valeurs.

Compter les valeurs distinctes dans Excel 365/2021 avec une formule

Conseils:

  1. Si la liste de données inclut d’autres types de données, tels que du texte, des nombres, des booléens ou des valeurs d’erreur, cette formule compte le nombre de valeurs distinctes, quel que soit leur type.
  2. La formule ci-dessus compte les valeurs uniques, y compris les cellules vides. Si vous souhaitez exclure les cellules vides, appliquez la formule ci-dessous et appuyez sur la touche « Entrée » pour obtenir le résultat :
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Compter les valeurs distinctes dans Excel 365/2021 avec une formule en excluant les cellules vides

Articles associés :

  • Compter le nombre de valeurs uniques dans une plage dans Tableau croisé dynamique
  • Par défaut, lorsque nous créons un Tableau croisé dynamique à partir d’une plage de données contenant certains Valeurs en double, tous les enregistrements sont également comptabilisés. Cependant, il arrive que nous souhaitions uniquement compter les valeurs uniques selon une colonne afin d’obtenir le bon résultat visuel. Dans cet article, je vais expliquer comment compter les valeurs uniques dans Tableau croisé dynamique.
  • Compter le nombre de valeurs uniques dans une plage avec plusieurs critères
  • Voici une plage de données comprenant plusieurs noms, projets et emplacements. Votre mission consiste à identifier les noms qui répondent aux critères que j’ai listés, puis à compter chaque nom correspondant une seule fois, comme le montre la capture d’écran ci-dessous. Connaissez-vous des astuces pour relever ce défi ? Dans cet article, je vous dévoile justement ces astuces.
  • Concaténer les valeurs uniques
  • Si j’ai une longue liste de valeurs contenant des doublons, comment puis-je extraire uniquement les valeurs uniques et les concaténer dans une seule cellule ? Existe-t-il une méthode rapide et simple pour résoudre ce problème dans Excel ?