Comment obtenir la liste des dossiers dans Outlook?

Parfois, l'arborescence de tous les dossiers de messagerie (y compris les dossiers personnels créés) dans le volet de navigation peut aider les utilisateurs d'Outlook pendant leur travail. Pour lister rapidement l'ensemble des dossiers de l'arborescence, le code VBA peut vous aider. Dans ce didacticiel, vous pouvez apprendre à obtenir facilement la liste des dossiers avec le code VBA.

Obtenir la liste des dossiers dans Outlook avec le code VBA

Obtenir la liste des dossiers dans Outlook avec le code VBA

Pour obtenir la liste des dossiers dans Outlook avec le code VBA, procédez comme suit.

1. appuie sur le autre + F11 touches sur le clavier pour ouvrir le Microsoft Visual Basic pour applications fenêtre.

2. Double-cliquez ensuite sur le Project1 > Objet Microsoft Outlook > Cette session Outlook ouvrir le Projet1 - ThisOutlookSession la fenêtre. Voir la capture d'écran:

3. Puis copiez et collez le code VBA ci-dessous dans la fenêtre Project1 - ThisOutlookSession.

VBA: obtenir la liste des dossiers dans Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. appuie sur le F5 touche du clavier pour démarrer l'exécution du code VBA.

5. Maintenant un Macro boîte de dialogue apparaît, veuillez cliquer sur le course .

6. Attendez que la macro s'exécute. Ensuite, la liste de tous vos dossiers de courrier électronique est immédiatement répertoriée dans une nouvelle fenêtre de message créée. Vous pouvez facilement l'imprimer. Voir la capture d'écran:

Notes: Ce code VBA peut être appliqué à Outlook 2007, 2010 et 2013.

Kutools for Outlook - Apporte 100 fonctionnalités avancées à Outlook et simplifie grandement le travail!

• CC / BCC automatique par des règles lors de l'envoi d'e-mails; Transfert automatique Emails multiples par coutume; Réponse automatique sans serveur d'échange, et plus de fonctionnalités automatiques ...
• Avertissement BCC - afficher le message lorsque vous essayez de répondre à tous si votre adresse e-mail est dans la liste BCC; Rappeler en cas de pièces jointes manquantes, et plus de fonctionnalités de rappel ...
• Répondre (à tous) avec toutes les pièces jointes dans la conversation par courrier électronique; Répondre à de nombreux e-mails en secondes; Ajouter un message d'accueil automatique quand répondre; Ajouter la date au sujet ...
• Outils de pièces jointes: gérer toutes les pièces jointes dans tous les courriers, Détachement automatique, Compresser tout, Tout renommer, Tout enregistrer ... Rapport rapide, Compter les courriers sélectionnésplus
• Courriels indésirables puissants par coutume; Supprimer les messages et contacts en doubleplus Vous permettre de faire plus intelligemment, plus rapidement et mieux dans Outlook.

Lire la suite... Télécharger maintenant...