Comment obtenir la liste des dossiers dans Outlook ?

Parfois, l’arborescence complète de tous les dossiers de messagerie — y compris les dossiers personnels que vous avez créés — s’avère particulièrement utile dans le volet de navigation Outlook pendant votre travail. Pour afficher rapidement cette arborescence en entier, un code VBA peut vous simplifier la tâche. Dans ce tutoriel, découvrez comment obtenir facilement la liste de tous vos dossiers à l’aide d’un simple code VBA.

Obtenir la liste des dossiers dans Outlook avec un code VBA

---

Obtenir la liste des dossiers dans Outlook avec un code VBA

Pour récupérer la liste des dossiers dans Outlook à l’aide d’un code VBA, suivez les étapes ci-dessous.

1. Appuyez sur les touches « Alt » + « F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

2. Double-cliquez ensuite sur « Projet1 » > « Objets Microsoft Outlook » > « ThisOutlookSession » pour ouvrir la fenêtre « Projet1 – ThisOutlookSession ». Voir la capture d’écran :

3. Copiez ensuite le code VBA ci-dessous et collez-le dans la fenêtre « Projet1 – ThisOutlookSession ».

VBA : obtenir la liste des dossiers dans Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Appuyez sur la touche « F5 » de votre clavier pour exécuter le code VBA.

5. La boîte de dialogue « Macro » s’ouvre maintenant ; cliquez sur le bouton « Exécuter ».

6. Attendez que la macro s’exécute. La liste de tous vos dossiers de messagerie s’affiche alors instantanément dans une nouvelle fenêtre de message. Vous pouvez l’imprimer facilement. Voir la capture d’écran :

Remarque : Ce code VBA est compatible avec Outlook 2007, 2010 et 2013.