Comment exporter et imprimer la liste complète de tous vos dossiers et sous-dossiers dans Outlook ?

Généralement, vous pouvez afficher la liste de tous les dossiers dans la navigation Outlook en appuyant sur les touches « Ctrl » + « 6 ». Toutefois, il n’est pas possible d’imprimer directement cette liste. Cet article présente deux scripts VBA permettant d’exporter et d’imprimer la liste complète des dossiers ainsi que leurs sous-dossiers depuis Outlook.

• Exporter et imprimer la liste de tous les dossiers Outlook et de leurs sous-dossiers dans Nouveau email
• Exporter et imprimer la liste de tous les dossiers Outlook et de leurs sous-dossiers dans le Bloc-notes

---

Exporter et imprimer la liste de tous les dossiers Outlook et de leurs sous-dossiers dans Nouveau email

Cette méthode utilise un script VBA pour exporter la liste complète des dossiers et de leurs sous-dossiers d’un compte de messagerie donné directement dans un nouvel e-mail Outlook, que vous pouvez ensuite imprimer facilement.

1. Appuyez sur « Alt » + « F11 » pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez sur « Insertion » > « Module », puis collez le code VBA ci-dessous dans la nouvelle fenêtre du module.

VBA : Exporter la liste des dossiers et sous-dossiers d’un Nouveau email dans Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Appuyez sur « F5 » pour exécuter le code VBA.

4. Dans la boîte de dialogue « Sélectionner un dossier » qui s’ouvre, choisissez le compte de messagerie dont vous souhaitez imprimer la liste des dossiers, puis cliquez sur « OK ».

5. La liste des dossiers du compte sélectionné sera insérée dans un nouvel e-mail, comme illustré ci-dessous. Cliquez sur « Fichier » > « Imprimer » pour imprimer cette liste.

6. Après avoir imprimé, fermez le nouveau message sans l’enregistrer.

---

Exporter et imprimer la liste de tous les dossiers Outlook et de leurs sous-dossiers dans le Bloc-notes

Cette méthode utilise un script VBA pour exporter, depuis Outlook, la liste complète des dossiers et sous-dossiers d’un compte de messagerie spécifié vers le Bloc-notes — une solution idéale pour une impression rapide et facile.

1. Appuyez sur « Alt » + « F11 » pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez sur « Insertion » > « Module », puis collez le code VBA suivant dans la nouvelle fenêtre du module.

VBA : Exporter la liste de tous les dossiers et sous-dossiers Outlook depuis Outlook vers le Bloc-notes

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Appuyez sur « F5 » pour exécuter le code VBA. Dans la boîte de dialogue « Sélectionner un dossier » qui s’ouvre, choisissez le compte de messagerie dont vous souhaitez exporter et imprimer la liste des dossiers, puis cliquez sur « OK ».

4. La boîte de dialogue « Arborescence des dossiers de sortie » s’ouvre. Cliquez sur « Oui » pour inclure l’indentation arborescente ou sur « Non » pour l’exclure.

Un Fichier texte nommé « Outlook-Folders » est désormais créé et enregistré sur votre bureau, comme illustré ci-dessous :

5. Double-cliquez pour ouvrir le nouveau fichier texte, puis cliquez sur « Fichier » > « Imprimer » afin d’imprimer la liste des dossiers Outlook exportée.

Articles associés

Afficher ou masquer la vue en liste des dossiers dans Outlook