Comment faire pour que tous les dossiers se développent automatiquement au démarrage d’Outlook ?

Généralement, lorsque vous développez ou réduisez un dossier dans le volet de navigation d’Outlook, puis fermez le programme, ce dossier conserve son état (développé ou réduit) au prochain démarrage. Mais comment faire si vous souhaitez que tous les dossiers soient automatiquement développés à chaque lancement d’Outlook ? Cet article vous propose une solution VBA pour y parvenir.

Développer tous les dossiers automatiquement au démarrage d’Outlook à l’aide de VBA

---

Développer tous les dossiers automatiquement au démarrage d’Outlook à l’aide de VBA

Ce guide explique comment utiliser un script VBA pour développer automatiquement tous les dossiers dans le volet de navigation à chaque ouverture d’Outlook. Suivez ces étapes pour implémenter le script VBA :

1. Appuyez simultanément sur les touches Alt + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.
2. Développez le nœud Projet 1et Objets Microsoft Outlookdans le volet Projet, double-cliquez pour ouvrir la fenêtre ThisOutlookSession, puis collez le code VBA ci-dessous à l’intérieur.

   

   VBA : Développer tous les dossiers automatiquement dans Outlook

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Enregistrez le code et fermez la fenêtre Microsoft Visual Basic pour Applications.

Désormais, tous les dossiers seront automatiquement dépliés au redémarrage d’Outlook.

---

Articles associés