Comment enregistrer un e-mail au format image (JPG/TIFF) dans Outlook ?

Avez-vous déjà tenté d’enregistrer un e-mail sous forme d’image, par exemple au format JPG ou TIFF, directement depuis Outlook ? Cet article vous propose une solution efficace pour y parvenir.

Enregistrer un message électronique au format image à l’aide d’un code VBA

---

Enregistrer un message électronique au format image à l’aide d’un code VBA

Voici la marche à suivre pour enregistrer un e-mail au format image dans Outlook.

1. Sélectionnez un e-mail que vous souhaitez enregistrer sous forme d’image, puis appuyez simultanément sur les touches Alt + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Dans la fenêtre Microsoft Visual Basic pour Applications, cliquez sur Insertion > UserForm. Voir la capture d’écran :

3. Créez un UserForm comme indiqué dans la capture d’écran ci-dessous.

4. Sélectionnez le bouton d’option jpg, puis modifiez son nom en opbJPG dans le volet gauche Propriétés.

5. Répétez l’étape précédente 4 pour renommer les autres boutons d’option en opbTIFF. Renommez également le bouton de commande OK et le bouton de commande Annuler respectivement en cdbOk et cdbCancel.

Remarque : Si le volet Propriétés n’apparaît pas dans la fenêtre Microsoft Visual Basic pour Applications, appuyez sur la touche F4 pour afficher ce volet.

6. Double-cliquez sur un espace vide du formulaire utilisateur pour ouvrir la fenêtre Code. Remplacez l’intégralité du code par le script VBA suivant, puis fermez la fenêtre Code.

Code VBA 1 : Enregistrer un message électronique sous forme d’image

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. Sélectionnez le UserForm1 et renommez-le en FrmPicType dans le volet Propriétés, comme indiqué dans la capture d’écran ci-dessous.

8. Cliquez sur Insertion > Module, puis copiez le code VBA ci-dessous dans la fenêtre du module.

Code VBA 2 : Enregistrer un message électronique sous forme d’image

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. Cliquez sur Outils > Références, cochez la case Microsoft PowerPoint Object Library, puis cliquez sur le bouton OK. Voir la capture d’écran :

10. Appuyez sur la touche F5 pour exécuter le code. La boîte de dialogue UserForm1 s’affiche alors. Veuillez sélectionner un type d’image, puis cliquer sur le bouton OK. Voir la capture d’écran :

11. Dans la boîte de dialogue Parcourir les dossiers, spécifiez le dossier dans lequel enregistrer l’image, puis cliquez sur le bouton OK.

12. Enfin, une boîte de dialogue Microsoft Outlook s’affiche pour vous informer de la fin de l’enregistrement. Cliquez sur le bouton OK.

Les e-mails sélectionnés ont été convertis avec succès en images JPG ou TIFF et enregistrés dans le dossier spécifié.

---

Articles associés :

• Comment enregistrer toutes les pièces jointes de plusieurs e-mails dans un même dossier sous Outlook ?
• Comment supprimer toutes les pièces jointes d’un e-mail dans Outlook ?