Comment créer des rappels Outlook à partir d’une feuille de calcul Excel ?

Cet article explique comment créer des rappels Outlook à partir des données d’une feuille de calcul Excel.

Créer des rappels Outlook à partir d’une feuille de calcul Excel avec du code VBA

---

Créer des rappels Outlook à partir d’une feuille de calcul Excel avec du code VBA

Pour créer des rappels Outlook à partir d’Excel, suivez ces étapes.

1. Créez une feuille de calcul comprenant les en-têtes de colonnes et les champs de rappel correspondants, comme le montre la capture d’écran ci-dessous.

Remarque : dans la colonne « Statut d’occupation », le chiffre « 2 » fait apparaître le rappel comme « Occupé » dans votre calendrier Outlook. Vous pouvez le remplacer par « 1 (Provisoire) », « 3 (Absent du bureau) », « 4 (Travail ailleurs) » ou « 5 (Libre) » selon vos besoins.

2. Appuyez sur les touches « Alt » + « F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

3. Dans la fenêtre « Microsoft Visual Basic pour Applications », cliquez sur « Insertion » > « Module », puis copiez le code VBA suivant dans la fenêtre de code.

Code VBA : Créer des rappels Outlook à partir d’une feuille de calcul Excel

Sub AddAppointments()
'Update by Extendoffice 20180608
    Dim I As Long
    Dim xRg As Range
    Dim xOutApp As Object
    Dim xOutItem As Object
    Set xOutApp = CreateObject("Outlook.Application")
    Set xRg = Range("A2:G2")
    For I = 1 To xRg.Rows.Count
        Set xOutItem = xOutApp.CreateItem(1)
        Debug.Print xRg.Cells(I, 1).Value
        xOutItem.Subject = xRg.Cells(I, 1).Value
        xOutItem.Location = xRg.Cells(I, 2).Value
        xOutItem.Start = xRg.Cells(I, 3).Value
        xOutItem.Duration = xRg.Cells(I, 4).Value
        If Trim(xRg.Cells(I, 5).Value) = "" Then
            xOutItem.BusyStatus = 2
        Else
            xOutItem.BusyStatus = xRg.Cells(I, 5).Value
        End If
        If xRg.Cells(I, 6).Value > 0 Then
            xOutItem.ReminderSet = True
            xOutItem.ReminderMinutesBeforeStart = xRg.Cells(I, 6).Value
        Else
            xOutItem.ReminderSet = False
        End If
        xOutItem.Body = xRg.Cells(I, 7).Value
        xOutItem.Save
        Set xOutItem = Nothing
    Next
    Set xOutApp = Nothing
End Sub

Remarque : dans le code ci-dessus, « A2:G2 » correspond à la plage de données à partir de laquelle vous souhaitez créer des rendez-vous.

4. Appuyez sur « F5 » ou cliquez sur le bouton « Exécuter » pour lancer le code : tous les rendez-vous comportant les champs spécifiés seront alors ajoutés en un seul clic à votre calendrier Outlook.

Vous pourrez ensuite accéder au calendrier de votre Outlook afin de visualiser les résultats. Voir la capture d’écran :