Comment exporter les contacts avec leurs photos depuis Outlook ?

Lorsque vous exportez des contacts depuis Outlook vers un fichier, seules les informations textuelles sont prises en compte. Pourtant, il peut s’avérer utile d’exporter également les photos associées à ces contacts. Comment procéder dans Outlook ?

Exporter les informations des contacts avec leurs photos à l’aide d’un code VBA

---

Exporter les informations des contacts avec leurs photos à l’aide d’un code VBA

Le code VBA ci-dessous vous permet d’exporter tous les contacts d’un dossier de contacts spécifique vers des fichiers texte distincts, incluant également leurs photos. Procédez comme suit :

1. Sélectionnez le dossier de contacts dont vous souhaitez exporter les contacts avec leurs photos.

2. Ensuite, maintenez enfoncées les touches « ALT » + « F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

3. Cliquez ensuite sur « Insertion » > « Module », puis copiez-collez le code ci-dessous dans le module vide qui s’ouvre. Voir la capture d’écran :

Code VBA : exporter les informations des contacts avec leurs photos

Sub BatchExportContactPhotosandInformation()
Dim xContactItems As Outlook.Items
Dim xItem As Object
Dim xContactItem As ContactItem
Dim xContactInfo As String
Dim xShell As Object
Dim xFSO As Scripting.FileSystemObject
Dim xTextFile As Scripting.TextStream
Dim xAttachments As Attachments
Dim xAttachment As Attachment
Dim xSavePath, xEmailAddress As String
Dim xFolder As Outlook.Folder
On Error Resume Next
Set xFSO = CreateObject("Scripting.FileSystemObject")
Set xShell = CreateObject("Shell.application").BrowseforFolder(0, "Select a Folder", 0, 16)
If xShell Is Nothing Then Exit Sub
xSavePath = xShell.Items.Item.Path & "\"
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    Set xFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
Else
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
End If
Set xContactItems = xFolder.Items
For i = xContactItems.Count To 1 Step -1
    Set xItem = xContactItems.Item(i)
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        With xContactItem
            xEmailAddress = .Email1Address
            If Len(Trim(.Email2Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email2Address
            End If
            If Len(Trim(.Email3Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email3Address
            End If
            xContactInfo = "Name: " & .FullName & vbCrLf & "Email: " & _
                           xEmailAddress & vbCrLf & "Company: " & .CompanyName & _
                           vbCrLf & "Department: " & .Department & _
                           vbCrLf & "Job Title: " & .JobTitle & _
                           vbCrLf & "IM: " & .IMAddress & _
                           vbCrLf & "Business Phone: " & .BusinessTelephoneNumber & _
                           vbCrLf & "Home Phone: " & .HomeTelephoneNumber & _
                           vbCrLf & "BusinessFax Phone: " & .BusinessFaxNumber & _
                           vbCrLf & "Mobile Phone: " & .MobileTelephoneNumber & _
                           vbCrLf & "Business Address: " & .BusinessAddress
            Set xTextFile = xFSO.CreateTextFile(xSavePath & .FullName & ".txt", True)
            xTextFile.WriteLine xContactInfo
            If .Attachments.Count > 0 Then
                Set xAttachments = .Attachments
                For Each xAttachment In xAttachments
                    If InStr(LCase(xAttachment.FileName), "contactpicture.jpg") > 0 Then
                        xAttachment.SaveAsFile (xSavePath & .FullName & ".jpg")
                    End If
                Next
            End If
        End With
    End If
Next i
End Sub

4. Après avoir collé le code dans le module, cliquez sur « Outils » > « Références » dans la fenêtre « Microsoft Visual Basic pour Applications ». Dans la boîte de dialogue « Références – Projet1 » qui s’ouvre, cochez l’option « Microsoft Scripting Runtime » dans la liste des « Références disponibles ». Voir la capture d’écran :

5. Cliquez sur « OK » pour fermer la boîte de dialogue, puis appuyez sur la touche « F5 » pour exécuter le code. Dans la boîte de dialogue « Parcourir les dossiers » qui s’ouvre, sélectionnez le dossier où vous souhaitez enregistrer les contacts exportés. Voir la capture d’écran :

6. Cliquez ensuite sur « OK ». Toutes les informations de vos contacts, accompagnées de leurs photos, ont été exportées dans le dossier que vous avez spécifié. Voir la capture d’écran :