Comment rechercher et remplacer le texte de l’objet dans les messages ou les tâches dans Outlook ?

Dans Outlook, si plusieurs objets de messages ou d’éléments de tâches doivent être remplacés par un texte que vous spécifiez, vous pouvez bien sûr les modifier un par un, mais existe-t-il un moyen rapide d’effectuer cette opération en une seule fois dans Outlook ?

Rechercher et remplacer le texte de l’objet dans plusieurs messages à l’aide d’un code VBA

Rechercher et remplacer le texte de l’objet dans plusieurs tâches à l’aide d’un code VBA

---

Rechercher et remplacer le texte de l’objet dans plusieurs messages à l’aide d’un code VBA

Pour rechercher un texte spécifique et le remplacer par un autre dans les objets de plusieurs messages, le code VBA ci-dessous vous sera d’une grande aide. Suivez simplement les étapes suivantes :

1. Sélectionnez les courriels dont vous souhaitez rechercher et remplacer le texte de l’objet, puis appuyez simultanément sur les touches « Alt + F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

2. Cliquez ensuite sur « Insertion » > « Module », puis copiez-collez le code ci-dessous dans le module vide qui s’ouvre. Voir la capture d’écran :

Code VBA : Rechercher et remplacer le texte de l’objet dans plusieurs messages :

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

Remarques : Dans le code ci-dessus, `xNewSubject = Replace(.Subject, «kte», «[[PH_8]]»)`, « kte » correspond à l’ancien texte que vous souhaitez rechercher, et « Kutools pour Excel » est le nouveau texte par lequel vous souhaitez le remplacer. Adaptez-les selon vos besoins.

3. Appuyez ensuite sur la touche « F5 » pour exécuter ce code. Le texte spécifique figurant dans les objets des messages sera alors remplacé par le nouveau texte, selon vos besoins. Voir la capture d’écran :

---

Rechercher et remplacer le texte de l’objet dans plusieurs tâches à l’aide d’un code VBA

Si vous devez rechercher et remplacer du texte dans des objets de tâches, le code VBA suivant peut également vous être utile.

1. Maintenez enfoncées les touches « ALT + F11 » pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez ensuite sur « Insertion » > « Module », puis copiez-collez le code ci-dessous dans le module vide qui s’ouvre. Voir la capture d’écran :

Code VBA : Rechercher et remplacer le texte de l’objet dans toutes les tâches :

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. Appuyez ensuite sur la touche « F5 » pour exécuter ce code. Une boîte de dialogue s’affiche alors : saisissez-y le texte que vous souhaitez rechercher dans les objets des tâches. Voir la capture d’écran :

4. Cliquez sur « OK », puis, dans la nouvelle boîte de dialogue qui s’affiche, saisissez le nouveau texte par lequel vous souhaitez effectuer le remplacement. Voir la capture d’écran :

5. Cliquez ensuite sur « OK ». Une boîte de dialogue s’affiche alors pour vous indiquer le nombre d’objets modifiés. Voir la capture d’écran :

6. Cliquez sur « OK » ; l’ancien texte dans les objets des tâches sera remplacé par le nouveau texte. Voir la capture d’écran :