Comment envoyer un calendrier à plusieurs destinataires, individuellement, dans Outlook ?

Généralement, vous pouvez envoyer rapidement et facilement un calendrier à un destinataire grâce à la fonctionnalité Envoyer le calendrier par e-mail d’Outlook. Si vous souhaitez transmettre un calendrier sous forme de fichier iCalendar joint à plusieurs contacts individuellement, vous devez l’envoyer un par un. Dans cet article, je vous présente une méthode simple pour envoyer un calendrier à plusieurs destinataires individuellement dans Outlook.

Envoyer un calendrier à plusieurs destinataires individuellement avec du code VBA

---

Envoyer un calendrier à plusieurs destinataires individuellement avec du code VBA

Pour envoyer un calendrier à plusieurs destinataires de manière individuelle, le code VBA suivant vous sera utile. Suivez ces étapes :

1. Accédez au volet Contacts, puis sélectionnez les contacts auxquels vous souhaitez envoyer le calendrier.

2. Maintenez ensuite enfoncées les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

3. Cliquez sur Insertion > Module, puis copiez et collez le code ci-dessous dans le module vide qui s’ouvre (voir capture d’écran) :

Code VBA : Envoyer un calendrier à plusieurs destinataires individuellement :

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Après avoir inséré le code, appuyez sur la touche F5 pour exécuter ce code. Une boîte de dialogue Sélectionner un dossier s’ouvre alors ; veuillez sélectionner le calendrier que vous souhaitez envoyer (voir capture d’écran).

5. Cliquez sur OK, puis indiquez la plage de dates à laquelle vous souhaitez associer le calendrier dans les boîtes de dialogue suivantes (voir capture d’écran).

6. Ensuite, cliquez sur OK. Des messages « Nouveau courriel » avec le calendrier en pièce jointe sont alors créés, comme illustré dans la capture d’écran suivante. Il ne vous reste plus qu’à les envoyer un par un.

---

Articles associés :

Comment envoyer un e-mail à plusieurs destinataires individuellement dans Outlook ?

Comment envoyer des e-mails personnalisés en masse à partir d’une liste Excel via Outlook ?

Comment envoyer plusieurs brouillons en même temps dans Outlook ?

Comment envoyer un e-mail à plusieurs destinataires sans qu’ils le sachent dans Outlook ?