Comment transférer automatiquement uniquement les pièces jointes selon des critères spécifiques dans Outlook ?

Normalement, lors de la transmission d’un courrier électronique, le corps du message d’origine et les pièces jointes sont inclus. Toutefois, il arrive parfois que vous souhaitiez transmettre uniquement les pièces jointes, sans le message d’origine, selon certains critères, à une personne précise. Comment réaliser cette tâche dans Outlook ?

Transmettre automatiquement uniquement les pièces jointes en fonction de critères spécifiques à une personne à l’aide d’un code VBA

---

Transmettre automatiquement uniquement les pièces jointes en fonction de critères spécifiques à une personne à l’aide d’un code VBA

Par exemple, lorsqu’un courrier électronique contenant le texte « kto feature » est reçu, toutes ses pièces jointes seront automatiquement transmises à la personne concernée, sans inclure le corps du message. Les étapes suivantes peuvent vous aider ; veuillez procéder comme suit :

1. Maintenez enfoncées les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Dans la fenêtre Microsoft Visual Basic pour Applications, double-cliquez sur ThisOutlookSession dans le volet Projet1 (VbaProject.OTM) afin d’ouvrir le module, puis copiez-collez le code suivant dans ce module vierge.

Code VBA : Transfert automatique un courrier électronique sans corps de message, en incluant uniquement les pièces jointes :

Public WithEvents ReceivedItems As Outlook.Items
Private Sub Application_Startup()
    Set ReceivedItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub ReceivedItems_ItemAdd(ByVal Item As Object)
    Dim xForwardMail As Outlook.MailItem
    Dim xEmail As MailItem
    On Error Resume Next
    If Item.Class <> olMail Then Exit Sub
    Set xEmail = Item
    If InStrRev(UCase(xEmail.Subject), UCase("kto feature")) = 0 Then Exit Sub  'change subject text to your need
    If xEmail.Attachments.Count = 0 Then Exit Sub
    Set xForwardMail = xEmail.Forward
    With xForwardMail
        .HTMLBody = ""
        With .Recipients
            .Add "skyyang@addin88.com"    'change address to your own
            .ResolveAll
        End With
        .Send
    End With
End Sub

Remarque : Dans le code ci-dessus, remplacez le texte de l’objet et l’adresse du destinataire par les vôtres.

3. Ensuite, enregistrez le code et redémarrez Outlook pour que les modifications prennent effet.

4. Désormais, chaque fois qu’un nouvel e-mail contenant l’objet spécifié arrivera dans votre boîte de réception, Outlook transférera automatiquement ses pièces jointes — sans le corps du message — à la personne de votre choix.

Remarque : Ce code fonctionne uniquement avec le compte Compte par défaut.