Comment faire pour que la signature dans Outlook change automatiquement en fonction des destinataires ?

Par défaut, Outlook dispose d’une fonction intégrée permettant aux utilisateurs de changer automatiquement la signature lors de l’envoi d’e-mails via différents comptes de messagerie. Au-delà de cette fonctionnalité, je vais vous montrer ici une méthode permettant de modifier automatiquement la signature en fonction des destinataires présents dans le champ À dans Outlook.

Modifier automatiquement la signature en fonction des destinataires à l’aide d’un code VBA

---

Modifier automatiquement la signature en fonction des destinataires à l’aide d’un code VBA

Veuillez suivre les étapes ci-dessous pour appliquer des signatures différentes aux destinataires concernés lors de l’envoi d’e-mails dans Outlook.

1. Tout d’abord, désactivez la fonction d’ajout automatique de signature dans Outlook. Cliquez sur Fichier > Options pour ouvrir la fenêtre Options Outlook.

2. Dans la fenêtre Options Outlook, sélectionnez Courrier dans le volet gauche, puis cliquez sur le bouton Signatures dans la section Rédiger des messages. Voir la capture d’écran :

3. Dans la boîte de dialogue Signatures et papier à lettres, accédez à la section Choisir la signature par défaut sous l’onglet Signature de courrier électronique. Sélectionnez un compte de messagerie dans la liste déroulante Compte de messagerie, puis choisissez (aucune) dans les listes déroulantes Nouveaux messages et Réponses/transmissions. Répétez ces étapes jusqu’à ce que tous les comptes soient définis sur (aucune), puis cliquez sur le bouton OK.

Remarque : vous pouvez également créer les signatures de votre choix dans cette boîte de dialogue Signatures et papier à lettres.

4. Cliquez sur le bouton OK lorsque vous revenez à la fenêtre Options Outlook.

5. Appuyez sur les touches Alt + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

6. Dans la fenêtre Microsoft Visual Basic pour Applications, double-cliquez sur ThisOutlookSession dans le volet gauche pour ouvrir la fenêtre de code, puis y copiez le code VBA ci-dessous. Voir la capture d’écran :

Code VBA : Modifier automatiquement la signature en fonction des destinataires dans Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Remarques:

• 1). Dans le code VBA, veuillez remplacer «Adresse e-mail 1/2/3/4» par l’adresse e-mail spécifique des destinataires.
• 2). «aaa.htm», «bbb.htm» et «ccc.htm» sont les signatures que vous avez spécifiées et que vous enverrez aux destinataires correspondants.
• 3). Dans ce cas, la signature «aaa» sera envoyée à «Adresse e-mail 1», la signature «bbb» sera envoyée à «Adresse e-mail 2» et à «Adresse e-mail 3», et la signature «ccc» sera intégrée aux e-mails destinés à «Adresse e-mail 4». Veuillez les adapter selon vos besoins.
• 4). Si un e-mail comporte plusieurs destinataires, le code ne prend en compte que le premier. Les autres destinataires reçoivent alors des e-mails dotés de la même signature que celle du premier destinataire.

7. Cliquez ensuite sur Outils > Références pour accéder à la boîte de dialogue Références – Projet. Dans cette boîte de dialogue, cochez à la fois les options Microsoft Word Object Library et Microsoft Scripting Runtime, puis cliquez sur le bouton OK. Voir la capture d’écran :

8. Appuyez sur les touches Alt + Q pour fermer la fenêtre Microsoft Visual Basic pour Applications.

Désormais, après avoir rédigé un e-mail et cliqué sur le bouton Envoyer, la signature correspondante sera automatiquement insérée à la fin du corps de l’e-mail en fonction de l’Adresse e-mail du destinataire figurant dans le champ À.

---