Comment exporter la structure des dossiers Outlook vers Excel ?

Dans cet article, découvrez comment exporter la structure des dossiers d’un compte Outlook vers un fichier Excel. Suivez simplement les instructions détaillées ci-dessous.

Exporter Structure du dossier d’un compte d’Outlook vers Excel à l’aide d’un code VBA

---

Exporter Structure du dossier d’un compte d’Outlook vers Excel à l’aide d’un code VBA

Le code VBA suivant pourrait vous être utile. Suivez simplement les étapes ci-dessous :

1. Ouvrez Excel et maintenez enfoncées les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez sur Insertion > Module, puis collez le code suivant dans la fenêtre du Module.

Code VBA : Exporter Structure du dossier d’un compte d’Outlook vers Excel :

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Toujours dans la fenêtre Microsoft Visual Basic pour Applications, cliquez sur Outils>Référencespour accéder à la boîte de dialogue Références – Projet1, puis cochez l’option Microsoft Excel Object Librarydans la liste des Références disponibles, comme illustré ci-dessous :

4. Cliquez ensuite sur le bouton OK, puis appuyez sur la touche F5 pour exécuter ce code. Une boîte de dialogue Sélectionner un dossier s’ouvre ; veuillez sélectionner le compte de messagerie dont vous souhaitez exporter la structure des dossiers, comme illustré ci-dessous :

5. Ensuite, cliquez sur le bouton OK : la fenêtre Enregistrer le fichier s’affiche. Indiquez un emplacement et un nom de fichier pour ce fichier exporté, comme illustré ci-dessous :

6. Enfin, cliquez sur le bouton Enregistrer, puis rendez-vous dans le classeur Excel spécifié où vous avez enregistré le fichier afin de consulter la structure du dossier exporté, comme illustré ci-dessous :