Comment configurer Outlook pour signaler automatiquement les e-mails contenant une pièce jointe spécifique ?

Lorsque vous recevez certains e-mails contenant une pièce jointe importante spécifique, il peut être utile de les signaler afin de les retrouver rapidement et facilement pour un suivi. Dans cet article, je vous présente une méthode simple pour signaler automatiquement les e-mails dont les pièces jointes portent des noms spécifiques.

Signaler automatiquement des e-mails en fonction d’une pièce jointe spécifique à l’aide d’un code VBA

---

Signaler automatiquement des e-mails en fonction d’une pièce jointe spécifique à l’aide d’un code VBA

Pour signaler automatiquement les e-mails contenant une pièce jointe spécifique, appliquez le code VBA suivant :

1. Lancez Outlook, puis maintenez enfoncées les touches « ALT + F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

2. Dans la fenêtre « Microsoft Visual Basic pour Applications », double-cliquez sur « ThisOutlookSession » dans le volet « Projet1 (VbaProject.OTM) » pour ouvrir un nouveau module, puis copiez-collez le code suivant dans ce module vide.

Code VBA : Signaler automatiquement les e-mails en fonction d’une pièce jointe spécifique :

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Remarque : dans le code ci-dessus, vous pouvez adapter l’extension du fichier et le nom de la pièce jointe à vos besoins.

3. Ensuite, enregistrez le code et redémarrez Outlook pour que celui-ci prenne effet. Désormais, lors de la réception d’e-mails dont les noms des pièces jointes contiennent le texte spécifié, Outlook signalera automatiquement ces e-mails pour suivi, comme illustré ci-dessous :