Comment conserver la catégorie d’un e-mail lors de sa réponse ou de sa transmission dans Outlook ?

Normalement, lorsque vous répondez ou transmettez un e-mail que vous avez catégorisé, la catégorie est automatiquement supprimée de l’e-mail envoyé. Si vous souhaitez conserver la catégorie sur les e-mails sortants lors d’une réponse ou d’une transmission, cet article présente une méthode pour y parvenir.

Conserver la catégorie lors de la réponse ou de la transmission d’un e-mail à l’aide d’un code VBA

---

Conserver la catégorie lors de la réponse ou de la transmission d’un e-mail à l’aide d’un code VBA

1. Maintenez enfoncées les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic for Applications.

2. Dans la fenêtre Microsoft Visual Basic for Applications, double-cliquez sur ThisOutlookSession située dans le volet Project1 (VbaProject.OTM) pour ouvrir le module, puis copiez et collez le code suivant dans ce module vierge.

Code VBA : conserver la catégorie lors de la réponse ou de la transmission d’un e-mail :

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Ensuite, sauvegardez et fermez cette fenêtre de code, puis quittez et redémarrez Outlook. Désormais, lorsque vous répondez ou transmettez un e-mail comportant une catégorie, celle-ci sera conservée dans le message sortant figurant dans le dossier Éléments envoyés, comme illustré dans la capture d’écran suivante :