Outlook : comment renvoyer automatiquement un e-mail en l’absence de réponse

Lorsque vous envoyez un e-mail à un collègue, à un partenaire ou à toute autre personne et que vous avez besoin d’une réponse urgente, configurez une relance automatique pour qu’elle soit déclenchée si aucune réponse n’est reçue avant l’heure indiquée.

Utiliser le rappel et VBA pour configurer un renvoi automatique en l’absence de réponse

---

Utiliser le rappel et VBA pour configurer un renvoi automatique en l’absence de réponse

Partie 1 : définir un rappel à une heure spécifiée

1. Cliquez avec le bouton droit sur un e-mail issu du dossier « Éléments envoyés » que vous souhaitez renvoyer en l’absence de réponse, puis sélectionnez « Suivi » > « Ajouter un rappel » dans le menu contextuel.

2. Dans la boîte de dialogue « Personnalisé » qui s’ouvre, assurez-vous que la case à cocher « Rappel » est activée, puis sélectionnez dans les listes déroulantes situées en dessous la date et l’heure avant lesquelles vous souhaitez recevoir une réponse. Vous pouvez également saisir directement ces informations dans les champs prévus à cet effet. Cliquez ensuite sur « OK ».

Partie 2 : insérer une macro VBA pour renvoyer les e-mails en l’absence de réponse au-delà du délai spécifié

3. Appuyez sur les touches « Alt » + « F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

4. Double-cliquez sur « ThisOutlookSession » dans le volet « Projet – Projet1 » pour créer un script vierge, puis copiez-collez le code VBA ci-dessous dans ce script.

VBA : renvoyer un e-mail en l’absence de réponse

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Enregistrez le code, puis revenez à l’interface principale. Cliquez sur « Fichier » > « Options », sélectionnez « Centre de gestion de la confidentialité » dans le volet gauche de la fenêtre « Options Outlook », puis cliquez sur « Paramètres du Centre de gestion de la confidentialité ». Dans la fenêtre qui s’ouvre, cliquez sur « Paramètres des macros » et assurez-vous que l’option « Activer toutes les macros (non recommandé ; du code potentiellement dangereux peut s’exécuter) » est sélectionnée dans la section de droite. Cliquez ensuite sur « OK » > « OK ».

6. Désormais, lorsqu’un e-mail associé à un rappel n’a reçu aucune réponse au moment où l’heure spécifiée est atteinte, une boîte de dialogue s’affiche pour vous proposer de renvoyer un message de relance au destinataire.

7. Cliquez sur « Oui » : une fenêtre de message s’ouvre, contenant l’e-mail précédent en pièce jointe. Vous pouvez alors modifier le corps du message et cliquer sur « Envoyer » pour le renvoyer.

8. Cliquez sur « Non » : le rappel sera alors supprimé.

Remarque : si l’e-mail a été répondu avant l’heure indiquée, le rappel sera automatiquement supprimé par la macro VBA.