Comment importer des anniversaires depuis Excel vers le calendrier Outlook ?

Si vous disposez d’une longue liste d’informations relatives à des anniversaires dans une feuille de calcul et que vous souhaitez désormais les importer dans votre calendrier Outlook en tant qu’événements, comment accomplir cette tâche rapidement ?

---

Importer des anniversaires depuis Excel vers le calendrier Outlook à l’aide d’un code VBA

En règle générale, il n’existe pas de méthode directe pour importer les anniversaires dans le calendrier Outlook. Je vais donc créer un code VBA pour résoudre ce problème. Suivez les étapes ci-dessous :

1. Ouvrez la feuille de calcul contenant les anniversaires que vous souhaitez importer dans Outlook, puis appuyez simultanément sur les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez sur Insertion > Module, puis collez le code suivant dans la fenêtre du module.

Code VBA : Importer des anniversaires dans le calendrier Outlook

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Toujours dans la fenêtre Microsoft Visual Basic pour Applications, cliquez sur Outils > Références. Dans la boîte de dialogue Références – VBAProject qui s’ouvre, cochez l’option Microsoft Outlook 16,0 Object Library dans la zone de liste Références disponibles, comme illustré ci-dessous :

4. Cliquez ensuite sur OK pour fermer cette boîte de dialogue. Appuyez maintenant sur la touche F5 pour exécuter ce code. Une boîte de dialogue s’affiche alors, vous invitant à sélectionner les colonnes contenant les noms et les dates d’anniversaire, comme illustré ci-dessous :

5. Cliquez ensuite sur le bouton OK, et les anniversaires seront immédiatement importés dans votre calendrier Outlook. Vous pourrez alors ouvrir Outlook pour consulter le résultat, comme illustré ci-dessous :