Outlook : comment conserver une réunion annulée dans le calendrier en tant qu’organisateur ?

Dans Outlook, en tant qu’organisateur d’une réunion, son annulation entraîne sa suppression automatique du calendrier. Toutefois, il peut arriver que vous souhaitiez conserver cette réunion annulée dans votre calendrier afin d’y ajouter des annotations. Malheureusement, Outlook ne propose pas de fonctionnalité intégrée à cet effet. Ce tutoriel vous présente deux scripts VBA permettant de transformer la réunion annulée en simple rendez-vous, tout en conservant son entrée dans le calendrier.

Codes VBA pour copier une réunion annulée en tant que rendez-vous

---

Codes VBA pour copier une réunion annulée en tant que rendez-vous

Voici deux codes qui permettent d’annuler une réunion tout en la copiant et en la collant simultanément sous forme de rendez-vous.

Remarque : avant d’activer le code, veillez à cocher les deux options suivantes :

Ouvrez Outlook, cliquez sur Fichier > Options. Dans la fenêtre Options d’Outlook, cliquez sur l’onglet Centre de gestion de la confidentialité, puis sur Paramètres du Centre de gestion de la confidentialité. Dans la fenêtre Centre de gestion de la confidentialité, cliquez sur Paramètres des macros, cochez Activer toutes les macros (non recommandé ; du code potentiellement dangereux peut s’exécuter) et Appliquer les paramètres de sécurité des macros aux compléments installés. Cliquez sur OK > OK pour fermer cette fenêtre. Redémarrez Outlook.

1. Basculez vers la vue Calendrier d’Outlook et sélectionnez la réunion que vous souhaitez annuler. Appuyez sur Alt+F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez sur Insertion > Module afin d’insérer un nouveau module vide. Copiez ensuite le code ci-dessous et collez-le dans ce module.

Code : copier une réunion en tant que rendez-vous et l’annuler

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. Cliquez sur le bouton Exécuter ou appuyez sur la touche F5. La réunion sélectionnée est désormais annulée, et un rendez-vous intitulé « Annulée & objet » a été créé.

Si vous souhaitez copier et coller la réunion en tant que rendez-vous dans un autre calendrier, puis annuler la réunion, utilisez le code ci-dessous :

Code : copier une réunion en tant que rendez-vous dans un autre calendrier et l’annuler

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

Cliquez sur le bouton Exécuter ou appuyez sur la touche F5. Une boîte de dialogue « Sélectionner un dossier » s’ouvre, vous permettant de choisir un dossier de calendrier dans lequel coller le rendez-vous. Cliquez ensuite sur OK.

La réunion a désormais été annulée et copiée-collée en tant que rendez-vous dans le dossier de calendrier que vous avez choisi.