Passer au contenu principal

Compter des valeurs numériques ou des dates uniques dans une colonne

En supposant que vous ayez une liste de nombres contenant des doublons, vous souhaitez maintenant compter le nombre de valeurs uniques ou les valeurs n'apparaissent qu'une seule fois dans la liste, comme illustré ci-dessous. Dans cet article, nous allons parler de quelques formules utiles pour résoudre cette tâche dans Excel rapidement et facilement.


Compter des valeurs numériques ou des dates uniques dans une colonne dans Excel 2019, 2016 et versions antérieures

Si vous utilisez Excel 2019, 2016 et des versions antérieures, vous pouvez appliquer les fonctions normales SUM, FREQUENCY, IF, COUNTIF, ISNUMBER pour obtenir le nombre de valeurs uniques ou les valeurs qui ne se produisent qu'une seule fois.

Compter des valeurs numériques ou des dates uniques dans une colonne

Pour compter les nombres uniques d'une liste, les fonctions SOMME et FRÉQUENCE peuvent vous rendre service, la syntaxe générique est :

=SUM(--(FREQUENCY(range,range)>0))
  • range: la colonne de données à partir de laquelle vous souhaitez compter les valeurs uniques.

Veuillez entrer ou copier la formule suivante dans une cellule vide pour afficher le résultat, puis appuyez sur Entrer clé pour obtenir le résultat:

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))


Explication de la formule:

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))

  • FRÉQUENCE(A2:A12,A2:A12): La fonction FREQUENCE renvoie le nombre de chaque valeur numérique dans la liste A2:A12, et elle obtiendra un tableau comme celui-ci : {1;2;0;2;0;1;1;3;0;0;1; 0}. Les nombres dans le tableau indiquent combien de fois les valeurs apparaissent dans la colonne. Et le nombre 0 dans le tableau signifie que les nombres sont déjà apparus dans la plage de données.
  • --(FREQUENCY(A2:A12,A2:A12)>0=--({1;2;0;2;0;1;1;3;0;0;1;0})>0: Chaque valeur du tableau sera comparée à zéro : si supérieure à 0, un VRAI est affiché, sinon, un FAUX est affiché. Et puis, le double signe négatif convertit les VRAI et FAUX en 1 et 0, donc, il renverra le résultat comme ceci : {1;1;0;1;0;1;1;1;0;0;1; 0}.
  • SUM(--(FREQUENCY(A2:A12,A2:A12)>0))=SUM({1;1;0;1;0;1;1;1;0;0;1;0}): Enfin, la fonction SUM additionne toutes les valeurs du tableau et obtient le résultat : 7.

Compter des valeurs numériques ou des dates uniques qui n'apparaissent qu'une seule fois dans une colonne

Comptez les valeurs numériques uniques qui n'apparaissent qu'une seule fois dans une liste, vous devez combiner les fonctions SUM, IF, ISNUMBER et COUNTIF pour créer la formule, la syntaxe générique est :

{=SUM(IF(ISNUMBER(range)*COUNTIF(range,range)=1,1,0))}
Array formula, should press Ctrl + Shift + Enter keys together.
  • range: la colonne de données à partir de laquelle vous souhaitez compter les valeurs uniques.

Maintenant, veuillez entrer ou copier la formule ci-dessous dans une cellule vide, puis appuyez sur Ctrl + Maj + Entrée touches simultanément pour obtenir le résultat correct :

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))


Explication de la formule:

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

  • ESTNUM(A2:A12): Cette fonction ISNUMBER permet de vérifier les valeurs de la liste A2:A12 si ce sont des nombres ou non. Il renverra TRUE si une cellule contient une valeur numérique, et FALSE sinon. Ainsi, vous obtiendrez un tableau comme celui-ci : {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}.
  • NB.SI(A2:A12,A2:A12): La fonction COUNTIF compte combien de fois chaque valeur apparaît dans la plage spécifique, elle renverra le résultat comme ceci : {1;2;2;2;2;1;1;3;3;3;1}.
  • ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)= {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}* {1;2;2;2;2;1;1;3;3;3;1}: Ces deux expressions sont multipliées pour obtenir ce résultat : {1;2;2;2;2;1;1;3;3;3;1}.
  • IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0)=IF({1;2;2;2;2;1;1;3;3;3;1}=1,1,0): Ici, la fonction SI vérifie chaque valeur du tableau si elles sont égales à 1 ou non : Si oui, un nombre 1 sera renvoyé ; sinon, un chiffre 0 s'affiche. Le résultat est le suivant : {1;0;0;0;0;1;1;0;0;0;1}.
  • SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))=SUM({1;0;0;0;0;1;1;0;0;0;1}): Enfin, la fonction SUM additionne les valeurs du tableau et renvoie le nombre total de valeurs uniques : 4.

Compter des valeurs numériques ou des dates uniques dans une colonne dans Excel 365

Dans Excel 365, il existe une nouvelle fonction simple appelée UNIQUE. Le fait d'avoir cette fonction incluse dans la fonction COUNT peut vous aider à traiter cette tâche rapidement selon vos besoins.

Compter des valeurs numériques ou des dates uniques dans une colonne

La syntaxe générique pour compter les valeurs numériques ou les dates uniques dans Excel 365 est :

=COUNT(UNIQUE(range))
  • range: la colonne de données à partir de laquelle vous souhaitez compter les valeurs uniques.

Veuillez entrer ou copier la formule ci-dessous dans une cellule vide et appuyez sur Entrer clé pour obtenir le résultat, voir capture d'écran:

=COUNT(UNIQUE(A2:A12))


Explication de la formule:

=COMPTE(UNIQUE(A2:A12))

  • UNIQUE(A2:A12): Cette fonction UNIQUE extrait toutes les valeurs uniques de la liste, et vous obtiendrez une liste de tableaux comme celle-ci : {258;560;774;801;985;990;1569}.
  • COUNT(UNIQUE(A2:A12))=COUNT({258;560;774;801;985;990;1569}): Cette fonction COUNT compte le nombre de valeurs numériques et renvoie le résultat : 7.

Compter des valeurs numériques ou des dates uniques qui n'apparaissent qu'une seule fois dans une colonne

Cette fonction UNIQUE peut également extraire les valeurs uniques qui se produisent exactement une fois à partir d'une liste, la syntaxe générique est :

=COUNT(UNIQUE(range,0,1))
  • range: la colonne de données à partir de laquelle vous souhaitez compter les valeurs uniques.

Entrez ou copiez la formule suivante dans une cellule où vous souhaitez renvoyer le résultat, puis appuyez sur Entrer clé, voir capture d'écran:

=COUNT(UNIQUE(A2:A12,0,1))


Explication de la formule:

=COMPTE(UNIQUE(A2:A12,0,1))

  • UNIQUE(A2:A12,0,1): Cette fonction UNIQUE extrait les valeurs uniques qui n'apparaissent qu'une seule fois dans la liste, et vous obtiendrez une liste de tableaux comme celle-ci : {258;801;985;1569}.
  • COUNT(UNIQUE(A2:A12,0,1))=COUNT({258;801;985;1569}): Cette fonction COUNT compte le nombre de valeurs numériques et renvoie le résultat : 4.

Pourboires: Toutes les formules ci-dessus sont disponibles pour compter les dates uniques dans une colonne.


Fonction relative utilisée:

  • SOMME:
  • La fonction Excel SUM renvoie la somme des valeurs fournies.
  • FRÉQUENCE:
  • La fonction FRÉQUENCE calcule la fréquence d'apparition des valeurs dans une plage de valeurs, puis renvoie un tableau vertical de nombres.
  • ISNUMBER :
  • La fonction Excel ISNUMBER renvoie TRUE lorsqu'une cellule contient un nombre et FALSE sinon.
  • COUNTIF :
  • La fonction NB.SI est une fonction statistique dans Excel qui est utilisée pour compter le nombre de cellules qui répondent à un critère.
  • FORMAT:
  • La fonction COUNT est utilisée pour compter le nombre de cellules contenant des nombres ou compter les nombres dans une liste d'arguments.
  • UNIQUE:
  • La fonction UNIQUE renvoie une liste de valeurs uniques dans une liste ou une plage.

Plus d'articles:

  • Compter des valeurs numériques uniques en fonction de critères
  • Dans la feuille de calcul Excel, vous pouvez rencontrer un problème qui compte le nombre de valeurs numériques uniques en fonction d'une condition spécifique. Par exemple, comment puis-je compter les valeurs de quantité uniques du produit « T-shirt » à partir du rapport, comme illustré ci-dessous ? Dans cet article, je vais montrer quelques formules pour réaliser cette tâche dans Excel.
  • Compter le nombre de cellules est égal à l'une des nombreuses valeurs
  • Supposons que j'ai une liste de produits dans la colonne A, maintenant, je veux obtenir le nombre total de produits spécifiques Apple, Grape et Lemon répertoriés dans la plage C4: C6 de la colonne A comme illustré ci-dessous. Normalement, dans Excel, les fonctions simples COUNTIF et COUNTIFS ne fonctionneront pas dans ce scénario. Cet article, je vais parler de la façon de résoudre ce travail rapidement et facilement avec la combinaison des fonctions SUMPRODUCT et COUNTIF.
  • Compter le nombre de cellules contenant un nombre spécifique de caractères
  • Si vous souhaitez compter le nombre de cellules contenant un certain nombre de caractères (tels que 5 caractères) dans une plage de cellules, comme illustré ci-dessous. Dans Excel, la fonction COUNTIF peut vous rendre service. Dans cet article, je vais expliquer comment obtenir un nombre de cellules contenant exactement x caractères ou des cellules contenant plus d'un certain nombre de caractères.

Les meilleurs outils de productivité de bureau

Kutools for Excel - vous aide à vous démarquer de la foule

🤖 Aide à l'IA Kutools: Révolutionner l'analyse des données en s'appuyant sur : Exécution intelligente   |  Générer du code  |  Créer des formules personnalisées  |  Analyser les données et générer des graphiques  |  Invoquer les fonctions Kutools...
Caractéristiques populaires: Rechercher, mettre en évidence ou identifier les doublons  |  Supprimer les lignes vides  |  Combinez des colonnes ou des cellules sans perdre de données  |  Tour sans formule 
Super VRecherche: Plusieurs critères  |  Valeur multiple  |  Sur plusieurs feuilles  |  Recherche floue
Av. La liste déroulante: Liste déroulante facile  |  Liste déroulante dépendante  |  Liste déroulante à sélection multiple
Gestionnaire de colonnes: Ajouter un nombre spécifique de colonnes  |  Déplacer les colonnes  |  Basculer l'état de visibilité des colonnes masquées  Comparer les colonnes à Sélectionnez des cellules identiques et différentes 
Caractéristiques en vedette: Mise au point de la grille  |  Voir Design  |  Grande barre de formule  |  Gestionnaire de classeurs et de feuilles | Centre de ressources (Texte automatique)  |  Sélecteur de date  |  Combiner des feuilles de travail  |  Crypter/déchiffrer les cellules  |  Envoyer des e-mails par liste  |  Super filtre  |  Filtre spécial (filtre gras/italique/barré...) ...
Les 15 meilleurs ensembles d'outils12 Texte Outils (Ajouter du texte, Supprimer les caractères ...)  |  50+ Graphique Types (Diagramme de Gantt ...)  |  40+ Pratique Formules (Calculer l'âge en fonction de l'anniversaire ...)  |  19 Insertion Outils (Insérer le code QR, Insérer une image à partir du chemin ...)  |  12 Conversion Outils (Nombres en mots, Conversion des devises ...)  |  7 Fusionner et fractionner Outils (Lignes de combinaison avancées, Diviser les cellules Excel ...)  |  ... et plus

Kutools pour Excel possède plus de 300 fonctionnalités, Assurez-vous que ce dont vous avez besoin est à portée de clic...

Description


Onglet Office - Activer la lecture et l'édition par onglets dans Microsoft Office (y compris Excel)

  • Une seconde pour basculer entre des dizaines de documents ouverts!
  • Réduisez chaque jour des centaines de clics de souris, dites adieu à la souris.
  • Augmente votre productivité de 50% lors de l'affichage et de l'édition de plusieurs documents.
  • Apporte des onglets efficaces à Office (y compris Excel), tout comme Chrome, Edge et Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations