Accéder au contenu principal

Supprimer le texte avant ou après le premier ou dernier caractère spécifique des chaînes de texte

Author: Xiaoyang Last Modified: 2025-05-27

Ce tutoriel expliquera comment supprimer le texte avant ou après le premier ou dernier caractère spécifique, comme un espace ou une virgule, dans une liste de chaînes de texte sous Excel.

doc-remove-after-first-space-01

Supprimer le texte avant ou après le premier caractère spécifique des chaînes de texte

Supprimer le texte avant le premier caractère spécifique (par exemple, un espace, une virgule)

Pour supprimer le texte avant le premier caractère spécifique des chaînes de texte, les fonctions DROITE, NBCAR et TROUVER peuvent vous aider. La syntaxe générique est :

=DROITE(cellule, NBCAR(cellule)-TROUVER("car", cellule))
  • cellule : La référence de la cellule ou la chaîne de texte dont vous souhaitez supprimer le texte.
  • car : Le séparateur spécifique à partir duquel vous souhaitez supprimer le texte.

Veuillez entrer ou copier la formule ci-dessous dans une cellule vide où vous souhaitez afficher le résultat :

=DROITE(A2,NBCAR(A2)-TROUVER(" ",A2))

Ensuite, faites glisser la poignée de recopie vers le bas pour appliquer cette formule aux autres cellules, et tout le texte avant le premier espace sera supprimé des chaînes de texte, voir capture d'écran :

doc-remove-after-first-space-02

Explication de la formule :

1.NBCAR(A2)-TROUVER(" ",A2) : Cette partie de la formule est reconnue comme le nombre de caractères (num_chars) dans la fonction DROITE.

  • TROUVER(" ",A2) : La fonction TROUVER permet d'obtenir la position du premier espace, elle renvoie le nombre 11.
  • NBCAR(A2) : Cette fonction NBCAR renverra le nombre total de caractères dans la cellule A2. Elle obtiendra le nombre 27.
  • NBCAR(A2)-TROUVER(" ",A2)=27-11 : Soustraire la position du premier espace de la longueur totale de la cellule A2 donnera le nombre de caractères après le premier espace.

2. DROITE(A2,NBCAR(A2)-TROUVER(" ",A2))=DROITE(A2, 16) : Enfin, cette fonction DROITE extraira 16 caractères à partir de la droite de la chaîne de texte dans la cellule A2.

Supprimer le texte après le premier caractère spécifique (comme un espace, une virgule)

Dans Excel, en combinant les fonctions GAUCHE et TROUVER, vous pouvez rapidement supprimer le texte après le premier caractère spécifique. La syntaxe générique est :

=GAUCHE(cellule,TROUVER("car",cellule)-1)
  • cellule : La référence de la cellule ou la chaîne de texte dont vous souhaitez supprimer le texte.
  • car : Le séparateur spécifique à partir duquel vous souhaitez supprimer le texte.

Veuillez appliquer la formule suivante dans une cellule vide :

=GAUCHE(A2,TROUVER(" ",A2)-1)

Ensuite, faites glisser la poignée de recopie vers le bas pour appliquer cette formule aux autres cellules, et tout le texte après le premier espace sera immédiatement supprimé, voir capture d'écran :

doc-remove-after-first-space-03

Explication de la formule :

1.TROUVER(" ",A2)-1 : Cette fonction TROUVER obtient la position du premier espace dans la cellule A2, soustraire 1 signifie exclure le caractère d'espace. Cela donnera le résultat 10. C'est reconnu comme le nombre de caractères (num_chars) dans la fonction GAUCHE.

2. GAUCHE(A2,TROUVER(" ",A2)-1)=GAUCHE(A2, 10) : Cette fonction GAUCHE extraira 10 caractères à partir de la gauche de la chaîne de texte dans la cellule A2.

Supprimer le texte avant ou après le dernier caractère spécifique des chaînes de texte

Supprimer le texte avant le dernier caractère spécifique (comme un espace, une virgule)

Si vous devez supprimer tout le texte avant le dernier caractère spécifique et ne laisser que les sous-chaînes après ce caractère, les fonctions DROITE, NBCAR, RECHERCHE et SUBSTITUE peuvent vous aider. La syntaxe générique est :

=DROITE(cellule,NBCAR(cellule)-RECHERCHE("#",SUBSTITUE(cellule,"car","#",NBCAR(cellule)-NBCAR(SUBSTITUE(cellule,"car","")))))
  • cellule : La référence de la cellule ou la chaîne de texte dont vous souhaitez supprimer le texte.
  • car : Le séparateur spécifique à partir duquel vous souhaitez supprimer le texte.

Pour résoudre cette tâche, veuillez copier ou taper la formule suivante dans une cellule vide :

=DROITE(A2,NBCAR(A2)-RECHERCHE("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ","")))))

Ensuite, faites glisser la poignée de recopie pour appliquer cette formule aux autres cellules nécessaires, et tout le texte avant le dernier espace sera supprimé, seuls les textes après le dernier espace resteront, voir capture d'écran :

doc-remove-after-first-space-04

Explication de la formule :

1. NBCAR(A2)-RECHERCHE("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ","")))):

  • SUBSTITUE(A2," ","") : Cette fonction SUBSTITUE est utilisée pour remplacer tous les caractères d'espacement par rien dans la cellule A2, et vous obtiendrez le résultat suivant : “Tom-Grade1HoustonTexasUS”.
  • NBCAR(SUBSTITUE(A2," ","")) : Cette fonction NBCAR renvoie le nombre de caractères de la chaîne de texte retournée par la fonction SUBSTITUE sans espaces. Elle obtiendra le nombre 24.
  • NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))=27-24 : Soustraire le nombre de caractères sans espace de la longueur totale de la cellule A2 donnera le nombre d'espaces entre la chaîne de texte. Cela donnera le nombre 3.
  • SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ","")))= SUBSTITUE(A2," ","#", 3) : Cette fonction SUBSTITUE est utilisée pour remplacer le dernier caractère d'espace par un caractère # spécifique, le résultat est : “Tom-Grade1 Houston Texas#US”.
  • RECHERCHE("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))))= RECHERCHE("#", "Tom-Grade1 Houston Texas#US") : Cette fonction RECHERCHE trouvera la position du caractère # spécifique dans la chaîne de texte retournée par la fonction SUBSTITUE. Elle obtiendra le nombre 25.
  • NBCAR(A2)-RECHERCHE("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))))=27-25 : La longueur totale du texte dans la cellule A2 moins la position du dernier espace donnera le nombre de caractères après le dernier espace. Cela donnera le nombre 2.

2. DROITE(A2,NBCAR(A2)-RECHERCHE("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ","")))))=DROITE(A2, 2) : Enfin, cette fonction DROITE extraira 2 caractères à partir de la droite de la chaîne de texte dans la cellule A2.

Supprimer le texte après le dernier caractère spécifique (comme un espace, une virgule)

Pour supprimer le texte après le dernier caractère spécifique, les fonctions GAUCHE, TROUVER, SUBSTITUE et NBCAR peuvent vous aider. La syntaxe générique est :

=GAUCHE(cellule,TROUVER("#",SUBSTITUE(cellule,"car","#",NBCAR(cellule)-NBCAR(SUBSTITUE(cellule,"car",""))))-1)
  • cellule : La référence de la cellule ou la chaîne de texte dont vous souhaitez supprimer le texte.
  • car : Le séparateur spécifique à partir duquel vous souhaitez supprimer le texte.

Veuillez entrer ou copier la formule suivante dans une cellule vide :

=GAUCHE(A2,TROUVER("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))))-1)

Ensuite, faites glisser la poignée de recopie vers le bas pour appliquer cette formule aux cellules souhaitées, et vous obtiendrez le résultat comme indiqué dans la capture d'écran ci-dessous :

doc-remove-after-first-space-05

Explication de la formule :

1. TROUVER("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))))-1:

  • SUBSTITUE(A2," ","") : Cette fonction SUBSTITUE est utilisée pour remplacer tous les caractères d'espacement par rien dans la cellule A2, et vous obtiendrez le résultat suivant : “Tom-Grade1HoustonTexasUS”.
  • NBCAR(SUBSTITUE(A2," ","")) : Cette fonction NBCAR renvoie le nombre de caractères de la chaîne de texte retournée par la fonction SUBSTITUE sans espaces. Elle obtiendra le nombre 24.
  • NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))=27-24 : Soustraire le nombre de caractères sans espace de la longueur totale de la cellule A2 donnera le nombre d'espaces entre la chaîne de texte. Cela donnera le nombre 3.
  • SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ","")))= SUBSTITUE(A2," ","#", 3) : Cette fonction SUBSTITUE est utilisée pour remplacer le dernier caractère d'espace par un caractère # spécifique, le résultat est : “Tom-Grade1 Houston Texas#US”.
  • TROUVER("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))))-1=TROUVER("#", "Tom-Grade1 Houston Texas#US ")-1=25-1 : Cette fonction TROUVER retournera la position du caractère # spécifique dans la chaîne de texte retournée par la fonction SUBSTITUE, soustraire 1 signifie exclure le caractère d'espace. Cela donnera le nombre 24.

2. GAUCHE(A2,TROUVER("#",SUBSTITUE(A2," ","#",NBCAR(A2)-NBCAR(SUBSTITUE(A2," ",""))))-1)=GAUCHE(A2, 24) : Enfin, cette fonction GAUCHE extraira 24 caractères à partir de la gauche de la chaîne de texte de la cellule A2.

Fonctions relatives utilisées :

  • GAUCHE :
  • La fonction GAUCHE extrait un nombre donné de caractères à partir de la gauche d'une chaîne fournie.
  • DROITE :
  • La fonction DROITE est utilisée pour extraire un nombre spécifique de caractères à partir de la droite de la chaîne de texte.
  • TROUVER :
  • La fonction TROUVER est utilisée pour trouver une chaîne dans une autre chaîne et retourne la position de départ de la chaîne à l'intérieur de l'autre.
  • RECHERCHE :
  • La fonction RECHERCHE peut vous aider à trouver la position d'un caractère ou d'une sous-chaîne spécifique dans une chaîne de texte donnée.
  • SUBSTITUE :
  • La fonction SUBSTITUE d'Excel remplace du texte ou des caractères dans une chaîne de texte par un autre texte ou des caractères.
  • NBCAR :
  • La fonction NBCAR renvoie le nombre de caractères dans une chaîne de texte.

Plus d'articles :

Les meilleurs outils de productivité pour Office

Kutools pour Excel - Vous aide à vous démarquer de la foule

🤖 Assistant IA Kutools : Révolutionnez l'analyse des données grâce à : Exécution intelligente   |  Générer du code  |  Créer des formules personnalisées  |  Analyser les données et générer des graphiques  |  Invoquer les fonctions de Kutools…
Fonctionnalités populaires : Rechercher, Mettre en évidence ou Identifier les doublons  |  Supprimer les lignes vides  |  Combiner les colonnes ou cellules sans perte de données  |  Arrondir sans formule ...
Super VLookup : Critères multiples  |  Valeurs multiples  |  À travers plusieurs feuilles  |  Correspondance floue...
Liste déroulante avancée : Liste déroulante facile  |  Liste déroulante dépendante  |  Liste déroulante à sélection multiple...
Gestionnaire de colonnes : Ajouter un nombre spécifique de colonnes  |  Déplacer des colonnes  |  Basculer la visibilité des colonnes masquées  |  Comparer des colonnes pour sélectionner des cellules identiques et différentes ...
Fonctionnalités phares : Mise au point de la grille  |  Affichage de conception  |  Barre de formule améliorée  |  Gestionnaire de classeur et de feuille de calcul | Bibliothèque d’AutoTexte (texte automatique)  |  Sélecteur de date  |  Fusionner les feuilles de calcul  |  Chiffrer/Déchiffrer les cellules  |  Envoyer des e-mails par liste  |  Super Filtre  |  Filtre spécial (filtrer gras/italique/barré...) ...
Top 15 des ensembles d'outils :  12 outils de texte (Ajouter du texte, Supprimer des caractères ...)  |  50+ types de graphiques (Diagramme de Gantt ...)  |  40+ formules pratiques (Calculer l’âge en fonction de la date de naissance ...)  |  19 outils d'insertion (Insérer un code QR, Insérer une image depuis un chemin ...)  |  12 outils de conversion (Convertir en mots, Conversion de devises ...)  |  7 outils de fusion et division (Fusion avancée des lignes, Diviser les cellules Excel ...)  |  ... et plus encore

Kutools pour Excel compte plus de 300 fonctionnalités, garantissant que ce dont vous avez besoin n'est qu'à un clic...

Office Tab - Active la lecture et l'édition par onglets dans Microsoft Office (y compris Excel)

  • Une seconde pour basculer entre des dizaines de documents ouverts !
  • Réduit des centaines de clics de souris pour vous chaque jour, dites adieu à la main de la souris.
  • Augmente votre productivité de 50 % lors de la consultation et de l'édition de plusieurs documents.
  • Apporte des onglets efficaces à Office (y compris Excel), tout comme Chrome, Edge et Firefox.