Récupérer la nième correspondance avec INDEX

Pour trouver la nième correspondance d'une valeur dans une plage et récupérer les données correspondantes, vous pouvez utiliser une formule basée sur les fonctions INDEX, LIGNE, PETITE.VALEUR et SI.

Comment récupérer les informations associées à la nième correspondance d'une valeur avec INDEX ?

Pour obtenir les informations sur la 3e correspondance d'Usain Bolt dans le tableau ci-dessus, vous pouvez utiliser les fonctions LIGNE et SI ensemble pour obtenir un tableau composé des numéros de ligne de toutes les valeurs Usain Bolt. Ensuite, utilisez la fonction PETITE.VALEUR pour récupérer le numéro de ligne de la nième valeur correspondante spécifiée. Enfin, transmettez le résultat à la fonction INDEX pour obtenir les informations correspondantes sur la même ligne.

Syntaxe générique

=INDEX(plage_retour,PETITE.VALEUR(SI(plage_recherche=valeur_recherche,LIGNE(plage_recherche)-LIGNE(INDEX(plage_recherche,1,1))+1),n))

√ Remarque : Il s'agit d'une formule matricielle qui nécessite d'être validée avec Ctrl + Maj + Entrée.

Pour obtenir les informations sur la 3e correspondance d'Usain Bolt, veuillez copier ou saisir les formules ci-dessous dans les cellules G8 et G9, puis appuyez sur Ctrl + Maj + Entrée pour obtenir les résultats :

Année (Cellule G8)
=INDEX(B6:B12,PETITE.VALEUR(SI(C6:C12=G5,LIGNE(C6:C12)-LIGNE(INDEX(C6:C12,1,1))+1),G6))
Temps (Cellule G9)
=INDEX(D6:D12,PETITE.VALEUR(SI(C6:C12=G5,LIGNE(C6:C12)-LIGNE(INDEX(C6:C12,1,1))+1),G6))

Explication de la formule

Ici, nous utilisons la formule ci-dessous comme exemple :

=INDEX(B6:B12,PETITE.VALEUR(SI(C6:C12=G5,LIGNE(C6:C12)-LIGNE(INDEX(C6:C12,1,1))+1),G6))

• LIGNE(C6:C12) : La fonction LIGNE renvoie les numéros de ligne de chaque cellule dans la plage C6:C12 sous forme de tableau comme ceci : {6;7;8;9;10;11;12}.
• LIGNE(INDEX(C6:C12,1,1)): Les fonctions INDEX et LIGNE renvoient le premier numéro de ligne de la plage de recherche C6:C12 dans cette feuille Excel, qui est 6.
• SI(C6:C12=G5,LIGNE(C6:C12)-LIGNE(INDEX(C6:C12,1,1))+1) = SI(C6:C12=G5,{6;7;8;9;10;11;12}-6+1) : La fonction SI vérifie si chaque valeur dans la plage C6:C12 correspond à la valeur dans la cellule G5, Usain Bolt. Si oui, la fonction renverra le résultat de « son numéro de ligne correspondant - 6 + 1 » ; sinon, elle renverra FAUX. Ainsi, les résultats seront dans un tableau comme ceci : {FAUX;2;3;4;FAUX;FAUX;FAUX}.
• PETITE.VALEUR(SI(C6:C12=G5,LIGNE(C6:C12)-LIGNE(INDEX(C6:C12,1,1))+1),G6) = PETITE.VALEUR({FAUX;2;3;4;FAUX;FAUX;FAUX},G6) : L'extrait renvoie la 3e plus petite valeur (valeur dans la cellule G6) du tableau, qui est 4.
• INDEX(B6:B12,PETITE.VALEUR(SI(C6:C12=G5,LIGNE(C6:C12)-LIGNE(INDEX(C6:C12,1,1))+1),G6)) = INDEX(B6:B12,4) La fonction INDEX renvoie la 4e valeur dans la plage année B6:B12, qui est Pékin 2008.

Fonctions connexes

Formules connexes