Note: The other languages of the website are Google-translated. Back to English
English English

Octets séparés de l'adresse IP dans Excel

Avez-vous déjà essayé de diviser les adresses IP en colonnes séparées dans la feuille de calcul Excel? Peut-être que la fonctionnalité Texte en colonne peut vous aider à résoudre ce travail rapidement, mais, dans cet article, je vais parler de quelques formules pour réaliser cette tâche dans Excel.


Divisez les octets d'adresses IP en colonnes séparées dans Excel

Normalement, dans Excel, les fonctions LEFT, MID, LEN et FIND peuvent vous aider à extraire chaque octet de l'adresse IP dans différentes colonnes. Veuillez suivre les étapes suivantes:

Divisez le premier octet des adresses IP:

Pour extraire le premier octet de l'adresse IP, veuillez appliquer la formule ci-dessous dans une cellule vide:

=LEFT(A2,FIND(".",A2)-1)

Et puis, faites glisser la poignée de remplissage vers les cellules auxquelles vous souhaitez appliquer cette formule, et tous les premiers octets des adresses IP ont été extraits, voir capture d'écran:

Explication de la formule:

TROUVER (".", A2) -1: Cette fonction FIND renvoie la position du premier point de la cellule A2, soustrait 1 signifie exclure le point lui-même, vous obtiendrez le résultat 2.

LEFT(A2,FIND(".",A2)-1)=LEFT(A2, 2):La fonction GAUCHE est utilisée pour extraire 2 caractères du côté gauche de la chaîne dans la cellule A2.


Divisez le deuxième octet des adresses IP:

Pour obtenir le deuxième octet des adresses IP, veuillez copier ou saisir la formule suivante dans une cellule vide:

=MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)

Ensuite, faites glisser la poignée de remplissage vers les cellules pour remplir cette formule, et vous obtiendrez le résultat dont vous avez besoin, voir capture d'écran:

Explication de la formule:

1. FIND (".", A2) +1: Cette fonction FIND renvoie la position du premier point de la cellule A2, ajoute 1 signifie à l'extraction du caractère suivant, vous obtiendrez le résultat le numéro 4. Cette partie de la formule est reconnue comme l'argument start_num de la fonction MID.

2. FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1: Cette partie est reconnue comme l'argument num_chars dans la fonction MID.

  • FIND (".", A2, FIND (".", A2) +1) = TROUVER (".", A2,4): Cette fonction FIND renverra la position du deuxième point. Et vous obtiendrez le numéro 6.
  • FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1=6-3-1: Soustrayez la position du premier point de la position du deuxième point, puis soustrayez 1 du résultat pour supprimer un point de début. Et le résultat est 2.

3. MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)=MID(A2, 4, 2): Enfin, cette fonction MID permet d'extraire 2 caractères qui commencent au quatrième caractère de la cellule A2.


Divisez le troisième octet des adresses IP:

Pour extraire le troisième octet des adresses IP, les fonctions MID et FIND peuvent également vous rendre service, veuillez saisir ou copier la formule suivante dans une cellule vide:

=MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))

Ensuite, faites glisser la poignée de remplissage vers le bas pour obtenir les résultats dont vous avez besoin, et seul le troisième octet des adresses IP a été divisé, voir capture d'écran:

Explication de la formule:

1. FIND(".",A2,FIND(".",A2)+1)+1: Cette fonction FIND imbriquée est utilisée pour obtenir la position du deuxième point dans la cellule A2, en ajoutant 1 signifie à l'extraction du caractère suivant, et vous obtiendrez le numéro 7. Cette partie est reconnue comme l'argument start_num de la fonction MID.

2. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1): Cette partie de la formule est reconnue comme l'argument num_chars de la fonction MID.

  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=FIND(".",A2, 7): Cette fonction FIND imbriquée permet d'obtenir la position du troisième point dans la cellule A2, elle renvoie le nombre 8.
  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1)=8-7: Soustrayez la position du deuxième point de la position du troisième point, et le résultat est 1.

3.MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 7, 1): Cette fonction MID obtiendra 1 caractère qui commence au septième caractère de la cellule A2.


Divisez le quatrième octet des adresses IP:

La formule ci-dessous peut aider à extraire le dernier octet de l'adresse IP, veuillez copier ou entrer la formule dans une cellule vide:

=MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))

Et puis, faites glisser la poignée de remplissage pour remplir cette formule vers d'autres cellules dont vous avez besoin, vous obtiendrez le résultat comme ci-dessous la capture d'écran:

Explication de la formule:

1. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1: Cette fonction FIND imbriquée est utilisée pour obtenir la position du troisième point dans la cellule A2, en ajoutant 1 signifie à l'extraction du caractère suivant, et vous obtiendrez le numéro 9. Cette partie est reconnue comme l'argument start_num de la fonction MID.

2. LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1):

  • LEN (A2): La fonction LEN renvoie le nombre total de caractères dans la cellule A2. Il obtiendra le numéro 11.
  • LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=11-8: La longueur totale de la cellule A2 soustrait la position du troisième point pour obtenir le numéro du caractère restant. Cela obtiendra le numéro 3.

3. MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 9, 3): Enfin, cette fonction MID obtiendra 3 caractères qui commencent au neuvième caractère de la cellule A2.


Fonctions relatives utilisées:

  • LEFT:
  • La fonction LEFT extrait le nombre donné de caractères du côté gauche d'une chaîne fournie.
  • MID:
  • La fonction MID est utilisée pour rechercher et renvoyer un nombre spécifique de caractères à partir du milieu d'une chaîne de texte donnée.
  • FIND:
  • La fonction FIND est utilisée pour rechercher une chaîne dans une autre chaîne et renvoie la position de départ de la chaîne dans une autre.
  • LEN:
  • La fonction LEN renvoie le nombre de caractères dans une chaîne de texte.

Plus d'articles:

  • Diviser le texte et les nombres dans une cellule dans Excel
  • En supposant qu'une donnée de cellule soit mélangée avec du texte et des nombres, comment pouvez-vous les diviser en cellules de colonne séparées? Ce didacticiel va vous montrer les étapes détaillées pour le comprendre avec des formules.

Les meilleurs outils de productivité de bureau

Kutools for Excel - vous aide à vous démarquer de la foule

Souhaitez-vous terminer votre travail quotidien rapidement et parfaitement? Kutools pour Excel apporte

300
 fonctionnalités avancées puissantes (Combiner des classeurs, additionner par couleur, fractionner le contenu des cellules, convertir la date, etc.) et enregistrer
80 %
temps pour vous.

  • Conçu pour
    1500
    scénarios de travail, vous aide à résoudre
    80 %
     Problèmes Excel.
  • Réduisez les milliers de clics de clavier et de souris chaque jour, soulagez vos yeux et vos mains fatigués.
  • Devenez un expert Excel en 3 minutes. Plus besoin de se souvenir des formules douloureuses et des codes VBA.
  • 30
    -jour d'essai gratuit illimité. Garantie de remboursement de 60 jours. Mise à jour gratuite et assistance pendant 2 ans.
Ruban d'Excel (avec Kutools for Excel installé)

Onglet Office - Activer la lecture et la modification par onglets dans Microsoft Office (y compris Excel)

  • Une seconde pour basculer entre des dizaines de documents ouverts!
  • Réduisez chaque jour des centaines de clics de souris, dites adieu à la souris.
  • Augmente votre productivité en
    50 %
    lors de la visualisation et de la modification de plusieurs documents.
  • Apporte des onglets efficaces à Office (y compris Excel), tout comme Chrome, Firefox et le nouvel Internet Explorer.
Capture d'écran d'Excel (avec Office Tab installé)
Commentaires (1)
Noté 5 hors 5 · évaluations 1
Ce commentaire a été minimisé par le modérateur sur le site
Cela a fonctionné à merveille, merci pour ces informations !!
Noté 5 hors 5
Il n'y a pas encore de commentaires postés ici
Laisser vos commentaires
Publier en tant qu'invité
×
Évaluez cet article:
0   Personnages
Emplacements suggérés

Nous suivre

Copyright © 2009 - www.extendoffice.com. | Tous les droits sont réservés. Alimenté par ExtendOffice. | | Plan du site
Microsoft et le logo Office sont des marques commerciales ou des marques déposées de Microsoft Corporation aux États-Unis et / ou dans d'autres pays.
Protégé par Sectigo SSL