Fractionner une chaîne de texte à un caractère spécifique dans une cellule dans Excel
Ce tutoriel explique comment fractionner une chaîne de texte à un caractère spécifique en colonnes distinctes à l’aide d’une formule dans Excel.
Comment fractionner une chaîne de texte à un caractère spécifique dans une cellule Excel ?
Supposons que vous disposiez d’une liste de chaînes de texte dans la colonne B, comme illustré ci-dessous, et que vous souhaitiez fractionner ces textes au niveau du caractère « - » afin de les répartir sur trois colonnes distinctes. Les formules suivantes vous seront alors particulièrement utiles.
Formules génériques
Formule générique pour fractionner le texte de gauche
=LEFT(text_string,FIND(«Char», text_string)-1)
Formule générique pour fractionner le texte du milieu
=MID(text_string, FIND(«Char», text_string) + 1, FIND(«Char», text_string,FIND(«Char», text_string)+1) - FIND(«Char», text_string) - 1)
Formule générique pour fractionner le texte de droite
=RIGHT(text_string,LEN(text_string) - FIND(«Char», text_string, FIND(«Char», text_string) + 1))
Arguments des formules ci-dessus
Chaîne de texte: La chaîne de texte à partir de laquelle vous souhaitez fractionner le texte ;
Caractère : Le caractère à partir duquel vous allez fractionner le texte.
Comment utiliser ces formules ?
Tout d’abord, fractionnez la première partie de la chaîne de texte à l’aide d’un caractère spécifique
1. Sélectionnez une cellule vide pour afficher le résultat — ici, C3.
2. Saisissez la formule ci-dessous, puis appuyez sur la touche Entrée. Ensuite, faites glisser la poignée de recopie vers le bas pour appliquer la formule aux autres cellules.
=LEFT(B3,FIND("-",B3)-1)
Ensuite, fractionnez la partie centrale de la chaîne de texte à l’aide d’un caractère spécifique
1. Sélectionnez une cellule vide, comme D3, pour afficher le résultat.
2. Saisissez la formule ci-dessous, puis appuyez sur la touche Entrée. Sélectionnez la cellule contenant le résultat et faites glisser la poignée de recopie vers le bas pour étendre la formule aux autres cellules.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
Enfin, fractionnez la dernière partie de la chaîne de texte à l’aide d’un caractère spécifique
1. Sélectionnez une cellule vide, comme E3, pour afficher le résultat.
2. Saisissez la formule ci-dessous, puis appuyez sur la touche Entrée. Sélectionnez la cellule contenant le résultat, puis faites glisser la poignée de recopie vers le bas pour appliquer la formule aux autres cellules.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
Les chaînes de texte de chaque cellule de la colonne B ont désormais été divisées en trois parties.
Conseil : Si vous souhaitez fractionner une chaîne de texte en deux parties à l’aide d’un caractère spécifique, appliquez la formule DROITE ci-dessous pour extraire la deuxième partie, après avoir utilisé la formule GAUCHE mentionnée précédemment pour obtenir la première.
=RIGHT(B3,LEN(B3)-FIND("-",B3))
Comment ces formules fonctionnent-elles ?
=LEFT(B3,FIND("-",B3)-1)
- FIND("-",B3)La fonction TROUVE renvoie la position de départ du caractère « - » dans la chaîne de texte « KTE-Jan-359 », soit la 4ᵉ position.
- LEFT(B3,4-1) : La fonction GAUCHE extrait 3 caractères (4 – 1 = 3) depuis le début de la chaîne « KTE-Jan-359 ». Le résultat est donc « KTE ».
Remarque : Comme le premier caractère « – » se trouve à la 4ᵉ position de la chaîne, vous devez soustraire 1 pour l’exclure de l’extraction.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
- FIND("-",B3) + 1 : La fonction TROUVE renvoie la position du caractère « - » dans la chaîne de texte KTE-Jan-359. Le résultat ici est 4.
Remarque : Comme le premier caractère « - » se trouve à la 4ᵉ position de la chaîne, vous devez ajouter 1 à ce résultat pour extraire le texte qui suit. Cela donne donc 4 + 1 = 5. - FIND("-",B3,FIND("-",B3)+1)Ici, on écrit TROUVE("-", "KTE-Jan-359", 4+1) : la fonction TROUVE détermine la position du caractère « - » en commençant à partir du 5ᵉ caractère de « KTE-Jan-359 » et renvoie le résultat 8.
- MID(B3, 5, 8 - 4 - 1)La fonction STXT(KTE-Jan-359;5;3) extrait 3 caractères à partir du 5ᵉ caractère de la chaîne « KTE-Jan-359 », ce qui donne « Jan ».
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
- LEN(B3)La fonction NBCAR calcule la longueur totale de la chaîne de texte « KTE-Jan-359 » et renvoie le résultat 11.
- FIND("-",B3,FIND("-",B3)+1)La fonction TROUVE détermine la position du caractère « - » en commençant à partir du 5ᵉ caractère dans « KTE-Jan-359 » et renvoie le résultat 8.
- RIGHT(B3,11 - 8))La fonction DROITE extrait 3 caractères (11 – 8) à partir de la fin de « KTE-Jan-359 », ce qui donne ici le résultat 359.
Fonctions associées
Fonction GAUCHE d’Excel
La fonction GAUCHE extrait un nombre spécifié de caractères depuis le début d’une chaîne donnée.
Fonction TROUVE d’Excel
La fonction TROUVE vous permet de rechercher une chaîne de caractères à l’intérieur d’une autre et renvoie la position à laquelle cette sous-chaîne commence.
Fonction STXT d’Excel
La fonction STXT vous permet d’extraire un nombre précis de caractères à partir du milieu d’une chaîne de texte.
Fonction DROITE d’Excel
La fonction DROITE extrait un nombre déterminé de caractères à partir de la fin d’une chaîne de texte.
Fonction NBCAR d’Excel
La fonction NBCAR d’Excel renvoie le nombre de caractères présents dans une chaîne de texte.
Formules associées
Fractionner des dimensions en deux parties dans Excel
Découvrez comment utiliser des formules pour séparer, en un clin d’œil, les dimensions contenues dans une cellule en deux parties distinctes (longueur et largeur), sans les unités !
Séparer les nombres des unités de mesure
Découvrez comment utiliser une formule simple pour séparer facilement les nombres de leurs unités de mesure !
Fractionner texte et nombre contenus dans une cellule Excel
Si vous souhaitez séparer le texte et les nombres présents dans une même cellule en différentes colonnes à l’aide d’une formule, ce tutoriel vous sera très utile.
Fractionner du texte avec un délimiteur dans une cellule dans Excel
Dans cet article, découvrez notre guide pas à pas pour fractionner facilement du texte dans une cellule à l’aide d’un délimiteur spécifique dans Excel.
Les meilleurs outils de productivité Office
Kutools pour Excel – Vous permet de vous démarquer de la foule
Kutools pour Excel propose plus de 300 fonctionnalités,garantissant que ce dont vous avez besoin est toujours à portée de clic...
Office Tab – Active la lecture et l’édition par onglets dans Microsoft Office (y compris Excel)
- Passez d’un document à l’autre en une seconde, même avec des dizaines de documents ouverts !
- Réduisez de centaines vos clics de souris chaque jour et dites adieu au syndrome de la main de la souris.
- Augmentez votre productivité de 50 % en consultant et en modifiant simultanément plusieurs documents.
- Apporte à Office (y compris Excel) une efficacité comparable à celle des navigateurs tels que Chrome, Edge et Firefox.