Diviser une chaîne de texte à un caractère spécifique dans une cellule sous Excel

Ce tutoriel explique comment diviser une chaîne de texte à un caractère spécifique en cellules de colonnes distinctes avec des formules dans Excel.

Comment diviser une chaîne de texte à un caractère spécifique dans une cellule sous Excel ?

Supposons que vous ayez une liste de chaînes de texte dans la colonne B, comme dans la capture d'écran ci-dessous, et que vous souhaitiez diviser les textes au niveau du caractère « - » et les afficher dans trois colonnes séparées. Dans ce cas, les formules ci-dessous peuvent vous aider.

Formules génériques

Formule générique pour diviser le texte à gauche

=GAUCHE(texte_chaine,TROUVE("Car", texte_chaine)-1)

Formule générique pour diviser le texte du milieu

=STXT(texte_chaine, TROUVE("Car", texte_chaine) + 1, TROUVE("Car", texte_chaine,TROUVE("Car", texte_chaine)+1) - TROUVE("Car", texte_chaine) - 1)

Formule générique pour diviser le texte à droite

=DROITE(texte_chaine,NBCAR(texte_chaine) - TROUVE("Car", texte_chaine, TROUVE("Car", texte_chaine) + 1))

Arguments des formules ci-dessus

Comment utiliser ces formules ?

Tout d'abord, divisez la première chaîne de texte en fonction d'un caractère spécifique

1. Sélectionnez une cellule vide pour afficher le résultat. Ici, je sélectionne C3.

2. Entrez la formule ci-dessous dans cette cellule et appuyez sur la touche Entrée. Ensuite, faites glisser la cellule contenant votre formule GAUCHE jusqu'en bas pour l'appliquer aux autres cellules.

=GAUCHE(B3,TROUVE("-",B3)-1)

Ensuite, divisez la chaîne de texte du milieu en fonction d'un caractère spécifique

1. Sélectionnez une cellule vide, par exemple D3, pour afficher le résultat.

2. Entrez la formule ci-dessous dans cette cellule et appuyez sur la touche Entrée. Sélectionnez la cellule résultat, puis faites glisser la poignée de remplissage vers le bas pour appliquer la formule aux autres cellules.

=STXT(B3, TROUVE("-",B3) + 1, TROUVE("-",B3,TROUVE("-",B3)+1) - TROUVE("-",B3) - 1)

Enfin, divisez la dernière chaîne de texte en fonction d'un caractère spécifique

1. Sélectionnez une cellule vide, par exemple E3, pour afficher le résultat.

2. Entrez la formule ci-dessous dans cette cellule et appuyez sur la touche Entrée. Sélectionnez la cellule résultat, puis faites glisser la poignée de remplissage vers le bas pour appliquer la formule aux autres cellules.

=DROITE(B3,NBCAR(B3) - TROUVE("-", B3, TROUVE("-", B3) + 1))

Maintenant, la chaîne de texte dans chaque cellule de la colonne B a été divisée en trois parties.

Astuce : Si vous souhaitez uniquement diviser la chaîne de texte en deux parties en fonction d'un caractère spécifique, après avoir divisé la première partie avec la formule GAUCHE ci-dessus, vous pouvez appliquer la formule DROITE ci-dessous pour extraire la deuxième partie, comme illustré dans la capture d'écran ci-dessous.

=DROITE(B3,NBCAR(B3)-TROUVE("-",B3))

Comment fonctionnent ces formules ?

=GAUCHE(B3,TROUVE("-",B3)-1)

• TROUVE("-",B3) : La fonction TROUVE renvoie la position de départ du caractère « - » dans la chaîne de texte KTE-Jan-359. Le résultat est 4.
• GAUCHE(B3,4-1)La fonction GAUCHE extrait 3 caractères (4-1=3) depuis le côté gauche de la chaîne de texte KTE-Jan-359. Ici, le résultat est KTE.
  RemarqueComme le premier caractère « - » se trouve à la 4ème position de la chaîne de texte, vous devez soustraire 1 pour l'exclure de l'extraction. 

=STXT(B3, TROUVE("-",B3) + 1, TROUVE("-",B3,TROUVE("-",B3)+1) - TROUVE("-",B3) - 1)

• TROUVE("-",B3) + 1La fonction TROUVE renvoie la position de départ du caractère « - » dans la chaîne de texte KTE-Jan-359. Ici, le résultat est 4.
  RemarqueComme le premier caractère "-" est à la 4ème position de la chaîne de texte, vous devez ajouter 1 à 4 afin d'extraire les textes après celui-ci, et finalement obtenir 4+1=5.
• TROUVE("-",B3,TROUVE("-",B3)+1) ici s'affiche comme TROUVE("-",KTE-Jan-359,4+1) : La fonction TROUVE recherche la position du caractère "-" à partir du 5ème caractère dans KTE-Jan-359. Et retourne le résultat 8.
• STXT(B3, 5, 8 - 4 - 1): STXT(KTE-Jan-359,5,3), ce qui signifie que la fonction STXT extrait 3 caractères à partir du 5ème caractère dans la chaîne de texte KTE-Jan-359. Et le résultat est Jan.

=DROITE(B3,NBCAR(B3) - TROUVE("-", B3, TROUVE("-", B3) + 1))

• NBCAR(B3) : La fonction NBCAR calcule la longueur totale de la chaîne de texte KTE-Jan-359, et retourne le résultat 11.
• TROUVE("-",B3,TROUVE("-",B3)+1) : La fonction TROUVE recherche la position du caractère "-" à partir du 5ème caractère dans KTE-Jan-359. Et retourne le résultat 8.
• DROITE(B3,11 - 8)): La fonction DROITE extrait 3 caractères (11-8) depuis le côté droit de KTE-Jan-359. Ici, le résultat est 359.

Fonctions connexes

Formules connexes