Passer au contenu principal

Diviser la chaîne de texte à un caractère spécifique dans une cellule dans Excel

Ce didacticiel explique comment diviser la chaîne de texte à un caractère spécifique dans des cellules de colonne séparées avec des formules dans Excel.


Comment diviser une chaîne de texte à un caractère spécifique dans une cellule dans Excel?

Supposons que vous ayez une liste de chaînes de texte dans la colonne B comme capture d'écran ci-dessous, et que vous souhaitiez diviser les textes au caractère «-» et les afficher dans trois colonnes distinctes. Dans ce cas, les formules ci-dessous peuvent vous rendre service.

Formules génériques

Formule générique pour fractionner le texte de gauche

=LEFT(text_string,FIND("Char", text_string)-1)

Formule générique pour diviser le texte du milieu

=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)

Formule générique pour diviser le bon texte

=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))

Arguments des formules ci-dessus

Chaîne_texte: La chaîne de texte à partir de laquelle vous souhaitez diviser le texte;

Carboniser: Le caractère sur lequel vous allez fractionner le texte.

Comment utiliser ces formules?

Tout d'abord, divisez la première chaîne de texte en fonction d'un caractère spécifique

1. Sélectionnez une cellule vide pour afficher le résultat. Ici, je sélectionne C3.

2. Entrez la formule ci-dessous et appuyez sur la touche Entrer clé. Et puis faites glisser la cellule avec votre formule GAUCHE tout en bas pour l'appliquer à d'autres cellules.

=LEFT(B3,FIND("-",B3)-1)

Deuxièmement, divisez la chaîne de texte du milieu en fonction d'un caractère spécifique

1. Sélectionnez une cellule vide telle que D3 pour sortir le résultat.

2. Entrez la formule ci-dessous et appuyez sur la touche Entrer clé. Sélectionnez la cellule de résultat, faites glisser la poignée de remplissage vers le bas pour appliquer la formule à d'autres cellules.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

Enfin, divisez la dernière chaîne de texte en fonction d'un caractère spécifique

1. Sélectionnez une cellule vide telle que E3 pour afficher le résultat.

2. Entrez la formule ci-dessous et appuyez sur la touche Entrer clé. Sélectionnez la cellule de résultat, faites glisser la poignée de remplissage vers le bas pour appliquer la formule à d'autres cellules.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

Maintenant, la chaîne de texte dans chaque cellule de la colonne B a été divisée en trois parties.

Pourboires: Si vous souhaitez seulement diviser la chaîne de texte en deux parties en fonction d'un caractère spécifique, après avoir divisé la première partie avec la formule GAUCHE ci-dessus, vous pouvez appliquer la formule ci-dessous à DROITE pour extraire la deuxième partie comme illustré ci-dessous.

=RIGHT(B3,LEN(B3)-FIND("-",B3))

Comment fonctionnent ces formules?

=LEFT(B3,FIND("-",B3)-1)

  • FIND("-",B3): La fonction FIND renvoie la position de départ du caractère «-» dans la chaîne de texte KTE-Jan-359. Le résultat est 4.
  • LEFT(B3,4-1): La fonction LEFT extrait 3 caractères (4-1 = 3) du côté gauche de la chaîne de texte KTE-Jan-359. Ici, le résultat est KTE.
    Notes: Comme le premier caractère «-» se trouve à la 4ème position de la chaîne de texte, vous devez soustraire 1 pour l'exclure de l'extraction. 

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

  • FIND("-",B3) + 1: La fonction FIND renvoie la position de départ du caractère «-» dans la chaîne de texte KTE-Jan-359. Ici, le résultat est 4.
    Notes: Comme le premier caractère "-" est en 4ème position de la chaîne de texte, il faut ajouter 1 à 4 pour extraire les textes après, et finalement on finit par 4 + 1 = 5.
  • FIND("-",B3,FIND("-",B3)+1) ici est affiché comme FIND ("-", KTE-Jan-359,4 + 1): La fonction Find trouve la position du caractère "-" à partir du 5ème caractère dans KTE-Jan-359. Et renvoie le résultat comme 8.
  • MID(B3, 5, 8 - 4 - 1): MID (KTE-Jan-359,5,3) ce qui signifie que la fonction MID extrait 3 nombre de caractères à partir du 5ème caractère dans la chaîne de texte KTE-Jan-359. Et le résultat est Jan.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

  • LEN(B3): La fonction LEN calcule la longueur totale de la chaîne de texte KTE-Jan-359 et renvoie le résultat 11.
  • FIND("-",B3,FIND("-",B3)+1): La fonction Find trouve la position du caractère "-" à partir du 5ème caractère dans KTE-Jan-359. Et renvoie le résultat comme 8.
  • RIGHT(B3,11 - 8)): La fonction DROITE extrait 3 (11-8) caractères du côté droit de KTE-Jan-359. Ici, le résultat est 359.

Fonctions connexes

Fonction Excel GAUCHE
La fonction LEFT extrait le nombre donné de caractères du côté gauche d'une chaîne fournie.

Fonction Excel FIND
La fonction FIND est utilisée pour rechercher une chaîne dans une autre chaîne et renvoie la position de départ de la chaîne dans une autre.

Fonction Excel MID
La fonction MID est utilisée pour rechercher et renvoyer un nombre spécifique de caractères à partir du milieu d'une chaîne de texte donnée.

Fonction Excel DROITE
La fonction DROITE extrait un nombre spécifique de caractères du côté droit de la chaîne de texte.

Fonction Excel LEN
La fonction Excel LEN renvoie le nombre de caractères dans une chaîne de texte.


Formules associées

Diviser les dimensions en deux parties dans Excel
Cet article explique comment utiliser des formules pour diviser les cotes d'une cellule en deux parties sans unités (longueur et largeur individuelles).

Séparer les nombres des unités de mesure
Cet article explique comment utiliser une formule pour séparer les nombres des unités de mesure.

Diviser le texte et les nombres dans une cellule dans Excel
Si vous souhaitez diviser le texte et les nombres d'une cellule en différentes cellules de colonne avec des formules, ce didacticiel vous rendra service.

Diviser le texte avec un délimiteur dans une cellule dans Excel
Dans cet article, nous fournissons un guide étape par étape pour vous aider à diviser le texte dans une cellule avec un délimiteur spécifique dans Excel.


Les meilleurs outils de productivité de bureau

Kutools for Excel - vous aide à vous démarquer de la foule

🤖 Aide à l'IA Kutools: Révolutionner l'analyse des données en s'appuyant sur : Exécution intelligente   |  Générer du code  |  Créer des formules personnalisées  |  Analyser les données et générer des graphiques  |  Invoquer les fonctions Kutools...
Caractéristiques populaires: Rechercher, mettre en évidence ou identifier les doublons  |  Supprimer les lignes vides  |  Combinez des colonnes ou des cellules sans perdre de données  |  Tour sans formule 
Super VRecherche: Plusieurs critères  |  Valeur multiple  |  Sur plusieurs feuilles  |  Recherche floue
Av. La liste déroulante: Liste déroulante facile  |  Liste déroulante dépendante  |  Liste déroulante à sélection multiple
Gestionnaire de colonnes: Ajouter un nombre spécifique de colonnes  |  Déplacer les colonnes  |  Basculer l'état de visibilité des colonnes masquées  Comparer les colonnes à Sélectionnez des cellules identiques et différentes 
Caractéristiques en vedette: Mise au point de la grille  |  Voir Design  |  Grande barre de formule  |  Gestionnaire de classeurs et de feuilles | Centre de ressources (Texte automatique)  |  Sélecteur de date  |  Combiner des feuilles de travail  |  Crypter/déchiffrer les cellules  |  Envoyer des e-mails par liste  |  Super filtre  |  Filtre spécial (filtre gras/italique/barré...) ...
Les 15 meilleurs ensembles d'outils12 Texte Outils (Ajouter du texte, Supprimer les caractères ...)  |  50+ Graphique Types (Diagramme de Gantt ...)  |  40+ Pratique Formules (Calculer l'âge en fonction de l'anniversaire ...)  |  19 Insertion Outils (Insérer le code QR, Insérer une image à partir du chemin ...)  |  12 Conversion Outils (Nombres en mots, Conversion des devises ...)  |  7 Fusionner et fractionner Outils (Lignes de combinaison avancées, Diviser les cellules Excel ...)  |  ... et plus

Kutools pour Excel possède plus de 300 fonctionnalités, Assurez-vous que ce dont vous avez besoin est à portée de clic...

Description


Onglet Office - Activer la lecture et l'édition par onglets dans Microsoft Office (y compris Excel)

  • Une seconde pour basculer entre des dizaines de documents ouverts!
  • Réduisez chaque jour des centaines de clics de souris, dites adieu à la souris.
  • Augmente votre productivité de 50% lors de l'affichage et de l'édition de plusieurs documents.
  • Apporte des onglets efficaces à Office (y compris Excel), tout comme Chrome, Edge et Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations