Accéder au contenu principal

Sommer les valeurs par numéro de semaine ou jour de la semaine dans Excel

Author: Siluvia Last Modified: 2025-08-06

Ce tutoriel présente étape par étape des formules pour vous aider à sommer les valeurs dans une plage spécifique en fonction du numéro de semaine ou du jour de la semaine spécifié dans Excel.

Comment sommer les valeurs par numéro de semaine dans Excel ?
Comment sommer les valeurs par jour de la semaine dans Excel ?

Comment sommer les valeurs par numéro de semaine dans Excel ?

Comme le montre la capture d'écran ci-dessous, pour sommer les valeurs dans la colonne Montant en fonction des dates correspondant à un certain numéro de semaine donné, nous proposons deux formules.

doc-sum-by-week-number-weekday-1

Formules génériques

=SOMME.SI.ENS( plage_valeurs, plage_colonne_aide, numero_semaine)

=SOMMEPROD(--(NO.SEMAINE(plage_dates+0,1)=numero_semaine),plage_valeurs)

Arguments

Plage_valeurs : La plage de valeurs que vous souhaitez sommer en fonction du numéro de semaine ;
Plage_colonne_aide : La plage des numéros de semaine extraits des dates ;
Numero_semaine : Le numéro de semaine utilisé comme critère pour la sommation des valeurs.

Comment utiliser cette formule ?

Utilisation de la formule SOMME.SI.ENS et d'une colonne d'aide

Pour utiliser la formule SOMME.SI.ENS, il faut d'abord appliquer la fonction NO.SEMAINE pour créer une colonne d'aide afin de calculer les numéros de semaine correspondants pour les dates dans la colonne Date.

=NO.SEMAINE(numéro_série, [type_retour])

La fonction NO.SEMAINE renvoie le numéro de semaine de la date donnée dans une année.

1. Dans ce cas, je sélectionne une cellule (F5) à côté de la première valeur dans la colonne Montant.

2. Entrez la formule ci-dessous dedans et appuyez sur la touche Entrée pour obtenir le numéro de semaine de la première date. Sélectionnez la cellule résultat, puis faites glisser son poignée de recopie automatique vers le bas pour obtenir les autres numéros de semaine. Voir capture d'écran :

=NO.SEMAINE(C5)

doc-sum-by-week-number-weekday-2

3. Sélectionnez une cellule pour afficher le montant total, entrez la formule ci-dessous dedans et appuyez sur la touche Entrée. Sélectionnez cette cellule résultat, faites glisser sa poignée de recopie automatique vers le bas pour obtenir les autres résultats.

=SOMME.SI.ENS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

Utilisation de la formule SOMMEPROD

Vous n’avez pas besoin de créer une colonne d’aide lorsque vous utilisez la formule SOMMEPROD pour résoudre ce problème.

1. Sélectionnez une cellule vide, entrez la formule ci-dessous dedans et appuyez sur la touche Entrée.

=SOMMEPROD(--(NO.SEMAINE($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. Sélectionnez la cellule résultat, faites glisser sa poignée de recopie automatique vers le bas pour obtenir les autres résultats selon vos besoins.

doc-sum-by-week-number-weekday-4

Explication de la formule

=SOMME.SI.ENS($E$5:$E$14, $F$5:$F$14, H6)

Après avoir calculé les numéros de semaine avec la fonction NO.SEMAINE, la fonction SOMME.SI.ENS somme les valeurs dans la plage E5:E14 si les numéros de semaine dans la colonne d'aide F5:F14 correspondent au numéro de semaine donné dans H6.

=SOMMEPROD(--(NO.SEMAINE($C$5:$C$14+0,1)=G6),$E$5:$E$14)

NO.SEMAINE($C$5:$C$14+0,1) : La fonction NO.SEMAINE calcule chaque numéro de semaine des dates dans la plage C5:C14 et renvoie un tableau comme ceci : {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6 : Ici, chaque numéro de semaine dans le tableau est comparé au numéro de semaine donné dans G6, et retourne un nouveau tableau : {VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX};
--{VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX} : Ces deux signes moins convertissent les « VRAI » et « FAUX » en 1 et 0. Vous obtiendrez ici un nouveau tableau comme ceci : {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100} : Chaque paire d'entrées dans les tableaux est multipliée ensemble et retourne {1428;2010;0;0;0;0;0;0;0;0};
SOMMEPROD({1428;2010;0;0;0;0;0;0;0;0}) : La fonction SOMMEPROD additionne tous les nombres dans le tableau et retourne le résultat final 1428+2010=3438.

Comment sommer les valeurs par jour de la semaine dans Excel ?

Comme le montre la capture d'écran ci-dessous, pour sommer les valeurs dans la colonne Montant par un certain jour de la semaine dans Excel, vous pouvez appliquer la fonction SOMMEPROD avec la fonction JOURSEM pour y parvenir.

Dans ce cas, comme nous devons sommer le montant total pour chaque jour de la semaine, avant d'appliquer la formule, nous créons une colonne d'aide avec les chiffres 1 à 7 pour indiquer séparément lundi à dimanche.

doc-sum-by-week-number-weekday-6

Formule générique

=SOMMEPROD((JOURSEM(plage_dates,2)=numero_jour)*plage_valeurs)

Arguments

Plage_dates : La plage de dates où vous souhaitez évaluer les jours de la semaine donnés ;
Plage_valeurs : La plage de valeurs que vous souhaitez sommer en fonction du jour de la semaine ;
2 : Le chiffre 2 représente les chiffres 1 (lundi) à 7 (dimanche) ;
Numero_jour : Le numéro du jour de la semaine utilisé comme critère pour la sommation des valeurs. Il peut s'agir d'une référence de cellule ou d'un nombre compris entre 1 et 7.

Comment utiliser cette formule ?

1. Sélectionnez une cellule à côté de la cellule contenant le chiffre 1. Ici, je sélectionne I6.

2. Copiez ou entrez la formule ci-dessous dedans et appuyez sur la touche Entrée. Sélectionnez la cellule résultat, puis faites glisser sa poignée de recopie automatique vers le bas pour obtenir les résultats pour les autres jours de la semaine.

=SOMMEPROD((JOURSEM($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

Remarque : Si vous avez juste besoin de sommer les valeurs en fonction d'un seul jour de la semaine spécifié, comme vendredi, vous pouvez directement entrer le chiffre 5 dans la formule comme suit.

=SOMMEPROD((JOURSEM($C$5:$C$14,2)=5)*$E$5:$E$14)

Explication de la formule

=SOMMEPROD((JOURSEM($C$5:$C$14,2)=H6)*$E$5:$E$14)

JOURSEM($C$5:$C$14,2) : La fonction JOURSEM renvoie des nombres entiers de 1 à 7 pour représenter les jours de la semaine de lundi à dimanche dans la plage C5:C14 : {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6 : Ici, chaque jour de la semaine dans le tableau est comparé au numéro du jour de la semaine donné dans H6, et retourne un nouveau tableau : {FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;VRAI;FAUX;FAUX;FAUX};
{FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;VRAI;FAUX;FAUX;FAUX}*$E$5:$E$14 : Ici, les VRAI et FAUX sont convertis en 1 et 0, puis multipliés avec les valeurs dans E5:E14 pour retourner le tableau : {0;0;2288;0;0;0;1325;0;0;0};
SOMMEPROD{0;0;2288;0;0;0;1325;0;0;0} : La fonction SOMMEPROD additionne tous les nombres dans le tableau et retourne le résultat final 2288+1325=3613.

Fonctions connexes

Fonction NO.SEMAINE Excel
La fonction Excel SOMME.SI.ENS renvoie le numéro de semaine de la date donnée dans une année, qui commence à compter les semaines à partir du 1er janvier.

Fonction SOMMEPROD Excel
La fonction Excel SOMMEPROD peut être utilisée pour multiplier deux ou plusieurs colonnes ou tableaux ensemble, puis obtenir la somme des produits.

Fonction JOURSEM Excel
La fonction Excel FIN.MOIS renvoie un nombre entier de 1 à 7 pour représenter le jour de la semaine pour une date donnée dans Excel.

Formules connexes

Sommer les valeurs par mois (avec ou sans année)
Ce tutoriel explique en détail deux formules pour aider à sommer les valeurs par un certain mois et année ou sommer les valeurs par un certain mois en ignorant l'année dans Excel.

Sommer les valeurs par la semaine d'une date donnée
Ce tutoriel parle de la façon de sommer les valeurs par la semaine dans laquelle une date donnée tombe.

Sommer toutes les n lignes ou colonnes dans une plage
Ce tutoriel explique deux formules basées sur les fonctions SOMME et DECALER pour sommer toutes les n lignes ou colonnes dans une plage spécifiée dans Excel.

Sommer chaque nième ligne ou colonne dans une plage
Ce tutoriel va vous montrer comment créer une formule basée sur les fonctions SOMMEPROD, MOD et COLONNE pour sommer chaque nième ligne ou colonne dans une plage dans Excel.

Les meilleurs outils de productivité pour Office

Kutools pour Excel - Vous aide à vous démarquer de la foule

🤖 Assistant AI de KUTOOLS : Révolutionnez l'analyse des données grâce à : Exécution Intelligente   |  Générer du Code  |  Créer des Formules Personnalisées  |  Analyser les Données et Générer des Graphiques  |  Invoquer les Fonctions de Kutools…
Fonctionnalités populaires : Rechercher, Mettre en évidence ou Identifier les Doublons  |  Supprimer les Lignes Vides  |  Combiner les Colonnes ou les Cellules sans Perte de Données  |  Arrondir sans Formule ...
Super VLookup : Critères Multiples  |  Valeurs Multiples  |  À Travers Plusieurs Feuilles  |  Correspondance Floue...
Liste Déroulante Avancée : Liste Déroulante Facile  |  Liste Déroulante Dépendante  |  Liste Déroulante Multi-sélection...
Gestionnaire de Colonnes : Ajouter un Nombre Spécifique de Colonnes  |  Déplacer les Colonnes  |  Basculer l'État de Visibilité des Colonnes Masquées  |  Comparer les Colonnes pour Sélectionner les Mêmes Cellules et Différentes Cellules ...
Fonctionnalités phares : Mise au point de la Grille  |  Affichage de Conception  |  Barre de Formule Améliorée  |  Gestionnaire de Classeur et Feuilles de Calcul | Bibliothèque d'AutoTexte (Texte Automatique)  |  Sélecteur de Date  |  Fusionner les Feuilles de Calcul  |  Chiffrer/Déchiffrer les Cellules  |  Envoyer des Emails par Liste  |  Super Filtre  |  Filtre Spécial (filtrer gras/italique/barré...) ...
Top 15 ensembles d'outils :  12 Outils de Texte (Ajouter du texte, Supprimer des caractères ...)  |  50+ Types de Graphiques (Diagramme de Gantt ...)  |  40+ Formules Pratiques (Calculer l’âge en fonction de la date de naissance ...)  |  19 Outils d'Insertion (Insérer un code QR, Insérer une image depuis le chemin ...)  |  12 Outils de Conversion (Convertir en mots, Conversion de devises ...)  |  7 Outils de Fusion et Division (Fusion avancée des lignes, Diviser les cellules Excel ...)  |  ... et plus encore
Utilisez Kutools dans votre langue préférée – prend en charge l'anglais, l'espagnol, l'allemand, le français, le chinois et plus de 40 autres langues !

Kutools pour Excel compte plus de 300 fonctionnalités, garantissant que ce dont vous avez besoin n'est qu'à un clic...

Office Tab - Active la lecture et l'édition par onglets dans Microsoft Office (y compris Excel)

  • Passez d'un document ouvert à un autre en une seconde !
  • Réduisez des centaines de clics de souris chaque jour, dites adieu à la fatigue de la souris.
  • Augmente votre productivité de 50 % lors de la consultation et de la modification de plusieurs documents.
  • Apporte des onglets efficaces à Office (y compris Excel), tout comme Chrome, Edge et Firefox.