Note: The other languages of the website are Google-translated. Back to English
Se connecter  \/ 
x
or
x
S’enregistrer  \/ 
x

or

MS Excel IF fonction

La fonction IF est l'une des fonctions les plus simples et les plus utiles du classeur Excel. Il effectue un test logique simple qui dépend du résultat de la comparaison, et il renvoie une valeur si un résultat est VRAI, ou une autre valeur si le résultat est FAUX.


 syntaxe:

La syntaxe de la fonction IF dans Excel est:

=IF (logical_test, [value_if_true], [value_if_false])

doc si fonction 2


 Arguments:

  • logical_test: Obligatoire. C'est la condition que vous souhaitez tester.
  • value_if_true: Optionnel. Une valeur spécifique que vous souhaitez renvoyer si le résultat du test_logique est TRUE.
  • value_if_false: Optionnel. Valeur que vous souhaitez renvoyer si le résultat du test_logique est FALSE.

Notes:

1. Si value_if_true est omis:

  • Si la value_if_true L'argument est omis dans la fonction IF, par exemple uniquement la virgule après le test_logique, il renverra zéro lorsque la condition est remplie. Par exemple: =IF(C2>100,, "Low ").
  • Si vous souhaitez utiliser une cellule vide au lieu du zéro si la condition est remplie, vous devez entrer des guillemets doubles "" dans le deuxième paramètre, comme ceci: =IF(C2>100, "", "Low").
doc si fonction 3 doc si fonction 4

2. Si value_if_false est omis:

  • Si la value_if_false est omis dans la fonction IF, il renverra un FALSE lorsque la condition spécifiée n'est pas remplie. Tel que: =IF(C2>100, "High").
  • Si vous mettez une virgule après l'argument value_if_true, il renverra un zéro lorsque la condition spécifiée n'est pas remplie. Tel que: =IF(C2>100, "High" ,).
  • Si vous entrez des guillemets doubles "" dans le troisième paramètre, une cellule vide sera renvoyée si la condition n'est pas remplie. Tel que: =IF(C2>100, "High" , "").
doc si fonction 5 doc si fonction 6 doc si fonction 7

 Retour:

Tester une condition spécifique, renvoie la valeur correspondante que vous fournissez pour TRUE ou FALSE.


 Exemples:

Exemple 1: Utilisation d'une simple fonction IF pour les nombres

Par exemple, en supposant que vous souhaitiez tester une liste de valeurs, si la valeur est supérieure à une valeur spécifique 100, un texte «Good» est affiché, sinon, un texte «Bad» est renvoyé.

Entrez la formule ci-dessous et vous obtiendrez le résultat ci-dessous selon vos besoins.

=IF(B2>100,"Good","Bad")

doc si fonction 8


Exemple 2: utilisation de la fonction IF pour les valeurs de texte

Cas 1: fonction IF pour les valeurs de texte insensible à la casse:

Ici, j'ai un tableau avec une liste de tâches et l'état d'achèvement, maintenant, je veux savoir quelles tâches doivent être exécutées et lesquelles ne le sont pas. Lorsque le texte de la colonne C est complété, «Non» sera affiché, sinon, «Oui» sera renvoyé.

Veuillez appliquer la formule suivante, maintenant, la cellule retournera «Non» lorsque le texte de la colonne C est affiché comme «terminé», qu'il soit en majuscules ou en minuscules; si un autre texte dans la colonne C, «Oui» sera renvoyé. Voir la capture d'écran:

=IF(C2="completed", "No", "Yes")

doc si fonction 9

Cas 2: fonction IF pour les valeurs de texte sensibles à la casse:

Pour tester les valeurs de texte en respectant la casse, vous devez combiner la fonction IF avec la fonction EXACT, veuillez appliquer la formule ci-dessous, puis seul le texte avec la correspondance exacte sera reconnu et vous obtiendrez le résultat ci-dessous comme vous le souhaitez:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc si fonction 10

Cas 3: Fonction IF pour les valeurs de texte avec correspondance partielle:

Parfois, vous devez vérifier les valeurs de cellule en fonction du texte partiel.Dans ce cas, vous devez utiliser les fonctions IF, ISNUMBER et SEARCH ensemble.

Par exemple, si vous souhaitez vérifier les cellules qui contiennent le texte «comp», puis renvoyer les valeurs correspondantes, veuillez appliquer la formule ci-dessous. Et vous obtiendrez le résultat comme ci-dessous la capture d'écran montrée:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc si fonction 11

Notes :

  • 1. La fonction RECHERCHE est appliquée pour le texte insensible à la casse, si vous souhaitez vérifier le texte sensible à la casse, vous devez remplacer la fonction RECHERCHE par la fonction FIND. Comme ça:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Les valeurs de texte comme paramètres dans les formules IF, vous devez les mettre entre "guillemets".

Exemple 3: Utilisation de la fonction IF pour les valeurs de date

Cas 1: Fonction IF pour les dates pour comparer les dates avec une date spécifique:

Si vous souhaitez comparer des dates pour vérifier si elles sont supérieures ou inférieures à une date spécifique, la fonction IF peut également vous rendre service. Comme la fonction IF ne peut pas reconnaître un format de date, vous devez combiner une fonction DATEVALUE avec elle.

Veuillez appliquer cette formule, lorsque la date est supérieure au 4/15/2019, un «Oui» sera renvoyé, sinon la formule renverra un texte «Non», voir capture d'écran:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc si fonction 12

Notes: Dans la formule ci-dessus, vous pouvez utiliser la référence de cellule directement sans utiliser la fonction DATEVALUE. Comme ça: =IF(D4>$D$1, "Yes", "No").

doc si fonction 13

Cas 2: la fonction IF pour les dates de vérification des dates est supérieure ou inférieure à 30 jours:

Si vous souhaitez identifier les dates qui sont supérieures ou inférieures à 30 jours à partir de la date actuelle, vous pouvez combiner la fonction AUJOURD'HUI avec la fonction IF.

Veuillez saisir cette formule:

Identifiez la date de plus de 30 jours: =IF(TODAY()-C4>30,"Older date","")

Identifiez la date supérieure à 30 jours: =IF(C4-TODAY()>30, "Future date", "")

doc si fonction 14 doc si fonction 15

Note : Si vous souhaitez mettre les deux résultats dans une colonne, vous devez utiliser une fonction IF imbriquée comme suit:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc si fonction 16


Exemple 4: Utilisation de la fonction IF avec la fonction AND, OR ensemble

C'est une utilisation courante pour nous de combiner les fonctions IF, AND, OR ensemble dans Excel.

Cas 1: Utilisation de la fonction IF avec les fonctions AND pour vérifier si toutes les conditions sont vraies:

Je veux vérifier si toutes les conditions que j'ai définies sont remplies, telles que: B4 est rouge, C4 est petit et D4> 200. Si toutes les conditions sont TURE, marquez le résultat comme «Oui»; Si l'une ou l'autre des conditions est FAUX, renvoyez «Non».

Veuillez appliquer cette formule et vous obtiendrez le résultat comme suit:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc si fonction 17

Cas 2: L'utilisation de la fonction IF avec les fonctions OR pour vérifier l'une des conditions est vraie:

Vous pouvez également utiliser les fonctions IF et OR pour vérifier si l'une des conditions est vraie, par exemple, je veux identifier si la cellule de la colonne B contient le texte "Bleu" ou "Rouge", s'il y a du texte dans la colonne B, Oui s'affiche, sinon, Non est renvoyé.

Ici, vous devez appliquer cette formule, et le résultat ci-dessous sera affiché:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc si fonction 18

Cas 3: Utilisation de la fonction IF avec les fonctions AND et OR ensemble:

Cet exemple, je vais combiner la fonction IF avec les deux fonctions AND & OR en même temps. En supposant, vous devriez vérifier les conditions suivantes:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Si l'une des conditions ci-dessus est remplie, une correspondance est renvoyée, sinon, non.

Veuillez utiliser cette formule, et vous obtiendrez le résultat ci-dessous selon vos besoins:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc si fonction 19


Exemple 5: Utilisation de la fonction IF imbriquée

La fonction IF est utilisée pour tester une condition et renvoyer une valeur si la condition est remplie et une autre valeur si elle n'est pas remplie. Mais, parfois, vous devriez avoir besoin de vérifier plus d'une condition en même temps et de renvoyer des valeurs différentes, vous pouvez utiliser IF imbriqué pour résoudre ce travail.

Une instruction IF imbriquée qui combine plusieurs conditions IF, cela signifie mettre une instruction IF dans une autre instruction IF et répéter ce processus plusieurs fois.

La syntaxe de la fonction IF imbriquée dans Excel est:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

Notes: Dans Excel 2007 et les versions ultérieures, vous pouvez imbriquer jusqu'à 64 fonctions IF dans une formule, et dans Excel 2003 et les versions antérieures, seules 7 fonctions IF imbriquées peuvent être utilisées.

Cas 1: Fonction IF imbriquée pour vérifier plusieurs conditions:

Une utilisation classique de la fonction IF imbriquée consiste à attribuer une note à chaque élève en fonction de ses scores. Par exemple, vous avez une table avec les étudiants et leurs résultats d'examen, vous voulez maintenant classer les scores avec les conditions suivantes:

doc si fonction 20

Veuillez appliquer cette formule, et vous obtiendrez le résultat ci-dessous, si le score est supérieur ou égal à 90, la note est «Excellent», si le score est supérieur ou égal à 80, la note est «Bon», si le score est supérieur ou égal à 60, la note est «moyenne», sinon la note est «médiocre».

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc si fonction 21

Explication de la formule ci-dessus:

doc si fonction 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Cas 2: Fonction IF imbriquée pour calculer le prix en fonction de la quantité:

La fonction IF imbriquée peut également être utilisée pour calculer le prix du produit en fonction de la quantité.

Par exemple, vous souhaitez offrir aux clients une remise en fonction de la quantité, plus de quantité qu'ils achètent, plus de remise qu'ils obtiendront, comme illustré ci-dessous.

doc si fonction 23

Comme le prix total est égal à la quantité, multipliez le prix, vous devez donc multiplier la quantité spécifiée par la valeur renvoyée par les If imbriqués. Veuillez utiliser cette formule:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc si fonction 24

Notes: Vous pouvez également utiliser les références de cellule pour remplacer les numéros de prix statiques, lorsque les données source changent, vous ne devriez pas avoir besoin de mettre à jour la formule, veuillez utiliser cette formule: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc si fonction 25

Capsules: En utilisant la fonction IF pour construire un test, vous pouvez utiliser les opérateurs logiques suivants:

Opérateur Sens Exemple Description
> Supérieure à =IF(A1>10, "OK",) Si le nombre de la cellule A1 est supérieur à 10, la formule renvoie «OK»; sinon 0 est renvoyé.
< Moins que =IF(A1<10, "OK", "") Si le nombre de la cellule A1 est inférieur à 10, la formule renvoie «OK»; sinon, une cellule vide est renvoyée.
>= Plus grand ou égal à =IF(A1>=10, "OK", "Bad") Si le nombre dans la cellule A1 est supérieur ou égal à 10, il renverra "OK"; sinon, "Bad" s'affiche.
<= Inférieur ou égal à =IF(A1<=10, "OK", "No") Si le nombre de la cellule A1 est inférieur ou égal à 10, il renvoie «OK»; sinon, «Non» est renvoyé.
= Égal à =IF(A1=10, "OK", "No") Si le nombre de la cellule A1 est égal à 10, il renvoie "OK"; sinon, il affiche "Non".
<> Pas égal à =IF(A1<>10, "No", "OK") Si le nombre de la cellule A1 n'est pas égal à 10, la formule renvoie «Non»; sinon - "OK".

Les meilleurs outils de productivité de bureau

Kutools for Excel - vous aide à vous démarquer de la foule

Souhaitez-vous terminer votre travail quotidien rapidement et parfaitement? Kutools for Excel apporte 300 fonctionnalités avancées puissantes (Combiner les classeurs, somme par couleur, diviser le contenu des cellules, convertir la date, etc.) et gagner 80% de temps pour vous.

  • Conçu pour 1500 scénarios de travail, vous aide à résoudre 80% des problèmes Excel.
  • Réduisez les milliers de clics de clavier et de souris chaque jour, soulagez vos yeux et vos mains fatigués.
  • Devenez un expert Excel en 3 minutes. Plus besoin de se souvenir des formules douloureuses et des codes VBA.
  • Essai gratuit illimité de 30 jours. Garantie de remboursement de 60 jours. Mise à jour et assistance gratuites pendant 2 ans.
Ruban d'Excel (avec Kutools for Excel installé)

Onglet Office - Activer la lecture et la modification par onglets dans Microsoft Office (y compris Excel)

  • Une seconde pour basculer entre des dizaines de documents ouverts!
  • Réduisez chaque jour des centaines de clics de souris, dites adieu à la souris.
  • Augmente votre productivité de 50% lors de l'affichage et de l'édition de plusieurs documents.
  • Apporte des onglets efficaces à Office (y compris Excel), tout comme Chrome, Firefox et le nouvel Internet Explorer.
Capture d'écran d'Excel (avec Office Tab installé)

Say something here...
symbols left.
You are guest
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.