Comment obtenir la liste des dossiers dans Outlook?

Auteur : Siluvia Dernière modification: 2014-09-26

Parfois, l'arborescence de tous les dossiers de messagerie (y compris les dossiers personnels créés) dans le volet de navigation peut aider les utilisateurs d'Outlook pendant leur travail. Pour lister rapidement l'ensemble des dossiers de l'arborescence, le code VBA peut vous aider. Dans ce didacticiel, vous pouvez apprendre à obtenir facilement la liste des dossiers avec le code VBA.

Obtenir la liste des dossiers dans Outlook avec le code VBA

Onglet Office - Activez l'édition et la navigation par onglets dans Microsoft Office, ce qui facilite le travail

Lire la suite...Télécharger ...

Kutools for Outlook - Boostez Outlook avec plus de 100 fonctionnalités avancées pour une efficacité supérieure

Automatisez l'envoi d'e-mails avec CC / BCC automatique, Transfert automatique par des règles ; envoyer Réponse automatique (Out of Office) sans nécessiter de serveur Exchange...
Recevez des rappels comme Avertissement BCC lorsque vous répondez à tous alors que vous êtes dans la liste BCC, et Rappeler en cas de pièces jointes manquantes pour les pièces jointes oubliées...
Améliorez l'efficacité de la messagerie avec Répondre (à tous) avec pièces jointes, Ajouter automatiquement un message d'accueil ou une date et une heure dans la signature ou l'objet, Répondre à plusieurs e-mails
Rationalisez l'envoi d'e-mails avec Rappel des e-mails, Outils de fixation (Tout compresser, Tout enregistrer automatiquement...), Supprimer les doublonset Rapport rapide

Boostez votre Outlook 2021 - 2010 ou Outlook 365 avec ces fonctionnalités avancées. Profitez d'un essai gratuit complet de 60 jours et améliorez votre expérience de messagerie !

Lire la suite...Télécharger ...

Obtenir la liste des dossiers dans Outlook avec le code VBA

Pour obtenir la liste des dossiers dans Outlook avec le code VBA, procédez comme suit.

1. appuie sur le autre + F11 touches sur le clavier pour ouvrir le Microsoft Visual Basic pour applications fenêtre.

2. Double-cliquez ensuite sur le Project1 > Objet Microsoft Outlook > Cette session Outlook ouvrir le Projet1 - ThisOutlookSession la fenêtre. Voir la capture d'écran:

3. Puis copiez et collez le code VBA ci-dessous dans la fenêtre Project1 - ThisOutlookSession.

VBA: obtenir la liste des dossiers dans Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. appuie sur le F5 touche du clavier pour démarrer l'exécution du code VBA.

5. Maintenant un Macro boîte de dialogue apparaît, veuillez cliquer sur le Courir .

6. Attendez que la macro s'exécute. Ensuite, la liste de tous vos dossiers de courrier électronique est immédiatement répertoriée dans une nouvelle fenêtre de message créée. Vous pouvez facilement l'imprimer. Voir la capture d'écran: