Comment masquer le numéro de fax dans la boîte de dialogue « Sélectionner la liste des noms » d’Outlook ?

Dans Outlook, vous avez peut-être remarqué que, dans la liste « Sélectionner des noms » ou dans le Carnet d’adresses, la colonne Adresse e-mail affiche non seulement des adresses e-mail, mais aussi des entrées de fax parfois gênantes. Dans cet article, je vous propose plusieurs méthodes pour masquer ces numéros de fax.

Masquer le numéro de fax dans la boîte de dialogue « Sélectionner Liste des noms » à l’aide de VBA

---

Masquer le numéro de fax dans la boîte de dialogue « Sélectionner Liste des noms » à l’aide de VBA

Si vous souhaitez masquer les numéros de fax existants dans la boîte de dialogue « Sélectionner Liste des noms », procédez comme suit :

1. Appuyez sur les touches Alt + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Cliquez sur Insertion > Module afin d’insérer un nouveau module vide, puis copiez et collez le code ci-dessous dans le script.

VBA : Masquer les numéros de fax existants dans « Sélectionner des noms »

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. Appuyez sur la touche F5 pour exécuter le code. Les numéros de fax sont désormais masqués.

Si vous souhaitez masquer le numéro de fax dans Contact, procédez comme suit :

1. Appuyez sur Alt + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Double-cliquez sur ThisOutlookSession dans le volet Projet - 1, puis copiez et collez le code ci-dessous dans le script.

VBA : Masquer le numéro de fax dans les nouveaux Ajouter un contact

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Enregistrez le code et redémarrez Outlook afin que les modifications prennent effet.

Désormais, les numéros de fax des contacts nouvellement créés seront masqués dans la fenêtre « Sélectionner des noms : Contacts ».