Comment imprimer des tâches classées par catégorie dans Outlook ?

Supposons que vous ayez plusieurs catégories de couleur dans vos tâches Outlook et que vous souhaitiez imprimer les listes de tâches par catégorie, chacune sur une page distincte. Comment procéder dans Outlook ?

Imprimer les tâches par catégories sur des pages différentes manuellement, une par une

Imprimer les tâches par catégories sur des pages différentes à l’aide d’un code VBA

---

Imprimer les tâches par catégories sur des pages différentes manuellement, une par une

Dans Outlook, vous pouvez imprimer manuellement vos tâches par catégorie, chacune sur une page distincte. Voici la marche à suivre :

1. Lancez Outlook, accédez au volet Tâches, sélectionnez le dossier de tâches à imprimer, puis appuyez sur Ctrl + E pour activer la zone Recherche. Ensuite, sous l’onglet Recherche, cliquez sur l’icône Catégorisé et choisissez la catégorie colorée que vous souhaitez imprimer (voir capture d’écran) :

2. Toutes les tâches liées à cette catégorie colorée s’affichent alors instantanément (voir la capture d’écran) :

3. Ensuite, cliquez successivement sur Fichier > Imprimer pour imprimer cette liste de tâches, comme illustré dans la capture d’écran suivante :

4. Répétez les étapes ci-dessus pour imprimer manuellement, une par une, les listes de tâches associées aux autres catégories de couleur.

---

Imprimer les tâches par catégories sur des pages différentes à l’aide d’un code VBA

Voici un code VBA qui vous permet d’imprimer, en une seule opération, les tâches par catégorie sur des pages séparées. Suivez les étapes suivantes :

1. Accédez au volet Tâches et sélectionnez le dossier de tâches que vous souhaitez imprimer.

2. Maintenez ensuite enfoncées les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

3. Cliquez ensuite sur Insertion > Module, puis copiez-collez le code ci-dessous dans le module vide qui s’ouvre :

Code VBA : Imprimer les tâches par catégories sur des pages différentes :

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Cliquez ensuite sur Outils > Références dans la fenêtre Microsoft Visual Basic pour Applications. Dans la boîte de dialogue Références - Projet1 qui s’affiche, cochez les options Microsoft Excel Object Library et Microsoft Scripting Runtime dans la liste Références disponibles (voir capture d’écran) :

5. Cliquez ensuite sur le bouton OK, puis appuyez sur la touche F5 pour exécuter ce code. Une fois l’exécution terminée, les listes de tâches classées par catégorie seront imprimées sur des pages distinctes.