Comment répondre normalement à partir du dossier Éléments envoyés dans Outlook ?

Généralement, lorsque vous cliquez sur la fonction **Répondre** dans le dossier **Éléments envoyés** pour envoyer un nouveau message aux destinataires à qui vous avez déjà écrit, votre propre adresse e-mail apparaît automatiquement dans le champ **À**, comme illustré dans la capture d’écran ci-dessous. Cela peut vite devenir gênant, puisqu’il vous faut la remplacer manuellement à chaque fois. Comment faire pour qu’Outlook utilise à la place l’adresse du destinataire d’origine ?

Répondre normalement dans le dossier Éléments envoyés à partir d’Outlook avec la fonction Répondre à tous

Répondre normalement dans le dossier Éléments envoyés à partir d’Outlook avec un code VBA

---

Répondre normalement dans le dossier Éléments envoyés à partir d’Outlook avec la fonction Répondre à tous

Dans Outlook, la fonction Répondre à tous peut vous aider à résoudre ce problème. Procédez comme suit :

Lorsque vous devez répondre à un courrier envoyé afin de le renvoyer tout en conservant l’adresse du destinataire d’origine, cliquez sur le bouton Répondre à tous, et l’adresse du destinataire d’origine apparaîtra dans le champ À, comme illustré dans la capture d’écran suivante :

---

Répondre normalement dans le dossier Éléments envoyés à partir d’Outlook avec un code VBA

Il arrive parfois que vous oubliiez la fonction Répondre à tous en répondant à un message envoyé. Le code VBA ci-dessous vous permet donc d’utiliser simplement la fonction Répondre pour répondre normalement depuis le dossier Éléments envoyés. Suivez les étapes suivantes :

1. Maintenez enfoncées les touches ALT + F11 pour ouvrir la fenêtre Microsoft Visual Basic pour Applications.

2. Dans la fenêtre Microsoft Visual Basic pour Applications, double-cliquez sur ThisOutlookSession dans le volet Projet1 (VbaProject.OTM) pour ouvrir le module, puis copiez-collez le code suivant dans le module vide.

Code VBA : Répondre normalement dans le dossier Éléments envoyés à partir d’Outlook :

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Ensuite, enregistrez le code et redémarrez Outlook pour que les modifications prennent effet. Désormais, lorsque vous cliquerez sur Répondre pour renvoyer un courrier depuis le dossier Éléments envoyés, l’adresse du destinataire d’origine s’affichera dans le champ À, exactement comme vous le souhaitez.