Outlook : comment supprimer les éléments en double du calendrier

Il arrive parfois que des doublons apparaissent dans le calendrier lors de l’importation d’événements depuis d’autres appareils. Ce tutoriel vous propose deux méthodes efficaces pour les supprimer : la première consiste à les éliminer manuellement, un par un, lorsque leur nombre est limité ; la seconde utilise un script VBA pour les supprimer tous en une seule opération.

Supprimer manuellement Supprimer les doublons les éléments du calendrier un par un

Utiliser un code VBA pour Supprimer les doublons les éléments du calendrier en une seule fois

---

Supprimer manuellement Supprimer les doublons les éléments du calendrier un par un

Pour supprimer les doublons du calendrier un par un, commencez par les trier de façon précise afin d’identifier clairement les éléments en double, puis éliminez-les individuellement.

1. Par défaut, le calendrier s’affiche en mode « Calendrier ». Sélectionnez le calendrier dont vous souhaitez supprimer les doublons, puis cliquez sur « Affichage » > « Modifier la vue » > « Liste ».

Le calendrier s’affiche désormais en liste.

2. Ensuite, définissez un critère pour identifier les doublons. Par exemple, si vous souhaitez comparer les éléments ayant le même objet, cliquez sur la colonne « OBJET » dans la liste du calendrier : tous les éléments partageant cet objet seront automatiquement regroupés.

3. Vous pouvez désormais supprimer un par un les éléments ayant le même objet en cliquant droit sur l’élément concerné, puis en choisissant « Supprimer » dans le menu contextuel qui s’affiche.

---

---

Utiliser un code VBA pour Supprimer les doublons les éléments du calendrier en une seule fois

Voici quelques exemples de code VBA pour supprimer tous les éléments en double d’un dossier de calendrier, adaptés à différents scénarios.

1. Appuyez sur « Alt » + « F11 » pour ouvrir la fenêtre « Microsoft Visual Basic pour Applications ».

2. Cliquez sur « Insertion » > « Module » pour créer un nouveau module vide, puis copiez-collez le code ci-dessous dedans.

Code VBA : supprimer tous les éléments en double du calendrier appartenant à une catégorie spécifique

'Sub RemoveDuplicateCalendar()
'UpdatebyExtendoffice20220413
  Dim xStores As Stores
  Dim xStore As Store
  Dim xRootFolder As Folder
  Dim xFolder As Object
  Set xStores = Application.Session.Stores
  For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
      Call ProcessFolders(xFolder)
    Next
  Next
  Set xStores = Nothing
End Sub

Sub ProcessFolders(ByVal CurrentFld As Folder)
  Dim xDictionary As Object
  Dim i As Long
  Dim xItem As Object
  Dim xKey As String
  Dim xSubFld As Folder
  On Error Resume Next
  If CurrentFld.DefaultItemType <> olAppointmentItem Then Exit Sub
  Set xDictionary = CreateObject("Scripting.Dictionary")
  For i = CurrentFld.Items.Count To 1 Step -1
    Set xItem = CurrentFld.Items.Item(i)
    'change categories as you need in below script
    If xItem.Categories = "date" Then
    'change the comparing items as you need
      xKey = xItem.Subject & xItem.Location & xItem.Body & xItem.Categories
      If xDictionary.Exists(xKey) = True Then
        xItem.Delete
      Else
        xDictionary.Add xKey, True
      End If
    End If
  Next i
  For Each xSubFld In CurrentFld.Folders
    ProcessFolders xSubFld
  Next
End Sub

Ce code VBA supprime tous les doublons dans la catégorie « date » en comparant l’objet, le lieu, le corps du message et la catégorie. Vous pouvez adapter ces critères à vos besoins.

3. Ensuite, appuyez sur «F5» ou cliquez sur « Exécuter » pour lancer le code. La boîte de dialogue « Macros » s’ouvre ; sélectionnez « RemoveDuplicateCalendar », puis cliquez sur « Exécuter ». .

Les doublons dans la catégorie « date » ont été supprimés.

Code VBA : supprimer tous les éléments en double du calendrier, quelles que soient leurs catégories

Sub RemoveDuplicateCalendar()
'UpdatebyExtendoffice20220413
  Dim xStores As Stores
  Dim xStore As Store
  Dim xRootFolder As Folder
  Dim xFolder As Object
  Set xStores = Application.Session.Stores
  For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
      Call ProcessFolders(xFolder)
    Next
  Next
  Set xStores = Nothing
End Sub

Sub ProcessFolders(ByVal CurrentFld As Folder)
  Dim xDictionary As Object
  Dim i As Long
  Dim xItem As Object
  Dim xKey As String
  Dim xSubFld As Folder
  On Error Resume Next
  If CurrentFld.DefaultItemType <> olAppointmentItem Then Exit Sub
  Set xDictionary = CreateObject("Scripting.Dictionary")
  For i = CurrentFld.Items.Count To 1 Step -1
    Set xItem = CurrentFld.Items.Item(i)
    'change the comparing items as you need
      xKey = xItem.Subject & xItem.Location & xItem.Body & xItem.Categories
      If xDictionary.Exists(xKey) = True Then
        xItem.Delete
      Else
        xDictionary.Add xKey, True
      End If
  Next i
  For Each xSubFld In CurrentFld.Folders
    ProcessFolders xSubFld
  Next
End Sub

L’exécution de ce code supprime, au sein de chaque catégorie, tous les doublons dont l’objet, le lieu, le corps du message et la catégorie sont identiques.

Remarque : les codes VBA ci-dessus fonctionnent dans le dossier Calendrier, y compris ses sous-dossiers.