Comment classer les emails par mois dans Outlook ?

S'il y a beaucoup d'e-mails dans votre boîte de réception, pour que la boîte aux lettres soit soignée et bien organisée, vous pouvez les stocker ou les archiver dans différents dossiers en fonction du mois spécifique de l'heure de réception des e-mails, comme illustré ci-dessous. Normalement, vous pouvez créer les dossiers manuellement puis les déplacer un par un. Évidemment, cette approche sera longue et fastidieuse. Dans cet article, je parlerai d'un code VBA pour résoudre cette tâche rapidement et facilement.

Classer les e-mails en fonction du mois avec le code VBA

Pour déplacer les e-mails vers différents dossiers en fonction du mois, veuillez appliquer le code VBA ci-dessous :

1. Cliquez pour sélectionner le Mes Messages dossier dans lequel vous souhaitez classer les e-mails.

2. Maintenez le ALT + F11 clés pour ouvrir le Microsoft Visual Basic pour applications fenêtre.

3. Cliquez insérer > Moduleet collez le code suivant dans la fenêtre Module.

Code VBA : classer les e-mails en fonction du mois

Sub ClassifyEmailsbyMonth()
'Updateby ExtendOffice
Dim xCurFolder As Folder
Dim xMoveFolder As Folder
Dim xMail As MailItem
Dim I As Long
Dim xYear As String, xMonth As String
On Error Resume Next
Set xCurFolder = Application.ActiveExplorer.CurrentFolder
For I = xCurFolder.Items.Count To 1 Step -1
  DoEvents
  If xCurFolder.Items.Item(I).Class = olMail Then
    Set xMail = xCurFolder.Items.Item(I)
    xYear = Year(xMail.ReceivedTime)
    xMonth = Month(xMail.ReceivedTime)
    Set xMoveFolder = Nothing
    Set xMoveFolder = xCurFolder.Folders(xYear & "." & xMonth)
    If xMoveFolder Is Nothing Then
      Set xMoveFolder = xCurFolder.Folders.Add(xYear & "." & xMonth)
    End If
    xMail.Move xMoveFolder
  End If
Next
Set xMoveFolder = Nothing
Set xCurFolder = Nothing
End Sub

4. Puis appuyez F5 clé pour exécuter ce code, et tous les e-mails dans le dossier de la boîte de réception sélectionné sont classés par mois spécifique de l'heure de réception des e-mails, voir capture d'écran :