Accéder au contenu principal

Maîtriser les instructions SI imbriquées dans Excel – Un guide étape par étape

Author: Siluvia Last Modified: 2025-05-27

Dans Excel, bien que la fonction SI soit essentielle pour les tests logiques de base, les conditions complexes nécessitent souvent des instructions SI imbriquées pour un traitement des données amélioré. Dans ce guide complet, nous couvrirons en détail les bases des SI imbriqués, de la syntaxe aux applications pratiques, y compris les combinaisons de SI imbriqués avec des conditions ET/OU. De plus, nous partagerons comment améliorer la lisibilité des fonctions SI imbriquées ainsi que quelques conseils sur les SI imbriqués, et explorerons des alternatives puissantes telles que RECHERCHEV, SI.CONDITIONS, et plus encore pour rendre les opérations logiques complexes plus faciles à utiliser et plus efficaces.

A screenshot of the nested IF statements in Excel

Fonction SI d'Excel vs. Instructions SI imbriquées

La fonction SI et les instructions SI imbriquées dans Excel servent des objectifs similaires mais diffèrent considérablement en termes de complexité et d'application.

Fonction SI : La fonction SI teste une condition et renvoie une valeur si la condition est vraie et une autre valeur si elle est fausse.
  • La syntaxe est:
    =SI (test_logique, [valeur_si_vrai], [valeur_si_faux])
  • Limitation : Ne peut gérer qu'une seule condition à la fois, ce qui la rend moins adaptée aux scénarios de prise de décision plus complexes nécessitant l'évaluation de plusieurs critères.
Instructions SI imbriquées : Les fonctions SI imbriquées, c'est-à-dire une fonction SI à l'intérieur d'une autre, vous permettent de tester plusieurs critères et augmentent le nombre de résultats possibles.
  • La syntaxe est:
    =SI(condition1, valeur_si_vrai1, SI(condition2, valeur_si_vrai2, valeur_si_faux2))
  • Complexité : Peut gérer plusieurs conditions mais peut devenir complexe et difficile à lire avec trop de niveaux d'imbrication.

Utilisation des SI imbriqués

Cette section démontre l'utilisation de base des instructions SI imbriquées dans Excel, y compris la syntaxe, des exemples pratiques, et comment les utiliser avec des conditions ET ou OU.

Syntaxe des SI imbriqués

Comprendre la syntaxe d'une fonction est la base de son application correcte et efficace dans Excel. Commençons par la syntaxe des instructions SI imbriquées.

Syntaxe :

=SI(condition1, résultat1, SI(condition2, résultat2, SI(condition3, résultat3, résultat4)))

Arguments :

  • Condition1, Condition2, Condition3 : Ce sont les conditions que vous souhaitez tester. Chaque condition est évaluée dans l'ordre, en commençant par Condition1.
  • Résultat1 : C'est la valeur renvoyée si Condition1 est VRAI.
  • Résultat2 : Cette valeur est renvoyée si Condition1 est FAUX et Condition2 est VRAI. Il est important de noter que Résultat2 n'est évalué que si Condition1 est FAUX.
  • Résultat3 : Cette valeur est renvoyée si Condition1 et Condition2 sont FAUX, et Condition3 est VRAI. Essentiellement, pour que Résultat3 soit évalué, les conditions précédentes (Condition1 et Condition2) doivent toutes deux être FAUX.
  • Résultat4: Ce résultat est renvoyé si toutes les conditions (Condition1, Condition2, et Condition3) sont FAUX.
    En bref, cette expression peut être interprétée comme suit :
    Tester condition1, si VRAI, renvoyer résultat1, si FAUX,
    tester condition2, si VRAI, renvoyer résultat2, si FAUX,
    tester condition3, si VRAI, renvoyer résultat3, si FAUX,
    renvoyer résultat4

Rappelez-vous, dans une structure SI imbriquée, chaque condition suivante n'est évaluée que si toutes les conditions précédentes sont FAUX. Cette vérification séquentielle est essentielle pour comprendre comment fonctionnent les SI imbriqués.

Exemples pratiques de SI imbriqués

Maintenant, plongeons dans l'utilisation des SI imbriqués avec deux exemples pratiques.

Exemple1 : Système de notation

Comme montré dans la capture d'écran ci-dessous, supposons que vous ayez une liste de scores d'étudiants et que vous souhaitiez attribuer des notes en fonction de ces scores. Vous pouvez utiliser des SI imbriqués pour accomplir cette tâche.

Remarque : Les niveaux de notation et leurs plages de scores correspondantes sont listés dans la plage E2:F6.

A screenshot showing the grading system example for nested IF statements in Excel

Sélectionnez une cellule vide (C2 dans ce cas), entrez la formule suivante et appuyez sur Entrée pour obtenir le résultat. Ensuite, faites glisser la poignée de remplissage vers le bas pour obtenir le reste des résultats.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))
Remarques :
  • Vous pouvez spécifier directement le niveau de notation dans la formule, de sorte que la formule peut être modifiée en :
    =IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
  • Cette formule est utilisée pour attribuer une note (A, B, C, D ou F) en fonction d'un score dans la cellule A2, en utilisant des seuils de notation standard. C'est un cas d'utilisation typique pour les instructions SI imbriquées dans les systèmes de notation académique.
  • Explication de la formule :
    1. A2>=90 : C'est la première condition que la formule vérifie. Si le score dans la cellule A2 est supérieur ou égal à90, la formule renvoie "A".
    2. A2>=80 : Si la première condition est fausse (le score est inférieur à90), elle vérifie si A2 est supérieur ou égal à80. Si c'est vrai, elle renvoie "B".
    3. A2>=70 : De même, si le score est inférieur à80, elle vérifie s'il est supérieur ou égal à70. Si c'est vrai, elle renvoie "C".
    4. A2>=60 : Si le score est inférieur à70, la formule vérifie s'il est supérieur ou égal à60. Si c'est vrai, elle renvoie "D".
    5. "F" : Enfin, si aucune des conditions ci-dessus n'est remplie (ce qui signifie que le score est inférieur à60), la formule renvoie "F".
Exemple2 : Calcul de la commission de vente

Imaginez un scénario où les représentants commerciaux reçoivent différents taux de commission en fonction de leurs réalisations de vente. Comme montré dans la capture d'écran ci-dessous, vous souhaitez calculer la commission d'un vendeur en fonction de ces différents seuils de vente, et les instructions SI imbriquées peuvent vous aider avec cela.

Remarque : Les taux de commission et leurs plages de ventes correspondantes sont listés dans la plage E2:F4.
  • Niveau1 (20000 Tier 1 ($20,000+): 20%) :20%
  • Niveau2 (10000 $-19999 $) :15%
  • Niveau3 (<10000 $) :10%

A screenshot showing the sales commission calculation example for nested IF statements in Excel

Sélectionnez une cellule vide (C2 dans ce cas), entrez la formule suivante et appuyez sur Entrée pour obtenir le résultat. Ensuite, faites glisser la poignée de remplissage vers le bas pour obtenir le reste des résultats.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

A screenshot displaying the results of the sales commission calculation using nested IF formulas

Remarques :
  • Vous pouvez spécifier directement le taux de commission dans la formule, de sorte que la formule peut être modifiée en :
    =B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%))
  • La formule fournie est utilisée pour calculer la commission d'un vendeur en fonction de son montant de vente, en appliquant différents taux de commission pour différents seuils de vente.
  • Explication de la formule :
    1. B2 : Cela représente le montant des ventes pour le vendeur, qui est utilisé comme base pour calculer la commission.
    2. SI(B2>20000, "20%", ...) : C'est la première condition vérifiée. Elle vérifie si le montant des ventes dans B2 est supérieur à20000. Si c'est le cas, la formule utilise un taux de commission de20%.
    3. SI(B2>=10000, "15%", "10%") : Si la première condition est fausse (les ventes ne dépassent pas20000), la formule vérifie si les ventes sont égales ou dépassent10000. Si c'est vrai, elle applique un taux de commission de15%. Si le montant des ventes est inférieur à10000, la formule applique par défaut un taux de commission de10%.

SI imbriqué avec condition ET / OU

Dans cette section, je modifie le premier exemple ci-dessus "le système de notation" pour démontrer comment combiner un SI imbriqué avec une condition ET ou OU dans Excel. Dans l'exemple de notation révisé, j'ai introduit une condition supplémentaire basée sur le "Taux de présence".

A screenshot illustrating the grading example with attendance criteria in Excel

Utilisation de SI imbriqué avec condition ET

Si un étudiant répond à la fois aux critères de score et de présence, il recevra une augmentation de note. Par exemple, un étudiant dont le score est de60 ou plus et dont le taux de présence est de95% ou plus verra sa note augmentée d'un niveau, comme de A à A+, de B à B+, etc. Cependant, si le taux de présence est inférieur à95%, la notation suivra les critères de score d'origine. Dans de tels cas, nous devons utiliser une instruction SI imbriquée avec une condition ET.

Sélectionnez une cellule vide (D2 dans ce cas), entrez la formule suivante et appuyez sur Entrée pour obtenir le résultat. Ensuite, faites glisser la poignée de remplissage vers le bas pour obtenir le reste des résultats.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

A screenshot showing nested IF with AND condition for grading in Excel

Remarques : Voici une explication de la façon dont cette formule fonctionne :
  1. Vérification de la condition ET:
    ET(B2>=60, C2>=95%) : La condition ET vérifie d'abord si les deux conditions sont remplies — le score de l'étudiant est de60 ou plus, et son taux de présence est de95% ou plus.
  2. Nouvelle attribution de note:
    SI(B2>=90, "A+", SI(B2>=80, "B+", SI(B2>=70, "C+", "D+"))) : Si les deux conditions de l'instruction ET sont vraies, la formule vérifie alors le score de l'étudiant et augmente sa note d'un niveau.
    • B2>=90 : Si le score est de90 ou plus, la note est "A+". Nouvelle attribution de note :
    • B2>=80 : Si le score est de80 ou plus (mais inférieur à90), la note est "B+".
    • B2>=70 : Si le score est de70 ou plus (mais inférieur à80), la note est "C+".
    • B2>=60 : Si le score est de60 ou plus (mais inférieur à70), la note est "D+".
  3. Attribution de note régulière:
    SI(B2>=90, "A", SI(B2>=80, "B", SI(B2>=70, "C", SI(B2>=60, "D", "F")))) : Si la condition ET n'est pas remplie (soit le score est inférieur à80, soit la présence est inférieure à95%), la formule attribue des notes standard.
    • B2>=90 : Un score de90 ou plus obtient un "A".
    • B2>=80 : Un score de80 ou plus (mais inférieur à90) obtient un "B".
    • B2>=70 : Un score de70 ou plus (mais inférieur à80) obtient un "C".
    • B2>=60 : Un score de60 ou plus (mais inférieur à70) obtient un "D".
    • Les scores inférieurs à60 obtiennent un "F".
Utilisation de SI imbriqué avec condition OU

Dans ce cas, la note d'un étudiant sera augmentée d'un niveau si son score est de95 ou plus, ou si son taux de présence est de95% ou plus. Voici comment nous pouvons y parvenir en utilisant des conditions SI imbriquées et OU.

Sélectionnez une cellule vide (D2 dans ce cas), entrez la formule suivante et appuyez sur Entrée pour obtenir le résultat. Ensuite, faites glisser la poignée de remplissage vers le bas pour obtenir le reste des résultats.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

A screenshot showing nested IF with OR condition for grading in Excel

Remarques : Voici une explication de la façon dont la formule fonctionne :
  1. Vérification de la condition OU :
    OU(B2>=95, C2>=95%) : La formule vérifie d'abord si l'une des conditions est vraie — le score de l'étudiant est de95 ou plus, ou son taux de présence est de95% ou plus.
  2. Attribution de note avec bonus :
    SI(B2>=90, "A+", SI(B2>=80, "B+", SI(B2>=70, "C+", SI(B2>=60, "D+", "F+")))) : Si l'une des conditions de l'instruction OU est vraie, la note de l'étudiant sera augmentée d'un niveau.
    • B2>=90 : Si le score est de90 ou plus, la note est "A+".
    • B2>=80 : Si le score est de80 ou plus (mais inférieur à90), la note est "B+".
    • B2>=70 : Si le score est de70 ou plus (mais inférieur à80), la note est "C+".
    • B2>=60 : Si le score est de60 ou plus (mais inférieur à70), la note est "D+".
    • Sinon, la note est "F+".
  3. Attribution de note régulière:
    SI(B2>=80, "B", SI(B2>=70, "C", SI(B2>=60, "D", "F")))) : Si aucune des conditions OU n'est remplie (le score est inférieur à95 et la présence est inférieure à95%), la formule attribue des notes standard.
    • B2>=90 : Un score de90 ou plus obtient un "A".
    • B2>=80 : Un score de80 ou plus (mais inférieur à90) obtient un "B".
    • B2>=70 : Un score de70 ou plus (mais inférieur à80) obtient un "C".
    • B2>=60 : Un score de60 ou plus (mais inférieur à70) obtient un "D".
    • Les scores inférieurs à60 obtiennent un "F".

Astuces pour les SI imbriqués

Cette section couvre quatre astuces utiles pour les SI imbriqués.

Rendre les SI imbriqués faciles à lire

Une instruction SI imbriquée typique peut sembler compacte mais peut être difficile à déchiffrer.

Dans la formule suivante, il est difficile d'identifier rapidement où une condition se termine et où une autre commence, surtout à mesure que la complexité augmente.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
Solution : Ajouter des sauts de ligne et des indentations

Pour rendre les SI imbriqués faciles à lire, vous pouvez diviser la formule en plusieurs lignes avec chaque SI imbriqué sur une nouvelle ligne. Dans la formule, placez simplement le curseur avant le SI et appuyez sur les touches Alt + Entrée.

Après avoir divisé la formule ci-dessus, elle apparaîtra comme suit :

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Ce format rend plus clair où se trouvent chaque condition et sortie correspondante, améliorant ainsi la lisibilité de la formule.

L'ordre des fonctions SI imbriquées

L'ordre des conditions logiques dans une formule SI imbriquée est crucial car il détermine comment Excel évalue ces conditions et affecte ainsi le résultat final de la formule.

Formule correcte

Dans l'exemple du système de notation, nous utilisons la formule suivante pour attribuer des notes en fonction des scores.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

A screenshot displaying the correct order of conditions in a nested IF formula for grading

Excel évalue les conditions dans une formule SI imbriquée séquentiellement, de la première condition à la dernière. Cette formule vérifie d'abord le seuil de score le plus élevé (>=90 pour un "A") puis passe aux seuils inférieurs. Elle garantit qu'un score est comparé à la note la plus élevée pour laquelle il est qualifié. Si la première condition est vraie (A2>=90), elle renvoie "A" et n'évalue pas d'autres conditions.

Formule mal ordonnée

Si l'ordre des conditions était inversé, en commençant par le seuil le plus bas, elle renverrait des résultats incorrects.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

A screenshot illustrating incorrect ordering in a nested IF formula

Dans cette formule incorrecte, un score de95 remplirait immédiatement la première condition B2>=60 et se verrait attribuer incorrectement une note "D".

Les nombres et le texte doivent être traités différemment

Cette section vous montrera comment les nombres et le texte sont traités différemment dans les instructions SI imbriquées.

Nombres

Les nombres sont utilisés pour les comparaisons et calculs arithmétiques. Dans les instructions SI imbriquées, vous pouvez comparer directement les nombres en utilisant des opérateurs comme >, <, =, >=, et <=.

Texte

Dans les instructions SI imbriquées, le texte doit être entre guillemets. Voir les A, B, C, D et F dans la formule suivante :

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Limitations des SI imbriqués

Cette section liste plusieurs limitations et inconvénients des SI imbriqués.

Complexité et lisibilité :

Bien qu'Excel vous permette d'imbriquer jusqu'à64 fonctions SI différentes, il n'est pas du tout conseillé de le faire. Plus il y a de niveaux d'imbrication, plus la formule devient complexe. Cela peut conduire à des formules difficiles à lire, comprendre et maintenir.

Sujet à erreurs :

De plus, les instructions SI imbriquées complexes peuvent devenir sujettes à des erreurs et difficiles à déboguer ou à modifier.

Difficile à étendre ou à mettre à l'échelle :

Si votre logique change ou si vous devez ajouter plus de conditions, les SI profondément imbriqués peuvent être difficiles à modifier ou à étendre.

Comprendre ces limitations est essentiel pour utiliser efficacement les instructions SI imbriquées dans Excel. Souvent, combiner des SI imbriqués avec d'autres fonctions ou rechercher des approches alternatives peut conduire à des solutions plus efficaces et plus faciles à maintenir.

Alternatives aux SI imbriqués

Cette section liste plusieurs fonctions dans Excel qui peuvent être utilisées comme alternatives aux instructions SI imbriquées.

Utilisation de RECHERCHEV

Vous pouvez utiliser la fonction RECHERCHEV au lieu des instructions SI imbriquées pour accomplir les deux exemples pratiques ci-dessus. Voici comment vous pouvez le faire :

Exemple1 : Système de notation avec RECHERCHEV

Ici, je vais montrer comment utiliser RECHERCHEV pour attribuer des notes en fonction des scores.

Étape1 : Créer un tableau de recherche pour les notes

Tout d'abord, vous devez créer un tableau de recherche (tel que E1:F6 dans ce cas) pour la plage de scores et les notes correspondantes. Remarque : Les scores dans la première colonne du tableau doivent être triés par ordre croissant.

A screenshot showing a lookup table for grades to use with VLOOKUP in Excel

Étape2 : Appliquer la fonction RECHERCHEV pour attribuer des notes

Sélectionnez une cellule vide (C2 dans ce cas), entrez la formule suivante et appuyez sur la touche Entrée pour obtenir la première note. Sélectionnez cette cellule de formule et faites glisser sa poignée de remplissage vers le bas pour obtenir le reste des notes.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

A screenshot demonstrating the use of VLOOKUP for grading in Excel

Remarques :
  • La valeur95 dans la cellule B2 est ce que RECHERCHEV recherche dans la première colonne du tableau de recherche ($E$2:$F$6). Si elle est trouvée, elle renvoie la note correspondante de la deuxième colonne du tableau, située dans la même ligne que la valeur correspondante.
  • N'oubliez pas de rendre la référence du tableau de recherche absolue (ajoutez les signes dollar ($) avant les références), ce qui signifie que la référence ne changera pas si la formule est copiée dans une autre cellule.
  • Pour en savoir plus sur la fonction RECHERCHEV, visitez cette page.
Exemple2 : Calcul de la commission de vente avec RECHERCHEV

Vous pouvez également utiliser RECHERCHEV pour accomplir le calcul de la commission de vente dans Excel. Veuillez procéder comme suit.

Étape1 : Créer un tableau de recherche pour les notes

Tout d'abord, vous devez créer un tableau de recherche pour les ventes et le taux de commission correspondant, tel que E2:F4 dans ce cas. Remarque : Les ventes dans la première colonne du tableau doivent être triées par ordre croissant.

A screenshot showing a lookup table for sales commission rates to use with VLOOKUP in Excel

Étape2 : Appliquer la fonction RECHERCHEV pour attribuer des notes

Sélectionnez une cellule vide (C2 dans ce cas), entrez la formule suivante et appuyez sur la touche Entrée pour obtenir la première commission. Sélectionnez cette cellule de formule et faites glisser sa poignée de remplissage vers le bas pour obtenir le reste des résultats.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

A screenshot demonstrating the use of VLOOKUP for sales commission calculation in Excel

Remarques :
  • Dans les deux exemples, RECHERCHEV est utilisé pour trouver une valeur dans un tableau en fonction d'une valeur de recherche (score ou montant des ventes) et renvoie une valeur dans la même ligne à partir d'une colonne spécifiée (note ou taux de commission). Le quatrième paramètre VRAI indique une correspondance approximative, ce qui est approprié pour ces scénarios où la valeur de recherche exacte pourrait ne pas être présente dans le tableau.
  • Pour en savoir plus sur la fonction RECHERCHEV, visitez cette page.

Utilisation de SI.CONDITIONS

La fonction SI.CONDITIONS simplifie le processus en éliminant le besoin d'imbrication et rend les formules plus faciles à lire et à gérer. Elle améliore la lisibilité et simplifie la gestion de plusieurs vérifications conditionnelles. Pour utiliser la fonction SI.CONDITIONS, assurez-vous d'utiliser Excel2019 ou une version ultérieure, ou d'avoir un abonnement Office365. Voyons comment elle peut être appliquée dans des exemples pratiques.

Exemple1 : Système de notation avec SI.CONDITIONS

En supposant les mêmes critères de notation qu'auparavant, la fonction SI.CONDITIONS peut être utilisée comme suit :

Sélectionnez une cellule vide, telle que C2, entrez la formule suivante et appuyez sur Entrée pour obtenir le premier résultat. Sélectionnez cette cellule de résultat et faites glisser sa poignée de remplissage vers le bas pour obtenir le reste des résultats.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

A screenshot showing the use of the IFS function for grading in Excel

Remarques :
  • Chaque condition est évaluée dans l'ordre. Dès qu'une condition est remplie, son résultat correspondant est renvoyé, et la formule cesse de vérifier d'autres conditions. Dans ce cas, la formule est utilisée pour attribuer des notes en fonction du score dans B2, suivant une échelle de notation typique où un score plus élevé correspond à une meilleure note.
  • Pour en savoir plus sur la fonction SI.CONDITIONS, visitez cette page.
Exemple2 : Calcul de la commission de vente avec SI.CONDITIONS

Pour le scénario de calcul de la commission de vente, la fonction SI.CONDITIONS est appliquée comme suit :

Sélectionnez une cellule vide, telle que C2, entrez la formule suivante et appuyez sur Entrée pour obtenir le premier résultat. Sélectionnez cette cellule de résultat et faites glisser sa poignée de remplissage vers le bas pour obtenir le reste des résultats.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

A screenshot showing the use of the IFS function for sales commission calculation in Excel

Utilisation de CHOISIR et EQUIV

L'approche CHOISIR et EQUIV peut être plus efficace et plus facile à gérer par rapport aux instructions SI imbriquées. Cette méthode simplifie la formule et rend les mises à jour ou les modifications plus simples. Ci-dessous, je vais démontrer comment utiliser une combinaison des fonctions CHOISIR et EQUIV pour traiter les deux exemples pratiques de cet article.

Exemple1 : Système de notation avec CHOISIR et EQUIV

Vous pouvez utiliser la combinaison des fonctions CHOISIR et EQUIV pour attribuer des notes en fonction de différents scores.

Étape1 : Créer un tableau de recherche avec des valeurs de recherche

Tout d'abord, vous devez créer une plage de cellules contenant les valeurs seuils que EQUIV recherchera, telles que $E$2:$E$6 dans ce cas. Remarque : Les nombres dans cette plage doivent être triés par ordre croissant pour que la fonction EQUIV fonctionne correctement lors de l'utilisation d'un type de correspondance approximative.

A screenshot showing a lookup array for grades using CHOOSE and MATCH in Excel

Étape2 : Appliquer CHOISIR et EQUIV pour attribuer des notes

Sélectionnez une cellule vide (C2 dans ce cas), entrez la formule suivante et appuyez sur la touche Entrée pour obtenir la première note. Sélectionnez cette cellule de formule et faites glisser sa poignée de remplissage vers le bas pour obtenir le reste des résultats.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

A screenshot demonstrating CHOOSE and MATCH for grading in Excel

Remarques :
  • EQUIV(B2, $E$2:$E$6,1) : Cette partie de la formule recherche le score (95) dans la cellule B2 dans la plage $E$2:$E$6. Le1 indique que EQUIV doit trouver une correspondance approximative, ce qui signifie qu'il trouve la plus grande valeur dans la plage qui est inférieure ou égale à B2.
  • CHOISIR(..., "F", "D", "C", "B", "A") : En fonction de la position renvoyée par la fonction EQUIV, CHOISIR sélectionne une note correspondante.
  • Pour en savoir plus sur la fonction EQUIV, visitez cette page.
  • Pour en savoir plus sur la fonction CHOISIR, visitez cette page.
Exemple2 : Calcul de la commission de vente avec SI.CONDITIONS

Utiliser la combinaison CHOISIR et EQUIV pour un calcul de commission de vente peut également être efficace, surtout lorsque les taux de commission sont basés sur des seuils de vente spécifiés. Voyons comment nous pouvons faire.

Étape1 : Créer un tableau de recherche avec des valeurs de recherche

Tout d'abord, vous devez créer une plage de cellules contenant les valeurs seuils que EQUIV recherchera, telles que $E$2:$E$4 dans ce cas. Remarque : Les nombres dans cette plage doivent être triés par ordre croissant pour que la fonction EQUIV fonctionne correctement lors de l'utilisation d'un type de correspondance approximative.

A screenshot showing a lookup array for sales commission rates using CHOOSE and MATCH in Excel

Étape2 : Appliquer CHOISIR et EQUIV pour obtenir les résultats

Sélectionnez une cellule vide (C2 dans ce cas), entrez la formule suivante et appuyez sur la touche Entrée pour obtenir la première note. Sélectionnez cette cellule de formule et faites glisser sa poignée de remplissage vers le bas pour obtenir le reste des résultats.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

A screenshot demonstrating CHOOSE and MATCH for sales commission calculation in Excel

Remarques :

En conclusion, maîtriser les instructions SI imbriquées dans Excel est une compétence précieuse qui améliore votre capacité à gérer des scénarios logiques complexes dans les processus d'analyse de données et de prise de décision. Bien que les SI imbriqués soient puissants pour les opérations logiques complexes, il est important de garder à l'esprit leurs limitations. Des alternatives plus simples comme RECHERCHEV, SI.CONDITIONS, et CHOISIR avec EQUIV peuvent offrir des solutions plus rationalisées dans certains scénarios. Armé de ces connaissances, vous pouvez maintenant appliquer en toute confiance les techniques Excel les plus appropriées à vos tâches d'analyse de données, assurant clarté, précision et efficacité dans vos feuilles de calcul. Pour ceux qui souhaitent approfondir les capacités d'Excel, notre site Web regorge de tutoriels. Découvrez plus d'astuces et de conseils Excel ici.

Meilleurs outils de productivité pour Office

🤖 Kutools AI Aide : Révolutionner l'analyse des données basée sur : Exécution intelligente   |  Générer du code  |  Créer des formules personnalisées  |  Analyser les données et générer des graphiques  |  Invoquer les Fonctions améliorées…
Fonctionnalités populaires : Trouver, mise en évidence ou marquer les doublons   |  Supprimer les lignes vides   |  Consolider les colonnes ou les cellules sans perdre de données   |   Arrondir sans formule ...
Super RECHERCHEV : RECHERCHEV avec critères multiples  |   RECHERCHEV avec valeurs multiples  |   Recherche multi-feuilles   |   Correspondance floue ....
Liste déroulante avancée : Créer rapidement une liste déroulante   |  Liste déroulante dépendante   |  Liste déroulante multi-sélection ....
Gestionnaire de colonnes : Ajouter un nombre spécifique de colonnes  |  Déplacer les colonnes  |  Basculer l'état de visibilité des colonnes masquées  |  Comparer les plages & colonnes ...
Fonctionnalités en vedette : Mise au point de la grille   |  Affichage de conception   |   Barre de formule améliorée   |  Gestionnaire de classeur & feuille de calcul   |  Bibliothèque dAutoTexte (Auto Text)   |  Sélecteur de date   |  Fusionner les données   |  Crypter/Déchiffrer les cellules   |  Envoyer un e-mail par liste   |  Super Filtre   |   Filtre spécial (filtrer les cellules avec une police en gras/italique/barré...) ...
Top15 ensembles d'outils : 12 outils de texte (Ajouter du texte, Supprimer des caractères spécifiques, ...)   |   50+ types de graphiques (Diagramme de Gantt, ...)   |   40+ formules pratiques (Calculer lâge en fonction de la date de naissance, ...)   |   19 outils d'insertion (Insérer un code QR, Insérer une image depuis le chemin, ...)   |  12 outils de conversion (Convertir en mots, Conversion de devises, ...)   |  7 outils de fusion & division (Fusion avancée des lignes, Diviser les cellules, ...)   |   ... et plus

Boostez vos compétences Excel avec Kutools pour Excel, et découvrez une efficacité sans précédent. Kutools pour Excel propose plus de300 fonctionnalités avancées pour augmenter la productivité et gagner du temps.  Cliquez ici pour obtenir la fonctionnalité dont vous avez le plus besoin...

Office Tab apporte une interface à onglets à Office, et facilite grandement votre travail

  • Activez la modification et la lecture par onglets dans Word, Excel, PowerPoint, Publisher, Access, Visio et Project.
  • Ouvrez et créez plusieurs documents dans de nouveaux onglets de la même fenêtre, plutôt que dans de nouvelles fenêtres.
  • Augmente votre productivité de50 %, et réduit des centaines de clics de souris pour vous chaque jour !